vlowres
Prev | Orchestra Opcodes and Operators | Next

## vlowres

vlowres — A bank of filters in which the cutoff frequency can be separated under user control.

## Description

A bank of filters in which the cutoff frequency can be separated under user control

## Syntax

    ares vlowres asig, kfco, kres, iord, ksep

## Initialization

iord -- total number of filters (1 to 10)

## Performance

asig -- input signal

kfco -- frequency cutoff (not in Hz)

kres -- resonance amount

ksep -- frequency cutoff separation for each filter: the first filter has a kfreq cutoff, the second has a kfreq + ksep and the third kfreq + 2*ksep and so on, depending on the number of filters.

vlowres (variable resonant lowpass filter) allows a variable response curve in resonant filters. It can be thought of as a bank of lowpass resonant filters, each with the same resonance, serially connected. The frequency cutoff of each filter can vary with the kcfo and ksep parameters.

## Examples

Here is an example of the vlowres opcode. It uses the file vlowres.csd.

Example 1107. Example of the vlowres opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o vlowres.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kamp init p4
    asig vco2  kamp, 110			;saw wave
    kfco line 30, p3, 300			;vary the cutoff frequency from 30 to 300 Hz.
    kres = 20
    ksep = p5				;different resonance values
    iord = p6				;and different number of filters
    aout vlowres asig, kfco, kres, iord, ksep
    aclp clip aout, 1, 1			;avoid distortion
         outs aclp, aclp

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1	;sine

    s
    i 1 0 10 .1 5  2	;compensate volume and
    i 1 + 10 .1 25 2	;number of filters = 2
    s
    i 1 0 10 .01 5  6	;compensate volume and
    i 1 + 10 .04 15 6	;number of filters = 6

    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Gabriel Maldonado
Italy

New in Csound version 3.49

Prev | Up | Next
vlinseg | Home | vmap