Modul
Indhald
Innhaldsliste 🔎︎

## GJENNOMSNITT.VISS.SETT-funksjonen

Returnerer det aritmetiske gjennomsnittet av eit område som oppfyller fleire kriteria. Funksjonen GJENNOMSNITT.VISS.SETT legg saman alle resultata som oppfyller den logiske testen og dividerer denne summen med talet på merkte verdiar.

### Syntaks

GJENNOMSNITT.VISS.SETT(Funksjons_område; Område1; Kriterium1 [ ; Område2; Kriterium2 [;...]]))

Funksjonsområde – nødvendig argument. Dette kan vera eit celleområde, namnet på eit namngjeve område eller etiketten på ei rad eller ein kolonne som inneheld verdiar som vert brukte for å rekna ut gjennomsnittet.

Kriterium1 må ha eit argument. Eit strenguttrykk som representerer eit logisk vilkår eller ein cellereferanse til eit slikt uttrykk. Uttrykket kan innehalda tekst, tal, regulære uttrykk eller jokerteikn (viss det er opna for desse i innstillingane for utrekningane).

Område2 – Valfri. Område2 og alle dei følgjande tyder det same som Område1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfølgjande betyr det same som Kriterium1.

Funksjonsområde og Område1, Område2 … må vera av same storleik. Elles returnerer funksjonen feil:502 - ugyldig argument.

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frå den tilsvarande cella i det gjevne Funksjons_område tatt med i utrekningane.

Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieområde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)

### Eksempel

#### Studer denne tabellen

| A | B | C
1 | Produktnamn | Sal | Inntekt
2 | blyant | 20 | 65
3 | penn | 35 | 85
4 | notisbok | 20 | 190
5 | bok | 17 | 180
6 | penal | ikkje | ikkje

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.

#### Enkel bruk

=GJENNOMSNITT.VISS.SETT(B2:B6;B2:B6;">=20")

Reknar ut gjennomsnittet for verdiane i område B2:B6 som er større enn eller lik 20. Returnerer 25 fordi den femte rada ikkje oppfyller kriteriet.

=GJENNOMSNITT.VISS.SETT(C2:C6;B2:B6;">=20";C2:C6;">70")

Reknar ut gjennomsnittet for verdiane i område C2:C6 som er større enn 70 og som tilsvarer cellene i B2:B6 med verdiar større enn eller lik 20. Returnerer 137,5 fordi den andre og femte rada ikkje oppfyller minst eitt av kriteria.

#### Bruka regulære uttrykk og nøsta funksjonar

=GJENNOMSNITT.VISS.SETT(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Reknar ut gjennomsnittet for verdiane i område C2:C6 som svarar til alle verdiane i område B2:B6 unntatt den største og minste verdien. Returnerer 127,5 fordi den tredje og fjerde rada ikkje oppfyller minst eitt av kriteria.

=GJENNOMSNITT.VISS.SETT(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Reknar ut gjennomsnittet for verdiane i område C2:C6 som svarar til alle verdiane i område A2:A6 som byrjar med «pen» og for alle cellene i området B2:B6 unntatt maksimum. Returnerer 65 fordi berre den andre rada oppfyller alle kriteria.

#### Referanse til ei celle som kriterium

Dersom du ønskjer å lett kunna endra eit kriterium, kan du skrive dette inn i ei eige celle og bruke ein referanse til denne cella som kriterium i funksjonen GJENNOMSNITT.VISS.SETT. For eksempel kan funksjonen ovanfor skrivast slik:

=GJENNOMSNITT.VISS.SETT(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Viss E2 = pen vil funksjonen returnere 65 fordi lenkja til cella er bytt ut med innhaldet.

Liknande emne

GJENNOMSNITT, GJENNOMSNITTA, GJENNOMSNITTSAVVIK, GJENNOMSNITT.VISS

TAL.VISS.SETT, MINVISS.SANN, MAKSVISS.SANN, GJENNOMSNITT.VISS.SETT, SUMMER.VISS.SETT

Liste over regulære uttrykk