getrow
Prev | Orchestra Opcodes and Operators | Next

## getrow

getrow — Gets a given row from a 2-dimensional array as a vector.

## Description

Gets a given row from a 2-dimensional array. The output is an 1-d array with the contents of the requested row

## Syntax

    i/kout[] getrowi/kin[],i/krow

## Initialization

iout[] -- output array containing the extracted row. It will be created if it does not exist.

iin[] -- input 2-dimensional array.

irow -- row to be extracted.

## Performance

kout[] -- output array containing the extracted row. It will be created if it does not exist.

kin[] -- input 2-dimensional array.

krow -- row to be extracted.

## Examples

Here is an example of the getrow opcode. It uses the file rfft.csd.

Example 397. Example of the getrow opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>

    <CsOptions>
    -d -o dac
    </CsOptions>

    <CsInstruments>
    ;ksmps needs to be an integer div of hopsize
    ksmps = 64
    0dbfs=1

    instr 1

     ihopsize = 256   ; hopsize
     ifftsize = 1024  ; FFT size
     iolaps = ifftsize/ihopsize ; overlaps
     ibw = sr/ifftsize ; bin bandwidth
     kcnt init 0    ; counting vars
     krow init 0

     kOla[] init ifftsize ; overlap-add buffer
     kIn[] init ifftsize  ; input buffer
     kSw[] init ifftsize
     kOut[][] init iolaps, ifftsize ; output buffers

     a1 diskin2 "fox.wav",1,0,1 ; audio input
     ks  expon  100, p3, 1000
     asw vco2  0.15, ks

     /* every hopsize samples */
     if kcnt == ihopsize then
       /* window and take FFT */
       kWin[] window kIn,krow*ihopsize
       kSpec[] rfft kWin
       kWin window kSw,krow*ihopsize
       kSpec2[] rfft kWin
       kProd[] cmplxprod kSpec, kSpec2

       /* IFFT + window */
       kRow[] rifft kProd + kSpec
       kWin window kRow, krow*ihopsize
       /* place it on out buffer */
       kOut setrow kWin, krow

       /* zero the ola buffer */
       kOla = 0
       /* overlap-add */
       ki = 0
       until ki == iolaps do
         kRow getrow kOut, ki
         kOla = kOla + kRow
         ki += 1
       od

      /* update counters */
      krow = (krow+1)%iolaps
      kcnt = 0
     endif

     /* shift audio in/out of buffers */
     kIn shiftin a1
     kSw shiftin asw
     a2 shiftout kOla
        out a2/iolaps

     /* increment counter */
     kcnt += ksmps

    endin

    </CsInstruments>

    <CsScore>
    i1 0 10
    </CsScore>

    </CsoundSynthesizer>

## See Also

Vectorial opcodes array opcodes

## Credits

Author: Victor Lazzarini
NUI Maynooth
2014

New in version 6.04

Prev | Up | Next
getftargs | Home | getrowlin