LibreOffice 7.2 žinynas
Šioje sekcijoje galite rasti Tekstinių funkcijų aprašymus.
Apskaičiuoja romėniško skaičiaus reikšmę. Reikšmė privalo būti tarp 0 ir 3999.
ARABIC("Tekstas")
Tekstas – tekstas, kuris nurodo romėniškus skaičius.
=ARABIC("MXIV") grąžins 1014
=ARABIC("MMII") grąžins 2002
ASC funkcija konvertuoja viso pločio ASCII ir katakana ženklus į pusės pločio . Grąžina tekstinę eilutę.
Žiūrėkitehttps://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions, kad pamatytumėte perskaičiavimo lentelę.
ASC("Tekstas")
Tekstas – tekstas, kuriame yra konvertuojami ženklai.
Taip pat skaitykite apie JIS funkciją.
Konvertuoja skaičių į tajų tekstą, įskaitant tajų valiutos pavadinimus.
BAHTTEXT(skaičius)
Skaičius yra bet koks skaičius. „Baht“ yra pridedamas prie integralinės skaičiaus dalies, „Satang“ yra pridedamas prie dešimtainės skaičiaus dalies.
=BAHTTEXT(12.65) grąžina tekstinę eilutę tajų ženklais su reikšme „Dvylika Baht ir šešiasdešimt penki Satag“.
Konvertuoja teigiamą kintamąjį į tam tikrą tekstą iš skaitinės sistemos. Naudojami skaičiai nuo 0-9 ir raidės A-Z.
BASE(skaičius; intervalas [; minimalus ilgis])
Skaičius - teigiamas sveikasis skaičius, kuris bus konvertuojamas.
Pagrindas – nurodo pradinius skaičių sistemos skaičius. Tai gali būti bet koks teigiamas sveikasis skaičius tarp 2 ir 36.
Minimalus skaičius(neprivaloma) nurodo minimalią galimą skaitmenų kiekio reikšmę. Jei tekstas trumpesnis nei minimali reikšmė, gale bus pridedami nuliai.
=BASE(17;10;4) grąžina 0017 dešimtainių skaičių sistemoje
=BASE(17;2) grąžins 10001 dešimtainių skaičių sistemoje.
=BASE(255;16;4) grąžina 00FF šešioliktainėje sistemoje.
Konvertuoja skaičių į ženklą priklausomai nuo pasirinktos kodų lentelės. Skaičius gali būti dviejų skaitmenų arba trijų skaitmenų.
CHAR(Skaičius)
Skaičius – skaičius tarp 1 ir 255 nusakantis ženklo kodo reikšmę.
=CHAR(100) grąžina ženklą d.
="abc" & CHAR(10) & "def" grąžina naujos eilutės ženklą į eilutę.
Visi nespausdinimo ženklai yra pašalinami iš eilutės.
CLEAN(„Tekstas“)
Tekstas – nurodo tekstą iš kurio reikia pašalinti visus nespausdinamus ženklus.
=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.
Grąžina skaitinį kodą pirmam ženklui teksto eilutėje.
CODE(„tekstas“)
Tekstas – tekstas, kurio pirmojo rašmens skaitinis kodas yra nurodomas.
=CODE(„Hieronymus“) grąžins 72,=CODE(„hieroglyphic“) grąžins 104.
Čia naudojamas kodas nurodo ne į ASCII, bet į šiuo metu įkeltą kodų lentelę.
Sujungia kelias teksto eilutes į vieną teksto eilutę.
CONCATENATE(1 eilutė [; 2 eilutė [; … [; 255 eilutė]]])
1 eilutė[; 2 eilutė][; … ;[255 eilutė]] – eilutės arba nuorodos į langelius su eilutėmis.
=CONCATENATE("Sveiki,";"sėkmingai";"sugrįžę";"namo!") returns: Sveiki, sėkmingai sugrįžę namo!
Konvertuoja tekstą su ženklais iš skaičių sistemos į teigiamą sveikąjį pagal nurodytą skaičiavimo sistemos pagrindą. Pagrindas turi būti tarp 2 ir 36. Į tarpus ir tabuliavimo ženklus nekreipiama dėmesio. Tekste nekreipiama dėmesio į didžiąsias ir mažąsias raides.
Jei skaičiavimo sistemos pagrindas yra 16, tai nepaisoma ar pateikiamas x ar X ar 0X, pridedama h arba H. Jei skaičiavimo pagrindas 2, tai nepaisoma ar pridedama b ar B. Ženklai, kurie skaičių sistemai nepriklauso, sugeneruoja klaidos pranešimą.
DECIMAL("Tekstas"; pagrindas)
Tekstas – konvertuojamas tekstas. Kad funkcija atskirtų, ar įvedėte tekstą A1 ar skaičiaus nuorodą A1, skaičių rašykite tarp angliškų kabučių, pavyzdžiui, "A1" ar "NETIESA"
Pagrindas – nurodo skaičių sistemos pagrindą. Tai gali būti bet koks teigiamas sveikasis skaičius tarp 2 ir 36.
=DECIMAL("17";10) grąžina 17.
=DECIMAL("FACE";16) grąžina 64206.
=DECIMAL("0101";2) grąžina 5
Konvertuoja skaičių į valiutos formatą su nurodytu skaitmenų skaičiumi po kablelio. Reikšmės laukelyje įrašykite skaičių, kuris bus konvertuojamas. Papildomai galite įrašyti, kiek skaitmenų po kablelio turi būti rodoma dešimtainių skilčių laukelyje. Jei šis parametras nenurodytas, bus rodomi du skaitmenys po kablelio.
Sistemos nustatymuose nurodykite valiutos formatą.
DOLLAR(reikšmė [; dešimtainiai])
Reikšmė – skaičius, nuoroda į langelį su skaičiumi arba formule, kurios rezultatas yra skaičius.
Dešimtainės skiltys – papildomas parametras, kuris nurodo, kiek skaitmenų po kablelio turi būti rodoma.
=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ¥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.
=DOLLAR(367,456;2) grąžina $367,46. Naudokite dešimtainį skirtuką pagal savo kompiuterio valiutos lokalės nustatymus.
Palygina dvi tekstines eilutes ir grąžina TIESA, jei jos yra vienodos. Ši funkcija skiria didžiąsias ir mažąsias raides.
EXACT("Tekstas 1"; "Tekstas 2")
Tekstas 1 – pirmojo lyginamojo teksto nuoroda.
Tekstas 2 – antrojo lyginamojo teksto nuoroda.
=EXACT("microsystems";"Microsystems") grąžina NETIESA.
Grąžina tekstinės eilutės, esančios kitoje eilutėje, vietą. Galite nurodyti, nuo kurios vietos pradėti ieškoti. Ieškoma frazė gali būti skaičiai ar bet kokių ženklų eilutė. Paieška skiria didžiąsias ir mažąsias raides
FIND("rasti tekstą"; "tekstas" [; vieta])
Paieškos tekstas – nurodomas ieškomas tekstas.
Tekstas – nurodomas tekstas, kur vykdoma paieška.
Vieta (papildomas) – vieta tekste, nuo kurios pradedama paieška.
=FIND(76;998877665544) grąžina 6.
Returns a number as text with a specified number of decimal places and optional thousands separators.
FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])
Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.
Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.
NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.
=FIXED(1234567,89;3) grąžina 1234567,890 kaip teksto eilutę.
=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.
=FIXED(12345.6789;-2) returns 12,300 as a text string.
=FIXED(12134567.89;-3;1) returns 12135000 as a text string.
=FIXED(12345.789;3/4) returns 12,346 as a text string.
=FIXED(12345.789;8/5) returns 12,345.8 as a text string.
JIS funkcija konvertuoja pusės pločio ASCII ir katakana ženklus į viso pločio . Grąžina tekstinę eilutę.
Spustelėkite https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions, kad pamatytumėte perskaičiavimo lentelę.
JIS ("tekstas")
Tekstas – tekstas, kuriame yra konvertuojami ženklai.
Taip pat skaitykite apie ASC funkciją.
Grąžina pirmą ženklą ar ženklus, ar tekstą.
LEFT("tekstas" [; skaičius])
Tekstas – tekstas, kuriame reikia nustatyti nepilną žodį.
Skaičius (papildomas) – nurodomas ženklų skaičius. Jei šis parametras nenurodytas, funkcija grąžina vieną ženklą.
=LEFT("išvestis";2) grąžina „iš”.
Grąžina pirmą DBCS teksto ženklą.
LEFTB("tekstas" [; baitų skaičius])
Tekstas – tekstas, kuriame reikia nustatyti nepilną žodį.
Baitai (papildomas) – nurodomas ženklų, kuriuos norite ištraukti, skaičius baitais. Jei šis parametras nenurodytas, funkcija grąžina vieną ženklą.
=LEFTB("中国";1) grąžina „ “ (1 baitas yra tik pusė DBCS ženklo. Todėl grąžinamas tarpo ženklas).
=LEFTB("中国";2) grąžina „中“ (2 baitai apima vieną DBCS ženklą).
=LEFTB("中国";3) grąžina „中 “ (3 baitai apima vieną su puse DBCS ženklo. Todėl vietoj pusės antrojo ženklo grąžinamas tarpo ženklas).
=LEFTB("中国";4) grąžina „中国“ (4 baitai apima du DBCS ženklus).
=LEFTB("perėja";3) grąžina "per" (kiekvienas ženklas užima vieną baitą).
Grąžina eilutės ilgį įskaitant tarpus.
LEN("tekstas")
Tekstas – tekstas, kurio ilgis skaičiuojamas.
=LEN("Labas vakaras") grąžina 13.
=LEN(12345.67) grąžina 8.
Funkcija skirta dviejų baitų kalboms (DBCS). Grąžina eilutės ilgį baitais.
LENB("tekstas")
Tekstas – tekstas, kurio ilgis skaičiuojamas.
=LENB("中") grąžina 2 (1 DBCS ženklas užima 2 baitus).
=LENB("中国") grąžina 4 (1 DBCS ženklas užima 2 baitus).
=LENTB("perėja") grąžina 6 (kiekvienas kalbos ženklas užima vieną baitą).
=LENB("Labas vakaras") grąžina 13.
=LENB(12345.67) grąžina 8.
Konvertuoja visas didžiąsias raides tekste į mažąsias.
LOWER("tekstas")
Tekstas 1 – konvertuojamo teksto nuoroda.
=LOWER("SaULė") grąžina „saulė“.
Grąžina teksto eilutę. Parametras nurodo, nuo kurios eilutės vietos pradedamas konvertavimas.
MID("tekstas"; pradžia; skaičius)
Tekstas – teksto eilutė, kuri ar kurios dalis konvertuojama.
Pradžia – pirmojo ženklo, nuo kurio pradedamas konvertavimas, vieta.
Skaičius – ženklų, kurie bus konvertuojami, skaičius.
=MID("mėnulis";2;2) grąžina „ėn“
Grąžina DBCS teksto eilutę. Parametras nurodo, nuo kurios eilutės vietos pradedamas konvertavimas ir kiek ženklų bus konvertuojama.
MIDB("tekstas"; pradžia; baitai)
Tekstas – teksto eilutė, kuri ar kurios dalis konvertuojama.
Pradžia – pirmojo ženklo, nuo kurio pradedamas konvertavimas, vieta.
Baitai – nurodomas grąžinamas ženklų skaičius baitais.
=MIDB("中国";1;0) grąžina „“ (0 baitų eilutė yra tuščia).
=MIDB("中国";1;1) grąžina „ “ (1 baitas yra tik pusė DBCS ženklo, todėl grąžinama tuščia eilutė).
=MIDB("中国";2) grąžina „中“ (2 baitai apima vieną DBCS ženklą).
=MIDB("中国";1;3) grąžina „中 “ (3 baitai apima pusantro DBCS ženklo, todėl grąžina visą ženklą ir tarpo ženklą)
=MIDB("中国";4) grąžina „中国“ (4 baitai apima du DBCS ženklus).
=MIDB("中国";2;1) grąžina „ “ (nurodyta skaitymo pradžia 2 rodo pirmojo ženklo antrą pusę ir skaityti reikia tik pusę ženklo, todėl grąžina tarpo ženklą).
=MIDB("中国";2;2) grąžina „国“ (nurodyta skaitymo pradžia 2 rodo pirmojo ženklo antrą pusę, skaityti nurodyta 2 baitus, tai reiškia, kad skaityti reikia pirmojo ženklo pusę ir antrojo ženklo pusę, todėl grąžina tarpo ženklą)
=MIDB("中国";2;3) grąžina „国“ (nurodyta skaitymo pradžia 2 rodo pirmojo ženklo antrą pusę, skaityti reikia pusantro ženklo, todėl grąžinamas tarpo ženklas ir antrasis DBCS ženklas).
=MIDB("中国";3;1) grąžina „ “ (pagal nurodytus parametrus skaityti reikia pusę DBCS ženklo, todėl grąžinamas tarpo ženklas).
=MIDB("中国";3;2) grąžina „国“ (pagal nurodytus parametrus skaityti reikia vieną DBCS ženklą pradedant nuo antrojo ženklo, todėl grąžinamas antrasis ženklas)
=MIDB("saulė";2;3) grąžina „ulė" (skaito nuo 2 ženklo 3 ženklus).
Pirmąsias visų eilutės žodžių raides pakeičia didžiosiomis.
PROPER("tekstas")
Tekstas – konvertuojamo teksto nuoroda.
=PROPER("dokumento paieška") grąžina frazę „Dokumento Paieška“.
Pakeičia nurodytą teksto eilutės dalį kita teksto eilute. Ši funkcija naudojama visiems ženklams (jie automatiškai konvertuojami į tekstą). Funkcijos rezultatas visada yra tekstas. Jei vėliau norėsite gautus skaitinius ženklus naudoti skaičiavimuose, tai turėsite konvertuoti juos į skaičių formatą naudodami VAlUE funkciją.
Tekstas, kuriame yra skaičių, turi būti rašomas tarp angliškų kabučių, jei norite, kad jis būtų automatiškai konvertuojamas į teksto formatą.
REPLACE("tekstas"; vieta; ilgis; "naujas tekstas")
Tekstas – teksto, kurio dalis bus keičiama, nuoroda.
Vieta – teksto vieta, nuo kurios bus pradedamas keitimas.
Ilgis – keičiamų ženklų tekste skaičius.
Naujas tekstas – teksto, į kurį bus keičiamas nurodyta teksto dalis, nuoroda.
=REPLACE("1234567";1;1;"444") grąžina „444234567“. Į naują tekstą 444 keičiamas pirmasis nurodyto teksto ženklas.
Pakartoja ženklų eilutę nurodytą skaičių kartų.
REPT("tekstas"; skaičius)
Tekstas – tekstas, kurio kopijos kuriamos.
Skaičius – teksto kopijų skaičius.
Funkcijos rezultatas gali turėti daugiausia 255 ženklus.
=REPT("Labas rytas";2) grąžina „Labas rytasLabas rytas“.
Grąžina paskutinį teksto ženklų ženklą.
RIGHT("tekstas" [; skaičius])
Tekstas – tekstas, kurio dešinioji pusė bus grąžinta.
Skaičius (papildomas) – ženklų, kurie bus grąžinti, skaičius.
=RIGHT("Saulė";2) grąžina „lė“.
Grąžina nurodytą baitų skaičių DBCS ženklų eilutės dešinės dalies paskutinių ženklų.
RIGHTB("tekstas" [; baitų skaičius])
Tekstas – tekstas, kurios dešinioji pusė bus grąžinta.
Baitai (papildomas) – nurodoma baitais, kiek paskutinių dešinės eilutės dalies ženklų funkcija grąžina.
=RIGHTB("中国";1) grąžina „ “ (nurodyta grąžinti pusę DBCS ženklo, todėl grąžinamas tarpo ženklas).
=RIGHTB("中国";2) grąžina „国“ (2 baitai apima vieną DBCS ženklą).
=IGHTB("中国";3) grąžina „ 国“ (3 baitai apima pusantro DBCS ženklo, todėl grąžinamas tarpas vienas ženklas).
=RIGHTB("中国";4) grąžina „中国“ (4 baitai apima du DBCS ženklus).
=RIGHTB("perėja";3) grąžina "per" (kiekvienas ženklas užima vieną baitą).
Konvertuoja skaičių į romėniškus skaičius. Reikšmė turi būti tarp 0 ir 3999, metodas gali būti sveikasis skaičius nuo 0 iki 4.
ROMAN(skaičius [; veiksena])
Skaičius – į romėnišką skaičių konvertuojama skaitinė reikšmė.
Metodas (papildomas) – supaprastinimo laipsnis. Kuo didesnis metodo skaičius, tuo didesnis romėniško skaičiaus supaprastinimas.
=ROMAN(999) grąžina CMXCIX
=ROMAN(999;0) grąžina CMXCIX
=ROMAN(999;1) grąžina LMVLIV
=ROMAN(999;2) grąžina XMIX
=ROMAN(999;3) grąžina VMIV
=ROMAN(999;4) grąžina IM
Grąžina nurodytos tekstinės eilutės vietą. Galite papildomai nurodyti paieškos pradžios vietą. Ieškomas tekstas gali būti skaitinė arba bet kokia ženklų seka. Funkcija nekreipia dėmesio į didžiąsias ir mažąsias raides. Jei teksto neranda, grąžina 519 klaidos pranešimą (#VALUE).
SEARCH("rasti tekstą"; "tekstas" [; vieta])
Ieškomas tekstas – tekstas, kuris bus ieškomas.
Tekstas – tekstinė paieškos sritis.
Vieta (papildomas) – vieta tekste, nuo kurios pradedama paieška.
=SEARCH(54;998877665544) grąžina 10.
Pakeičia seną tekstą nauju.
SUBSTITUTE("tekstas"; "paieškos tekstas"; "naujas tekstas" [; tikslumas])
Tekstas – tekstas, kurio dalis bus pakeista.
Ieškomas tekstas – teksto dalis, kuri bus keičiama (kiek kartų bus keičiama).
Naujas tekstas – tekstas, kuriuo bus pakeistas surastas tekstas.
Tikslumas (papildomas) – nustato, kiek kartų surastas tekstas bus keičiamas. Jei šis parametras nenurodytas, keičiamas visas surastas tekstas.
=SUBSTITUTE("123123123";"3";"abc") grąžina „12abc12abc12abc“.
=SUBSTITUTE("123123123";"3";"abc";2) grąžina „12312abc123“
Ši funkcija grąžina ieškomą tekstą ar tuščią eilutę, jei tekstas nerastas.
T(reikšmė)
Jei reikšmė yra teksto eilutė arba teksto srities nuoroda, tai T grąžina teksto eilutę. Kitu atveju grąžina tuščią teksto eilutę.
=T(12345) grąžina tuščią eilutę.
=T("12345") grąžina eilutę „12345“.
Reikšmes konvertuoja į nurodyto formato tekstą.
TEXT(reikšmė; formatas)
Reikšmė – konvertuojama tekstinė arba skaitinė reikšmė.
Formatas – tekstas, kuris apibrėžia formatą. Naudokite dešimtainius ar tūkstančių skirtukus kaip numatyta formatuojamo langelio kalboje.
=TEXT(12,34567;"###,##") grąžina tekstą „12,35“
=TEXT(12,34567;"000,00") grąžina tekstą „012,35“
=TEXT("xyz";"=== @ ===") grąžina tekstą === xyz ===
Taip pat skaitykite Skaičių formatų kodai: vartotojų apibrėžtų formatų kodai.
Pašalina eilutėje nereikalingus tarpus, palieka tik po vieną tarpą tarp žodžių.
TRIM ("tekstas")
Tekstas – tekstas, kuriame bus šalinami tarpai.
=TRIM(" Sveikas, pasauli! ") grąžina „Sveikas, pasauli!“ be tarpų. Palieka tik tarpą tarp žodžių.
Konvertuoja kodo skaičių į Unikodą arba raidę.
UNICHAR(skaičius)
=UNICHAR(169) grąžina autorių teisių ženklą ©.
Taip pat skaitykite apie funkciją UNICODE().
Grąžina pirmojo Unikodo ženklo tekstinėje eilutėje skaitinę reikšmę.
UNICODE("tekstas")
=UNICODE("©") grąžina autorių teisių ženklo Unikodo skaitinę reikšmę 169.
Taip pat skaitykite apie funkciją UNICHAR().
Konvertuoja eilutę tekstiniame laukelyje į eilutę, kurios visi ženklai užrašomi didžiosiomis raidėmis.
UPPER("tekstas")
Tekstas – nurodomas tekstas, kurį norite pakeisti didžiosiomis raidėmis.
=UPPER("Labas rytas") grąžina „LABAS RYTAS“.
Konvertuoja tekstinę eilutę į skaitinę.
VALUE("tekstas")
Tekstas – konvertuojamas tekstas.
=VALUE("4321") grąžina 4321.