ScriptForge.Array-teneste

Inneheld ei samling metodar for å handsama og transformera matriser av éin dimensjon (vektorar) og matriser med to dimensjonar (matriser). Dette inkluderer å setja operasjonar, sortera, importera til og eksportere frå tekstfiler.

Matyriser med meir enn to dimensjonar kan ikkje brukast med metodane i denne tenesta. Einaste unnataket er metoden CountDims, som godtar matriser med kor mange dimensjonar som helst.

Matrise-element kan innehalda kva verdi som helst, også (under)matriser.

Oppkall av tenester

Før du kan bruka tenesta Array, må du henta inn biblioteket ScriptForge ved hjelp av


    GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
  

Lastinga av biblioteket vil laga objektet SF_Array som kan brukast for å kalla opp metodane i tenesta Array.

Desse kodesnuttane viser dei ulike måtane å kalla opp metodar på i tenesta Array. Metoden Append er brukt som eksempel:


    Dim arr : arr = Array(1, 2, 3)
    arr = SF_Array.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = SF_Array
    arr = svc.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = CreateScriptService("Array")
    arr = svc.Append(arr, 4)
  
warning

Because Python has built-in list and tuple support, most of the methods in the Array service are available for Basic scripts only. The only exception is ImportFromCSVFile which is supported in both Basic and Python.


List of Methods in the Array Service

Append
AppendColumn
AppendRow
Contains
ConvertToDictionary
Copy
CountDims
Difference
ExportToTextFile
ExtractColumn
ExtractRow

Flatten
ImportFromCSVFile
IndexOf
Insert
InsertSorted
Intersection
Join2D
Prepend
PrependColumn
PrependRow
RangeInit

Reverse
Shuffle
Slice
Sort
SortColumns
SortRows
Transpose
TrimArray
Union
Unique


tip

Det første argumentet i dei fleste metodane er kva matriseopbjekt som skal vurderast. Den vert alltid sendt med referanse og vert ikkje endra. Metodar som «Append», «Prepend» osv. returnerer eit nytt matrise-objekt etter utføringa.


Append

Legg elementa som er oppførte til som argument på slutten av inndatamatrisa.

Syntaks:

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

Parametrar:

array_1d: The pre-existing array, may be empty.

arg0, arg1, ...: Items that will be appended to array_1d.

Eksempel:


    Dim a As Variant
    a = SF_Array.Append(Array(1, 2, 3), 4, 5)
        ' (1, 2, 3, 4, 5)
  

AppendColumn

Set inn ein ny kolonne til høgre i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

Syntaks:

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

Parametrar:

array_2d: The pre-existing array, may be empty. If that array has only one dimension, it is considered as the first column of the resulting two-dimensional array.

column: A 1-dimensional array with as many items as there are rows in array_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((1, 4), (2, 5), (3, 6))
    b = SF_Array.AppendColumn(a, Array(7, 8, 9))
        ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
    c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

AppendRow

Legg til ei ny rad nedst i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege matrisa.

Syntaks:

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

Parametrar:

array_2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the first row of the resulting 2 dimension array.

row: A 1-dimensional array with as many items as there are columns in array_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
        '  ((1, 2, 3), (4, 5, 6))
    b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

Contains

Sjå etter om ei eindimensjonal matrise inneheld eit bestemt tal, ein bestemt tekst eller dato. Tekstsamanlikningar kan skilja mellom store og små bokstavar.
Sorterte inndatamatriser må fyllast ut homogent, det vil seia at alle elementa må vera skalarar av same type (Tomme- og Null-element kan ikkje brukast).
Det er uråd å vita på førehand kva resultatet av metoden vert når matrisa er sagt å vera sortert utan at ho er det.
Det vert utført eit binærsøk når matrisa er sortert, elles vert ho skanna frå øvst til nedst og Tomme element og Nullelement vert ignorerte.

Syntaks:

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

Parametrar:

array_1d: The array to scan.

tofind: A number, a date or a string to find.

casesensitive: Only for string comparisons (Default = False).

sorteringsrekkjefølgje: Det kan anten vera "ASC", "DESC" eller "" (ikkje sortert). Standardverdien er "".

Eksempel:


    Dim a As Variant
    a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
    SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
  

ConvertToDictionary

