Função MÉDIA.SE.S

Devolve a média aritmética de um intervalo de células que cumprem um determinado conjunto de condições ou critérios. A função MÉDIA.SE.S soma todos os valores que cumpram o teste e divide essa soma pelo número de valores selecionados.

tip

Esta função está disponível desde o LibreOffice 4.0


Sintaxe

MÉDIA.SE.S(intervalo_func; intervalo1; critério1 [ ; intervalo2; critério2 [;...]]))

intervalo_média - argumento obrigatório. É o intervalo de células, um nome de intervalo ou a etiqueta de uma coluna ou linha que contém os valores para calcular a média.

critério1 – obrigatório. Uma expressão de texto representando uma condição lógica, ou uma referência de contendo uma expressão de texto. A expressão pode conter texto, números, expressões regulares ou caracteres universais (se estas estiverem ativadas nas opções de cálculo).

intervalo2 – Opcional. intervalo2 e todos os seguintes têm o mesmo significado que intervalo1.

critério2 – Opcional. critério2 e todos os seguintes têm mesmo significado que critério1.

Ícone de aviso

Intervalo_Func e intervalo1, intervalo2... devem ter o mesmo tamanho, senão a função devolve err:502 - argumento inválido.


Ícone de nota

A relação lógica entre os critérios pode ser definida como E lógico (conjunção). Em outras palavras, se e apenas se todos os critérios são verificados, um valor da célula correspondente ao intervalo intervalo_func é computada.


A função pode ter até 255 argumentos, significando que pode haver 127 intervalos de critérios e critérios correspondentes.

Ícone de aviso

Se a célula contiver VERDADEIRO, será tratada como 1 e se contiver FALSO, será tratada como 0 (zero).


Ícone de nota

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).


Exemplo

Considere a seguinte tabela

A

B

C

1

Nome do produto

Vendas

Rendimento

2

pencil

20

65

3

pen

35

85

4

caderno

20

190

5

book

17

180

6

pencil-case

não

não


Ícone de aviso

Em todos os exemplos abaixo, os intervalo de cálculo contêm a linha n.º 6, que é ignorada por que contém texto.


Utilização

=MÉDIA.SE.S(B2:B6;B2:B6;">=20")

Calcula a média para os valores do intervalo B2:B6 que são maiores ou iguais a 20. Devolve 25, uma vez que a quinta linha não cumpre o critério.

=MÉDIA.SE.S(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcula a média para os valores do intervalo C2:C6 que são maiores que 70 e que correspondem às células de B2:B6 com valores maiores ou iguais a 20. Devolve 137,50 uma vez que a segunda e a quinta linha não cumprem pelo menos um dos critérios.

Utilizar expressões regulares e funções incorporadas

=MÉDIA.SE.S(C2:C6;B2:B6;">"&MÍNIMO(B2:B6);B2:B6;"<"&MÁXIMOB2:B6))

Calcula a média dos valores no intervalo C2:C6 que coincidam com todos os valores no intervalo B2:B6, exceto os valores máximo e mínimo. Devolve 127,5 uma vez que a terceira e a quinta linha não cumprem, pelo menos, um dos critérios.

=MÉDIA.SE.S(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a média dos valores do intervalo C2:C6 que correspondem a todos os valores do intervalo A2:A6 que começam com as letras "pen" e todas as células do intervalo B2:B6, exceto seu máximo. Devolve 65 porque apenas a segunda linha cumpre todos os critérios.

Referência a uma célula como critério

Se quiser alterar o critério facilmente, pode especificar o critério numa célula distinta e utilizar uma referência a esta célula como condição da função MÉDIA.SE.S. Por exemplo, a função acima pode ser escrita da seguinte forma:

=MÉDIA.SE.S(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2 = pen, a função devolve 65, uma vez que a ligação à célula é substituída pelo seu conteúdo.