vmult
Prev | Orchestra Opcodes and Operators | Next

## vmult

vmult — Multiplies a vector in a table by a scalar value.

## Description

Multiplies a vector in a table by a scalar value.

## Syntax

    vmult  ifn, kval, kelements [, kdstoffset] [, kverbose]

## Initialization

ifn - number of the table hosting the vectorial signal to be processed

## Performance

kval - scalar value to be multiplied

kelements - number of elements of the vector

kdstoffset - index offset for the destination table (Optional, default = 0)

kverbose - Selects whether or not warnings are printed (Default=0)

vmult multiplies each element of the vector contained in the table ifn by kval, starting from table index kdstoffset. This enables you to process a specific section of a table by specifying the offset and the number of elements to be processed. Offset is counted starting from 0, so if no offset is specified (or set to 0), the table will be modified from the beginning.

Note that this opcode runs at k-rate so the value of kval is multiplied every control period. Use with care or you will end up with very large numbers (or use vmult_i).

These opcodes (vadd, vmult, vpow and vexp) perform numeric operations between a vectorial control signal (hosted by the table ifn), and a scalar signal (kval). Result is a new vector that overrides old values of ifn. All these opcodes work at k-rate.

Negative values for kdstoffset are valid. Elements from the vector that are outside the table, will be discarded, and they will not wrap around the table.

If the optional kverbose argument is different to 0, the opcode will print warning messages every k-pass if table lengths are exceeded.

In all these opcodes, the resulting vectors are stored in ifn, overriding the initial vectors. If you want to keep initial vector, use vcopy or vcopy_i to copy it in another table. All these operators are designed to be used together with other opcodes that operate with vectorial signals such as vcella, adsynt, adsynt2, etc. They can also be useful in conjunction with the spectral opcodes pvsftw and pvsftr.

| Note
Please note that the elements argument has changed in version 5.03 from i-rate to k-rate. This will change the opcode's behavior in the unusual cases where the i-rate variable ielements is changed inside the instrument, for example in:
        instr 1
    ielements  =        10
               vadd     1, 1, ielements
    ielements  =        20
               vadd     2, 1, ielements
               turnoff
        endin

## Example

Here is an example of the vmult opcode. It uses the file vmult-2.csd.

Example 1109. Example of the vmult opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o cigoto.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr=44100
    ksmps=128
    nchnls=2

    	instr 1
    ifn1 = p4
    ival = p5
    ielements = p6
    idstoffset = p7
    kval init 25
    vmult ifn1, ival, ielements, idstoffset, 1
    	endin

    	instr 2	;Printtable
    itable = p4
    isize = ftlen(itable)
    kcount init 0
    kval table kcount, itable
    printk2 kval

    if (kcount == isize) then
      turnoff
    endif

    kcount = kcount + 1
    	endin

    </CsInstruments>

    <CsScore>

    f 1 0 16 -7 1 16 17

    i2	0.0	0.2	1
    i1	0.4	0.01	1	2	3	4
    i2	0.8	0.2	1
    i1	1.0	0.01	1	0.5	5	-3
    i2	1.2	0.2	1
    i1	1.4	0.01	1	1.5	10	12
    i2	1.6	0.2	1
    e

    </CsScore>

    </CsoundSynthesizer>

Here is another example of the vmult opcode. It uses the file vmult.csd.

Example 1110. Example of the vmult opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o cigoto.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr=44100
    kr=4410
    ksmps=10
    nchnls=2

    	instr 1 ;table playback
    ar lposcil 1, 1, 0, 262144, 1
    outs ar,ar
    	endin

    	instr 2
    vcopy 2, 1, 40000 ;copy vector from sample to empty table
    vmult 5, 10000, 262144 ;scale noise to make it audible
    vcopy 1, 5, 40000 ;put noise into sample
    turnoff
    	endin

    	instr 3
    vcopy 1, 2, 40000 ;put original information back in
    turnoff
    	endin

    </CsInstruments>
    <CsScore>
    f1  0 262144   -1 "beats.wav" 0 4 0
    f2  0 262144   2  0

    f5  0 262144   21  3 30000

    i1 0 4
    i2 3 1

    s
    i1 0 4
    i3 3 1
    s

    i1 0 4

    </CsScore>
    </CsoundSynthesizer>

## See also

vadd_i, vadd_i, vmult, vpow and vexp.

## Credits

Written by Gabriel Maldonado. Optional arguments added by Andres Cabrera and Istvan Varga.

Example by Andres Cabrera.

New in Csound 5 (Previously available only on CsoundAV)

Prev | Up | Next
vmirror | Home | vmult_i