Lagrar innhaldet av ei matrise med to kolonnar i eit ScriptForge.Dictionary-objekt.
Nøkkelen vert henta ut frå den første kolonnen, elementet frå den andre.

Syntaks:

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

Parametrar:

array_2d: Data to be converted into a ScriptForge.Dictionary object.

Eksempel:


    Dim a As Variant, b As Variant
    a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
    b = SF_Array.ConvertToDictionary(a)
    MsgBox b.Item("c") ' 3
  

Copy

Creates a copy of a 1D or 2D array.

Syntaks:

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

Parametrar:

array_nd: The 1D or 2D array to be copied.

Eksempel:

A simple assignment of an Array object will copy its reference instead of creating a copy of the object's contents. See the example below:


    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' The assignment below is made by reference
    b = a
    ' Hence changing values in "b" will also change "a"
    b(0) = 10
    MsgBox a(0) ' 10
  

By using the Copy method, a copy of the whole Array object is made. In the example below, a and b are different objects and changing values in b will not affect values in a.


    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' Creates a copy of "a" using the "Copy" method
    b = SF_Array.Copy(a)
    b(0) = 10
    MsgBox a(0) ' 1
  

CountDims

Count the number of dimensions of an array. The result can be greater than two.
If the argument is not an array, returns -1
If the array is not initialized, returns 0.

Syntaks:

svc.CountDims(array_nd: any): int

Parametrar:

array_nd: The array to examine.

Eksempel:


    Dim a(1 To 10, -3 To 12, 5)
    MsgBox SF_Array.CountDims(a) ' 3
  

Difference

Bygg eit sett som ei null-basert matrise, ved å bruka differensoperatoren på dei to inndatamatrisene. Resulterande element kjem frå den første matrisa og ikkje frå den andre.<br>Den resulterande matrisa vert sortert i stigande rekkjefølgje.<br>Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.<br>Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

Syntaks:

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

array1_1d: A 1-dimensional reference array, whose items are examined for removal.

array2_1d: A 1-dimensional array, whose items are subtracted from the first input array.

casesensitive: This argument is only applicable if the arrays are populated with strings (Default = False).

Eksempel:


    Dim a As Variant
    a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B")
  

ExportToTextFile

Skriv alle matriseelementa i nummerrekkjefølgje til ei tekstfil. Viss fila finst frå før, vert ho overskrive utan varsel.

Syntaks:

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

Parametrar:

array_1d: The array to export. It must contain only strings.

filename: The name of the text file where the data will be written to. The name must be expressed according to the current FileNaming property of the SF_FileSystem service.

encoding: The character set that should be used. Use one of the names listed in IANA character sets. Note that LibreOffice may not implement all existing character sets (Default is "UTF-8").

Eksempel:


    SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
  

ExtractColumn

Trekk ut ein bestemt kolonne frå ei todimensjonal matrise som ei ny matrise.
Dei nedre LBound og øvre UBound grensene er dei same som dei brukte i første dimensjon av innmatrisa.

Syntaks:

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

Parametrar:

array_2d: The array from which to extract.

columnindex: The column number to extract - must be in the interval [LBound, UBound].

Eksempel:


    'Lagar ei 3 × 3 matrise: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, col as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Trekk ut den tredje kolonnen: |3, 6, 9|
    col = SF_Array.ExtractColumn(mat, 2)
  

ExtractRow

Trekk ut ei bestemt rad som ei ny matrise frå ei to-dimensjonal matrise.
Nedre (LBound) og øvre (UBound) grense er lik grensene i den andre dimensjonen i inndatamatrisa.

Syntaks:

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

Parametrar:

array_2d: The array from which to extract.

rowindex: The row number to extract - must be in the interval [LBound, UBound].

Eksempel:


    ' Lagar ei 3 × 3 matrise: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, row as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    ' Trekk ut den første rada: |1, 2, 3|
    row = SF_Array.ExtractRow(mat, 0)
  

Flatten

Stablar alle enkeltelementa i ei matrise og alle elementa i delmatrisene i éi ny matrise utan delmatriser. Tomme delmatriser vert ignorerte og delmatriser med større dimensjonar enn éin vert ikkje slegne saman.

Syntaks:

svc.Flatten(array_1d: any[0..*]): any[0..*]

Parametrar:

