timeinsts
Prev | Orchestra Opcodes and Operators | Next

## timeinsts

timeinsts — Read absolute time in seconds.

## Description

Read absolute time, in seconds, since the start of an instance of an instrument.

## Syntax

    kres timeinsts

## Performance

Time in seconds is available with timeinsts. This would return 0.5 after half a second.

timeinsts produces a k-rate variable for output. There are no input parameters.

timeinsts is similar to times except it returns the time since the start of this instance of the instrument.

## Examples

Here is an example of the timeinsts opcode. It uses the file timeinsts.csd.

Example 1027. Example of the timeinsts opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o timeinsts.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    giSine ftgen 0, 0, 2^10, 10, 1

    instr 1

    kvib init 1
    ktim timeinsts				;read time

    if ktim > 2 then			;do something after 2 seconds
       kvib oscili 2, 3, giSine		;make a vibrato
    endif

    asig poscil .5, 600+kvib, giSine	;add vibrato
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 5
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

timeinstk, timek, times

## Credits

Author: Robin Whittle
Australia
May 1997

Prev | Up | Next
timeinstk | Home | timek