Contenido
Índice 🔎︎

## función CONTAR.SI.CONJUNTO

Returns the count of cells that meet criteria in multiple ranges.

Esta función está disponible desde LibreOffice 4.0

### Sintaxis

CONTAR.SI.CONJUNTO(Intervalo1; Criterio1 [;Intervalo2; Criterio2 [; …]])

Rango1 – argumento requerido. Es un rango de celdas, el nombre de un rango con nombre o la etiqueta de una columna o fila que contiene valores para contar y encontrar el criterio correspondiente.

Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Intervalo2: opcional. Intervalo2 y todos los argumentos siguientes tienen el mismo significado que Intervalo1.

Criterio2(opcional). Criterio2 y todos los argumentos siguientes tienen el mismo significado que Criterio1.

Range1, Range2, ... and Criterion1, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

La función puede tener hasta 255 argumentos, lo que significa que es posible especificar hasta 127 intervalos de criterios y sus criterios correspondientes.

Si una celda contiene VERDADERO se tratará como 1; si contiene FALSO, como 0 (cero).

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).

### Ejemplo

#### Tenga en cuenta la tabla siguiente

| A | B | C
1 | Nombre de producto | Ventas | Ingresos
2 | lápiz | 20 | 65
3 | pluma | 35 | 85
4 | cuaderno | 20 | 190
5 | libro | 17 | 180
6 | estuche | no | no

En todos los ejemplos siguientes, los intervalos utilizados para el cálculo incluyen la fila n.º 6, pero se ignorará debido a que contiene texto.

#### Uso simple

=CONTAR.SI.CONJUNTO(B2:B6;">=20")

Cuenta la cantidad de filas del intervalo B2:B6 con valores mayores o iguales que 20. Devuelve 3 porque las filas quinta y sexta no cumplen con el criterio.

=CONTAR.SI.CONJUNTO(B2:B6;">=20";C2:C6;">70")

Cuenta la cantidad de filas que contiene simultáneamente valores mayores que 70 en el intervalo C2:C6 y valores mayores o iguales que 20 en el intervalo B2:B6. Devuelve 2 porque las filas segunda, quinta y sexta no cumplen con al menos un criterio.

#### Uso de expresiones regulares y funciones anidadas

=CONTAR.SI.CONJUNTO(B2:B6;"[:alpha:]*")

Cuenta la cantidad de filas del intervalo B2:B6 que contienen solamente símbolos alfabéticos. Devuelve 1 porque solo la sexta fila cumple con el criterio.

=CONTAR.SI.CONJUNTO(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Contabiliza las filas en el intervalo B2:B6, excluyendo las filas con los valores mínimo y máximo de este intervalo. Devuelve 2, porque las filas tercera, quinta y sexta no cumplen con por lo menos un criterio.

=CONTAR.SI.CONJUNTO(A2:A6;"cla.*";B2:B6;"<"&MAX(B2:B6))

Cuenta la cantidad de filas que corresponde a todas las celdas del intervalo A2:A6 que comienzan por «cla» y a todas las celdas del intervalo B2:B6 con la excepción de su máximo. Devuelve 1 porque solo la segunda fila cumple con todos los criterios.

#### Referencia a una celda como criterio

Si se necesita cambiar un criterio fácilmente, se puede especificar en una celda separada y usar la referencia a esa celda en la condición de la función CONTAR.SI.CONJUNTO. Por ejemplo, la función anterior puede reescribirse así:

=CONTAR.SI.CONJUNTO(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2 = pen, la función devuelve 1, porque el link a la celda es sustituido con su contenido y funciona como la función anterior.

Temas relacionados

CONTAR, CONTAR.SI, CONTAR.BLANCO, CONTARA

CONTAR.SI.CONJUNTO, MINIFS, MAXIFS, PROMEDIO.SI.CONJUNTO, SUMAR.SI.CONJUNTO

Lista de expresiones regulares