array_1d: The pre-existing array, may be empty.

Eksempel:


    Dim a As Variant
    a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
        ' (1, 2, 3, 4, 5)
  
tip

Du kan bruka metoden Flatten saman med andre metodar som for eksempel Append eller Prepend for å kopla saman eit sett med 1D-matriser til éi enkelt 1D-matrise.


Eksempel:

Neste eksempel viser korleis metodane Flatten og Append kan kombinerast for å setja saman tre matriser.


    ' Lager tre matriser til dette eksempelet
    Dim a as Variant, b as Variant, c as Variant
    a = Array(1, 2, 3)
    b = Array(4, 5)
    c = Array(6, 7, 8, 9)
    ' Slår saman dei tre matrisene til éi 1D-matrise
    Dim arr as Variant
    arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
    '(1, 2, 3, 4, 5, 6, 7, 8, 9)
  

ImportFromCSVFile

Importer dataa frå ei kommadelt fil (CSV). Kommaet kan bytast ut med kva teikn som helst.

Det aktuelle CSV-formatet er forklart i IETF Common Format and MIME Type for CSV Files.

Kvar linje i fila inneheld ein fullstendig post (linjedeling er ikkje tillate).
Sekvensar som \n, \t, … vert uendra. Bruk SF_String, Unescape()-metoden for å administrera dei.

Metoden returnerer ei matrise med to dimensjonar der radene svarar til éin enkelt post i fila, og der kolonnane svarar til eitt felt i posten. Det vert ikkje kontrollert om felttypane er samanhengande på tvers av kolonnar. Det vert gjort ei beste gissing for å identifisera numeriske typar og datotypar.

Viss ei linje inneheld færre eller fleire felt enn den første linja i fila, vert det sett eit unntak. Tomme linjer vert ganske enkelt ignorerte. Viss fila er større enn grensa for talet på element (sjå i koden), vert det vist ei åtvaring og matrisa vert avkorta.

Syntaks:

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

Parametrar:

filename: The name of the text file containing the data. The name must be expressed according to the current FileNaming property of the SF_FileSystem service.

delimiter: A single character, usually, a comma, a semicolon or a TAB character (Default = ",").

dateformat: A special mechanism handles dates when dateformat is either "YYYY-MM-DD", "DD-MM-YYYY" or "MM-DD-YYYY". The dash (-) may be replaced by a dot (.), a slash (/) or a space. Other date formats will be ignored. Dates defaulting to an empty string "" are considered as normal text.

Eksempel:

Consider the CSV file "myFile.csv" with the following contents:

Name,DateOfBirth,Address,City

Anna,2002/03/31,"Rue de l'église, 21",Toulouse

Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

The examples below in Basic and Python read the contents of the CSV file into an Array object.

I Basic

    Dim arr As Variant
    arr = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
    MsgBox arr(0, 3) ' City
    MsgBox arr(1, 2) ' Rue de l'église, 21
    MsgBox arr(1, 3) ' Toulouse
  
I Python

    from scriptforge import CreateScriptService
    svc = CreateScriptService("Array")
    bas = CreateScriptService("Basic")
    arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "YYYY/MM/DD")
    bas.MsgBox(arr[0][3]) # City
    bas.MsgBox(arr[1][2]) # Rue de l'église, 21
    bas.MsgBox(arr[1][3]) # Toulouse
  

IndexOf

Sjå etter eit tal, ein streng eller ein dato i ei eindimensjonal matrise. Tekstsamanlikning kan skilja mellom store og små bokstavar, eller ikkje.<br>Viss matrisa er sortert, må ho vera utfylt homogent, altså at alle elementa må vera skalarer av same type (Empty og Null kan ikkje brukast).<br>Når matrisa er sett til å vera sortert men ikkje er det, er det uråd å vita resultatet på førehand.
Det vert brukt binært søk på sorterte matriser. Elles vert matriser ganske enkelt skanna frå topp til botn. Elementa Empty og Null vert ikkje tekne med.

Metoden returnerer LBound(input array) - 1 viss søket ikkje var vellukka.

Syntaks:

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

Parametrar:

array_1d: The array to scan.

tofind: A number, a date or a string to find.

casesensitive: Only for string comparisons (Default = False).

