İçerikler
Dizin 🔎︎

# BİRİKİM fonksiyonu

Bu işlev, aralıktaki hesaplamaların bir toplam sonucunu döndürür. Aşağıda listelenen farklı toplama işlevlerini kullanabilirsiniz. Toplama işlevi, hesaplamada gizli satırları, hataları, ALTTOPLAM ve diğer BİRİKİM işlev sonuçlarını çıkarmanızı sağlar.

BİRİKİM işlevi, etkin Otomatik Filtre ile dikey verilere uygulanır. Otomatik Filtre etkinleştirilmemişse, yeni gizli satırlar için işlev sonucunun otomatik olarak yeniden hesaplanması işe yaramaz. Yatay aralıklarla çalışılması gerekmemektedir, ancak sınırlamalarla bunlara da uygulanabilir. Özellikle, yatay bir veri aralığına uygulanan BİRİKİM işlevi, gizlenen sütunlarını tanımadığından satırlara gömülmüş ALTTOPLAM ve diğer BİRİKİM işlevlerinin hatalarını ve sonuçlarını doğru olarak alamaz.

This function is available since LibreOffice 4.4

### Syntax

AGGREGATE(Fonksiyon; Seçenek; Ref1 [; Ref2 [; …]])

veya

AGGREGATE(Fonksiyon; Seçenek; Dizi [; k])

Fonksiyon – zorunlu bir ifadedir. Aşağıdaki tabloya göre 1 ile 19 arasında değer alabilen bir fonksiyon dizini veya bir hücreye başvuru.

İşlev dizini | Uygulanan fonksiyon
1 | ORTALAMA
2 | BAĞ_DEĞ_SAY
3 | BAĞ_DEĞ_DOLU_SAY
4 | MAK
5 | MİN
6 | ÇARPIM
7 | STDSAPMA.S
8 | STDSAPMA.P
9 | TOPLA
10 | VAR.S
11 | VAR.P
12 | ORTANCA
13 | ENÇOK_OLAN.TEK
14 | BÜYÜK
15 | KÜÇÜK
16 | YÜZDEBİRLİK.HDL
17 | DÖRTTEBİRLİK.DHL
18 | YÜZDEBİRLİK.HRC
19 | DÖRTTEBİRLİK.HRC

Seçenek – zorunlu bağımsız değişken. Hücreye yapılan 0 ile 7 aralığında bir dizin seçeneği veya başvuru, belirlenen işlev için mevcut aralıkta nelerin yoksayılacağını belirler.

Seçenek dizini | Seçenek uygulandı
0 | Sadece iç içe ALTTOPLAM ve TOPLAM fonksiyonlarını yoksay
1 | Sadece gizli satırları, iç içe ALTTOPLAM ve TOPLAM fonksiyonlarını yoksay
2 | Sadece hataları, iç içe ALTTOPLAM ve TOPLAM fonksiyonlarını yoksay
3 | Sadece gizli satırları, hataları, iç içe ALTTOPLAM ve TOPLAM fonksiyonlarını yoksay
4 | Hiçbir şeyi yoksayma
5 | Sadece gizli satırları yoksay
6 | Sadece hataları yoksay
7 | Sadece gizli satırları ve hataları yoksay

Ref1 – zorunlu argüman. İlk sayısal değişken (aralık, işlev içindeki değerler listesiyle ayarlanırsa) veya onu içeren bir hücreye yapılan bir başvurudur.

Ref2, 3, ... – seçimsel. Toplam değere ihtiyacınız olan sayısal bir argüman veya bir hücrenin referansı (en fazla 253 argüman).

Dizi – zorunlu argüman. Dizi, aralığın sınırları, adlandırılmış aralığın adı veya sütun etiketiyle belirtilebilir.

Sütun etiketlerini kullanmak için "Sütunları ve satırları otomatik olarak bul" işlevinin etkinleştirilmesi gerekir.

k – bu işlevler için zorunlu argüman: BÜYÜK, KÜÇÜK, YÜZDEBİRLİK.DHL, DÖRTTEBİRLİK.DHL, YÜZDEBİRLİK.HRC, DÖRTTEBİRLİK.HRC. Bu işlevlerin ikinci argümanına karşılık gelen sayısal bir argümandır.

### Example

| A | B | C
1 | SütunBir | Sütunİki | SütunÜç
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VALUE! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=BİRİKİM(4;2;A2:A9)
A2:A9 = 34 aralığındaki en büyük değeri döndürür, =MAK(A2:A9) ise Err:511 hatasını verir.

=BİRİKİM(9;5;A5:C5)
bazı sütunlar gizli olmasına rağmen A5:C5 = 29 sonucunu döndürür.

=BİRİKİM(9;5;B2:B9)
B sütununun toplamı olan 115'i döndürür. Herhangi bir satır gizliyse, fonksiyon bu değeri atlar, örneğin 7. satır gizliyse, fonksiyon 95 değerini döndürür.

İşlevi 3 boyutlu bir aralıkla uygulamak istiyorsanız, bu örnek nasıl yapılacağını gösterir.

=BİRKİM(13;3;Sheet1.B2:B9:Sheet3.B2:B9)
Fonksiyon, ikinci sütunların değerlerini, sayfa 1:3 (aynı verilere sahip) yoluyla 8 döndürür.

Formüldeki her bağımsız değişken için bir hücreye veya aralığa başvuru kullanabilirsiniz. Aşağıdaki örnek, nasıl çalıştığını gösterir. Ayrıca, bir dizi belirtmek için sütun etiketlerini kullanabileceğinizi gösterir.

=BİRİKİM(E3;E5;'ColumnOne')
Eğer E3 = 13 and E5 = 5 ise, fonksiyon ilk sütunun modunu = 10 olarak döndürür.

İlgili Konular

ORTALAMA, BAĞ_DEĞ_SAY, BAĞ_DEĞ_DOLU_SAY, MAK, MİN, ÇARPIM, STDSAPMA.S, STDSAPMA.P, TOPLA, VAR.S, VAR.P, ORTANCA, ENÇOK_OLAN.TEK, BÜYÜK, KÜÇÜK, YÜZDEBİRLİK.DHL , DÖRTTEBİRLİK.DHL, YÜZDEBİRLİK.HRC, DÖRTTEBİRLİK.HRC

Sütun ve satır etiketlerini otomatik olarak bul