sorteringsrekkjefølgje: Det kan anten vera "ASC", "DESC" eller "" (ikkje sortert). Standardverdien er "".

Eksempel:


    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
  

Insert

Set inn elementa som er oppført som argument framføre ein gjeven indeks for inndatamatrisa.
Argument vert sette inn blindt. Kvart av dei kan anten vera ein skalar av kva type som helst eller ei undermatrise.

Syntaks:

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

Parametrar:

array_1d: The pre-existing array, may be empty.

before: The index before which to insert; must be in the interval [LBound, UBound + 1].

arg0, arg1, ...: Items that will be inserted into array_1d.

Eksempel:


    Dim a As Variant
    a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
        ' (1, 2, "a", "b", 3)
  

InsertSorted

Inserts into a sorted array a new item on its place.
The array must be filled homogeneously, meaning that all items must be scalars of the same type.
Empty and Null items are forbidden.

Syntaks:

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

Parametrar:

array_1d: The array into which the value will be inserted.

item: The scalar value to insert, of the same type as the existing array items.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og små bokstavar: Berre for strengsamanlikningar (Standard = Usann).

Eksempel:


    Dim a As Variant
    a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

Intersection

Bygg eit sett som ei null-basert matrise ved å bruka unionmengde-operatoren på dei to inndatamatrisene. Resulterande element kjem frå begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

Syntaks:

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

array1_1d: Den første inndatamatrisa.

array2_1d: Den andre inndatamatrisa.

skil mellom store og små bokstavar: Gjeld for matriser fylt med tekstelement (standard = Usann).

Eksempel:


    Dim a As Variant
    a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("C", "b")
  

Join2D

Føyer saman ei todimensjonal matrise med to skiljeteikn, eitt for kolonnane, eitt for radene.

Syntaks:

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

Parametrar:

array_2d: Kvart element må vera anten tekst, eit tall, ein dato eller ein boolsk verdi.
Datoar vert omforma til formatet Ã…Ã…Ã…Ã…-MM-DD tt:mm:ss.
Ugyldige element vert byt ut med ein streng med null lengd.

Kolonneskiljeteikn: Skilje mellom kolonnar (standard = Tab/Chr(9)).

Radskiljeteikn: Skil mellom radene (standard = LineFeed/Chr(10))

Hermeteikn: viss Sann vert strengen verna med doble hermeteikn ("). Standarden er Usann.

Eksempel:


    ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
    '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
    Dim arr as Variant : arr = Array()
    arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
    arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
    Dim arrText as String
    arrText = SF_Array.Join2D(arr, ",", "/", False)
    ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10
  

Prepend

Legg dei utlista elementa til som argument i byrjinga av inndatamatrisa.

Syntaks:

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

Parametrar:

matrise_1d: matrisa som finst frå før, kan vera tom.

arg0, arg1 …: ei liste over element som skal setjast inn først i Matrise_1d.

Eksempel:


    Dim a As Variant
    a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
        ' (4, 5, 1, 2, 3)
  

PrependColumn

Legg til ein ny kolonne først på venstre side i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

Syntaks:

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

Parametrar:

Matrise_2d: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første rada i den nye todimensjonale matrisa.

kolonne: ei eindimensional matrise med like mange element som det er rader i array_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 1), (5, 2), (6, 3))
    b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

PrependRow

Legg til ei ny rad først i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

Syntaks:

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

Parametrar:

matrise_2d: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den siste rada i den nye todimensjonale matrisa.

Rad: ei eindimensional matrise med like mange element som det er rader i matrise_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 5, 6), (1, 2, 3))
    b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

RangeInit

Initialiser ei ny null-basert matrise med numeriske verdiar.

Syntaks:

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

Parametrar:

frå: verdien av det første elementet.

Opptil: Det siste elementet må ikkje overstige Opptil.

Trinnvis: Differansen mellom to etterfølgjande element (standard = 1).

Eksempel:


    Dim a As Variant
    a = SF_Array.RangeInit(10, 1, -1)
        ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
  

Reverse

Returner den omvendte eindimensjonelle inndata-matrisa.

Syntaks:

svc.Reverse(array_1d: any[0..*]): any[0..*]

Parametrar:

matrise_1d: matrisa som skal reverserast.

Eksempel:


    Dim a As Variant
    a = SF_Array.Reverse(Array("a", 2, 3, 4))
        ' (4, 3, 2, "a")
  

Shuffle

Returns a random permutation of a one-dimensional array.

Syntaks:

svc.Shuffle(array_1d: any[0..*]): any[0..*]

Parametrar:

array_1d: The array to shuffle.

Eksempel:


    Dim a As Variant
    a = SF_Array.Shuffle(Array(1, 2, 3, 4))
        ' Array "a" is now in random order, f.i. (2, 3, 1, 4)
  

Slice

Returns a subset of a one-dimensional array.

Syntaks:

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

Parametrar:

array_1d: The array to slice.

from: The lower index in array_1d of the subarray to extract (from included)

upto: The upper index in array_1d of the subarray to extract (upto included). The default value is the upper bound of array_1d. If upto < from then the returned array is empty.

Eksempel:


    Dim a As Variant
    a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
  

Sort

Sorter ei eindimensjonal matrise i stigande eller falande rekkjefølgje. Tekstsamanlikningar kan skilja mellom store og små bokstavar eller ikkje.
Matrisa skal vera fylt homogent, altså at elementa må vera av same type skalarar.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva skalarverdi som helst.

Syntaks:

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

Parametrar:

array_1d: The array to sort.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

casesensitive: Only for string comparisons (Default = False).

Eksempel:


    Dim a As Variant
    a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

SortColumns

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada må vera fylt homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

Syntaks:

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

Parametrar:

array_2d: The 2-dimensional array to sort.

rowindex: The index of the row that will be used as reference to sort the columns.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

casesensitive: Only for string comparisons (Default = False).

Eksempel:


    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortColumns(arr, 2, "ASC")
    ' arr = | 7, 5, 3 |
    '       | 9, 1, 5 |
    '       | 1, 6, 8 |
  

SortRows

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada må vera fylt homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

Syntaks:

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

Parametrar:

array_2d: The array to sort.

columnindex: The index of the column that will be used as reference to sort the rows.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

casesensitive: Only for string comparisons (Default = False).

Eksempel:


    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortRows(arr, 0, "ASC")
    ' arr = | 1, 9, 5 |
    '       | 5, 7, 3 |
    '       | 6, 1, 8 |
  

Transpose

Swaps rows and columns in a two-dimensional array.

Syntaks:

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

Parametrar:

array_2d: The 2-dimensional array to transpose.

Eksempel:


    ' arr1 = | 1, 2 |
    '        | 3, 4 |
    '        | 5, 6 |
    arr1 = Array(1, 2)
    arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
    arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
    arr2 = SF_Array.Transpose(arr1)
    ' arr2 = | 1, 3, 5 |
    '        | 2, 4, 6 |
    MsgBox arr2(0, 2) ' 5
  

TrimArray

Fjern alle Null, Empty og nul-lengde-oppføringar frå ei eindimensjonal matrise.
Strengelementa kan trimmast med funksjonen LibreOffice Basic Trim() .

Syntaks:

svc.TrimArray(array_1d: any[0..*]): any[0..*]

Parametrar:

array_1d: The array to trim.

Eksempel:


    Dim a As Variant
    a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
        ' ("A", "B", "D")
  

Union

Bygg eit sett som ei null-basert matrise ved å bruka unionmengde-operatoren på dei to inndatamatrisene. Resulterande element kjem frå ei av begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

Syntaks:

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

array1_1d: The first input array.

array2_1d: The second input array.

casesensitive: Applicable only if the arrays are populated with strings (Default = False).

Eksempel:


    Dim a As Variant
    a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B", "C", "Z", "b")
  

Unique

Bygg eit sett av unike verdiar avleidde frå inndata-matrisa.
Inndata-matrisa må vera fylt homogent, altså at alle elementa må vera skalarer av den same typen. Elementa Empty og Null er ikkje tillatne.
Tekstsamanlikningar kan skilja mellom store og små bokstavar eller ikkje.

Syntaks:

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

array_1d: The input array.

casesensitive: Applicable only if the array is populated with strings (Default = False).

Eksempel:


    Dim a As Variant
    a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
        '  ("A", "B", "C", "b")
  
warning

All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "_" are reserved for internal use. They are not meant be used in Basic macros or Python scripts.