Module
Contents
Index 🔎︎

# 數學函式

此分類包含 Calc 的 Mathematical 函式。若要開啟 [函式精靈]，請選擇 [插入] - [函式]。

## [text/scalc/01/func_aggregate.xhp#aggregate_head not found].

This function returns an aggregate result of the calculations in the range. You can use different aggregate functions listed below. The Aggregate function enables you to omit hidden rows, errors, SUBTOTAL and other AGGREGATE function results in the calculation.

## RAWSUBTRACT

Subtracts a set of numbers and gives the result without eliminating small roundoff errors.

## HOUR

Return a numeric value calculated by a combination of three colors (red, green and blue) and the alpha channel, in the RGBA color system. The result depends on the color system used by your computer.

## [text/scalc/01/func_sumifs.xhp#sumifs_head not found].

Returns the sum of the values of cells in a range that meets multiple criteria in multiple ranges.

## ABS

傳回數字的絕對值。

### 語法

ABS(number)

Number 是要計算其絕對值的數字。數字的絕對值是沒有 +/- 符號的數值。

### 範例

=ABS(-56) 傳回 56。

=ABS(12) 傳回 12。

=ABS(0) 傳回 0。

## ACOS

傳回一個數字的反餘弦值。

### 語法

ACOS(number)

此函式傳回 Number 的反三角反弦值，亦即反弦值為 Number 的角度 (弧度)。傳回的角度介於 0 與 PI 之間。

若要得出角度，請使用 DEGREES 函式。

### 範例

=ACOS(-1) 傳回 3.14159265358979 (PI 弧度)。

=DEGREES(ACOS(0.5)) 傳回 60。60 度的餘弦值為 0.5。

## ACOSH

傳回一個數字的反雙曲餘弦值。

### 語法

ACOSH(number)

此函式傳回 Number 的反雙曲餘弦值，亦即雙曲餘弦值為 Number 的數字。

數字必須大於或等於 1。

### 範例

=ACOSH(1) 傳回 0。

=ACOSH(COSH(4)) 傳回 4。

## ACOT

得出指定數字的反餘切值。

### 語法

ACOT(number)

此函式傳回 Number 的反三角餘切值，亦即餘切值為 Number 的角度 (弧度)。傳回的角度介於 0 與 PI 之間。

若要得出角度，請使用 DEGREES 函式。

### 範例

=ACOT(1) 傳回 0.785398163397448 (PI/4 弧度)。

=DEGREES(ACOT(1)) 傳回 45。45 度的正切值為 1。

## ACOTH

傳回指定數字的反餘切雙曲線。

### 語法

ACOTH(number)

此函式傳回 Number 的反雙曲餘切值，亦即雙曲餘切值為該數目的數字。

若 Number 介於 -1 與 1 之間，則會發生錯誤。

### 範例

=ACOTH(1.1) 傳回 1.1 的反雙曲餘切近似值 1.52226。

## ASIN

傳回一個數字的反正弦值。

### 語法

ASIN(Number)

此函式傳回 Number 的反三角正弦值，亦即正弦值為 Number 的角度 (弧度)。傳回的角度介於 -PI/2 與 +PI/2 之間。

若要得出角度，請使用 DEGREES 函式。

### 範例

=ASIN(0) 傳回 0。

=ASIN(1) 傳回 1.5707963267949 (PI/2 弧度)。

=DEGREES(ASIN(0.5)) 傳回 30。30 度的正弦值為 0.5。

## ASINH

傳回一個數字的反雙曲正弦值。

### 語法

ASINH(number)

此函式傳回 Number 的反雙曲正弦值，亦即雙曲正弦值為 Number 的數字。

### 範例

=ASINH(-90) 傳回近似值 -5.1929877。

=ASINH(SINH(4)) 傳回 4。

## ATAN

傳回一個數字的反正切值。

### 語法

ATAN(number)

此函式傳回 Number 的反三角正切值，亦即正切值為 Number 的角度 (弧度)。傳回的角度介於 -PI/2 與 PI/2 之間。

若要得出角度，請使用 DEGREES 函式。

### 範例

=ATAN(1) 傳回 0.785398163397448 (PI/4 弧度)。

=DEGREES(ATAN(1)) 傳回 45。45 度的正切值為 1。

## ATAN2

傳回指定的 x 與 y 座標的反正切值。

### 語法

ATAN2(NumberX; NumberY)

NumberX 是 X 座標的數值。

NumberY 是 Y 座標的數值。

ATAN2 傳回反三角正切值，亦即 X 軸與點 (NumberX, NumberY) 到原點間直線的角度 (弧度)。傳回的角度介於 -PI 與 PI 之間。

若要得出角度，請使用 DEGREES 函式。

### 範例

=ATAN2(20;20) 傳回 0.785398163397448 (PI/4 弧度)。

=DEGREES(ATAN2(12.3;12.3)) 傳回 45。45 度的正切值為 1。

## ATANH

傳回一個數字的反雙曲正切值。

### 語法

ATANH(number)

此函式傳回 Number 的反雙曲正切值，亦即雙曲正切值為 Number 的數字。

數字必須遵守條件：-1 < 數字 < 1。

### 範例

=ATANH(0) 傳回 0。

## CEILING

將一個數字向上捨入成最接近的基數之倍數。

### 語法

CEILING(Number; Significance; Mode)

Number 是要進位的數字。

Significance 是將數值向上捨入成其倍數的數字。

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

If the spreadsheet is exported to Microsoft Excel, the CEILING function is exported as the equivalent CEILING.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either CEILING.PRECISE that exists since Excel 2010, or CEILING.XCL that is exported as the CEILING function compatible with all Excel versions. Note that CEILING.XCL always rounds away from zero.

### 範例

=CEILING(-11;-2) 傳回 -10。

=CEILING(-11;-2;0) 傳回 -10。

=CEILING(-11;-2;1) 傳回 -12。

## CEILING.MATH

Rounds a number up to the nearest multiple of Significance.

### Syntax

CEILING.MATH(Number; Significance; Mode)

Number is the number that is to be rounded up.

Significance is the number to whose multiple the value is to be rounded up.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

This function exists for interoperability with Microsoft Excel 2013 or newer.

### Example

=CEILING.MATH(-10;-3) returns -9

=CEILING.MATH(-10;-3;0) returns -9

=CEILING.MATH(-10;-3;1) returns -12

## CEILING.PRECISE

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

### 語法

CEILING.PRECISE(Number; Significance)

Number 是要進位的數字。

Significance 是將數值向上捨入成其倍數的數字。

### 範例

=CEILING(-11;-2) 傳回 -10。

## CEILING.XCL

Rounds a number away from zero to the nearest multiple of Significance.

### Syntax

CEILING.XCL(Number; Significance)

Number is the number that is to be rounded.

Significance is the number to whose multiple the value is to be rounded.

This function exists for interoperability with Microsoft Excel 2007 or older versions.

### Example

=CEILING.XCL(1;3) returns 3

=CEILING.XCL(7;4) returns 8

=CEILING.XCL(-10;-3) returns -12

## COMBIN

傳回元素的組合數，不包含重複項目。

### 語法

COMBIN(Count1; Count2)

Count1 是資料集中的項目數。

Count2 是從資料集中選擇的項目數。

COMBIN 會得出選擇這些項目的順序方法數目。例如，若在集合中有 3 個項目 A、B 和 C，您可用 3 種不同的方法選擇 2 個項目，亦即 AB、AC 和 BC。

COMBIN 執行公式：Count1!/(Count2!*(Count1-Count2)!)

### 範例

=COMBIN(3;2) 傳回 3。

## COMBINA

傳回項目子集合的組合數，包含重複項目。

### 語法

COMBINA(Count1; Count2)

Count1 是資料集中的項目數。

Count2 是從資料集中選擇的項目數。

COMBINA 會得出選擇這些項目的唯一方法數目，而選擇的順序並不相關，且允許項目重複。例如，若在集合中有 3 個項目 A、B 和 C，您可用 6 種不同的方法選擇 2 個項目，亦即 AA、AB、AC、BB、BC 及 CC。

COMBINA 會執行公式：(Count1+Count2-1)! / (Count2!(Count1-1)!)

### 範例

=COMBINA(3;2) 傳回 6。

## CONVERT_OOO

將值從一個計量單位轉換為另一個計量單位。配置中的清單提供了轉換係數。

轉換係數的清單曾經包括舊歐洲貨幣和歐元 (請見以下示例)。建議您使用新函式 EUROCONVERT 轉換這些貨幣。

### 語法

CONVERT_OOO(value;"text";"text")

### 範例

=CONVERT_OOO(100;"ATS";"EUR") returns the Euro value of 100 Austrian Schillings.

=CONVERT_OOO(100;"EUR";"DEM") converts 100 Euros into German Marks.

## COS

得出指定角度 (弧度) 的餘弦值。

### 語法

COS(number)

傳回 Number 的 (三角) 餘弦值，用弧度表示角度。

若要以角度得出餘弦值，請使用 RADIANS 函式。

### 範例

=COS(PI()/2) 傳回 0，PI/2 弧度的餘弦值。

=COS(RADIANS(60)) 傳回 0.5，60 度的餘弦值。

## COSH

傳回一個數字的雙曲餘弦值。

### 語法

COSH(number)

得出 Number 的雙曲餘弦值。

### 範例

=COSH(0) 傳回 1，0 的雙曲餘弦值。

## COT

得出指定角度 (弧度) 的餘切值。

### 語法

COT(number)

得出 Number 的 (三角) 餘切值，此為弧度角度。

若要以角度得出餘切值，請使用 RADIANS 函式。

某個角度的餘切值相當於 1 除以該角度的正切值。

### 範例：

=COT(PI()/4) 傳回 1，PI/4 弧度的餘切值。

=COT(RADIANS(45)) 傳回 1，45 度的餘切值。

## COTH

傳回指定數字 (角度) 的雙曲餘切值。

### 語法

COTH(number)

傳回 Number 的雙曲餘切值。

### 範例

=COTH(1) 傳回 1 的雙曲餘切近似值 1.3130。

## CSC

回傳給定角度 (單位：弧度) 的餘割值。角度的餘割值等於 1 除以該角度的正弦值。

### 語法

COS(Number)

回傳 Number 的 (三角) 餘割，角度為弧度。

若要以度為單位回傳餘割值，請使用 RADIANS 函式。

### 範例

=CSC(PI()/4) 回傳大約 1.4142135624，即 PI/4 弧度正弦值的倒數。

=CSC(RADIANS(30)) 回傳 2，即 30 度的餘割值。

## CSCH

回傳數字的雙曲餘割值。

### 語法

CSCH(Number)

回傳 Number 的雙曲餘割值。

### 範例

=CSCH(1) 回傳值大約為 0.8509181282，即 1 的雙曲餘割值。

## DEGREES

將弧度轉換為角度。

### 語法

DEGREES(Number)

Number 是要轉換為度數的角度 (弧度)。

### 範例

=DEGREES(PI()) 傳回 180 度。

## EVEN

將正數向上捨入成最接近的偶數，將負數向下捨入成最接近的偶數。

### 語法

EVEN(Number)

傳回 (向著背離零的雙整數方向) 向上捨入為下一個偶數整數的 Number。

### 範例

=EVEN(2.3) 傳回 4。

=EVEN(2) 傳回 2。

=EVEN(0) 傳回 0。

=EVEN(-0.5) 傳回 -2。

## EXP

傳回增加為數字乘冪的 e。常數 e 的近似值為 2.71828182845904。

### 語法

EXP(Number)

Number 是以 e 為底數的乘冪。

### 範例

=EXP(1) 傳回 2.71828182845904，此為接近 Calc 精準度的數學常數 e。

## FACT

得出一個數的階乘。

### 語法

FACT(Number)

得出 Number!，此為 Number 的階乘，計算方式為 1*2*3*4* ... * Number。

=FACT(0) 按定義會傳回 1。

負數的階乘傳回「無效的引數」錯誤。

### 範例

=FACT(3) 傳回 6。

=FACT(0) 傳回 1。

## FLOOR

將一個數字向下捨入成最接近的基數之倍數。

### 語法

FLOOR(Number; Significance; Mode)

Number 是要捨去的數字。

Significance 是將數字捨入成其倍數的值。

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded towards zero. If the Mode value is equal to zero or is not given, negative numbers are rounded away from zero.

If the spreadsheet is exported to Microsoft Excel, the FLOOR function is exported as the equivalent FLOOR.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either FLOOR.PRECISE that exists since Excel 2010, or FLOOR.XCL that is exported as the FLOOR function compatible with all Excel versions. Note that FLOOR.XCL always rounds towards zero.

### 範例

=FLOOR( -11;-2) 傳回 -12。

=FLOOR( -11;-2;0) 傳回 -12。

=FLOOR( -11;-2;1) 傳回 -10。

## FLOOR.PRECISE

Rounds a number down to the nearest multiple of Significance, regardless of sign of Significance

### 語法

FLOOR.PRECISE(Number; Significance)

Number 是要捨去的數字。

Significance 是將數字捨入成其倍數的值。

### 範例

=FLOOR( -11;-2) 傳回 -12。

## GCD

傳回兩個或多個整數的最大公約數。

最大公約數是可整除各指定整數的最大正整數。

### 語法

GCD(Integer1; Integer2; ...; Integer30)

Integer1 到 30 是指可多達 30 個將計算其最大公約數的整數。

### 範例

=GCD(16;32;24) 得出結果為 8，因為 8 是 16、24 與 32 的最大公約數。

=GCD(B1:B3) 其中儲存格 B1、B2、B3 分別包含 9、12、9 得出 3。

## GCD_EXCEL2003

The result is the greatest common divisor of a list of numbers.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

### 語法

GCD_EXCEL2003(Number(s))

Number(s) 是指可多達 30 個數字的清單。

### 範例

=GCD_EXCEL2003(5;15;25) returns 5.

## INT

將數字向下捨入為最接近的整數。

### 語法

INT(Number)

傳回 Number 向下捨入為最接近的整數。

負數會向下捨入至以下的整數。

### 範例

=INT(5.7) 傳回 5。

=INT(-1.3) 傳回 -2。

## ISO.CEILING

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

### 語法

ISO.CEILING(Number; Significance)

Number 是要進位的數字。

Significance 是將數值向上捨入成其倍數的數字。

### 範例

=CEILING(-11;-2) 傳回 -10。

## LCM

傳回一個或多個整數的最小公倍數。

### 語法

LCM(Integer1; Integer2; ...; Integer30)

Integer1 到 30 是指可多達 30 個將計算其最小公倍數的整數。

### 範例

若在 Integer 1、Integer 2 與 Integer 3 文字方塊中，分別輸入數字 512、1024 與 2000，則會傳回結果 128000。

## LCM_EXCEL2003

The result is the lowest common multiple of a list of numbers.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

### 語法

LCM_EXCEL2003(Number(s))

Number(s) 是指可多達 30 個數字的清單。

### 範例

=LCM_EXCEL2003(5;15;25) returns 75.

## LN

傳回數字底數為常數 e 的自然對數值。常數 e 的近似值為 2.71828182845904。

### 語法

LN(Number)

Number 是要計算自然對數的值。

### 範例

=LN(3) 傳回 3 的自然對數 (近似值為 1.0986)。

=LN(EXP(321)) 傳回 321。

## LOG

傳回指定底數的數字之對數。

### 語法

LOG(Number; Base)

Number 是要計算其對數的數值。

Base (選擇性) 為對數計算的基數。若省略，則假設為基數為 10。

### 範例

=LOG(10;3) 傳回基數為 3 的 10 的對數 (近似值為 2.0959)。

=LOG(7^4;7) 傳回 4。

## LOG10

傳回數字底數為 10 的對數值。

### 語法

LOG10(Number)

傳回 Number 的對數 (基底為 10)。

### 範例

=LOG10(5) 傳回基數為 10 的 5 的對數 (近似值為 0.69897)。

## MOD

得出某一整數除以另一整數時的餘數。

### 語法

MOD(Dividend; Divisor)

若是整數引數，此函式會傳回被除數除以除數的餘數，亦即Dividend 除以 Divisor 的餘數。

此函式的執行方式為 Dividend - Divisor * INT(Dividend/Divisor)，若引數不是整數，則此公式可得出結果。

### 範例

=MOD(22;3) 傳回 1，22 除以 3 的餘數。

=MOD(11.25;2.5) 傳回 1.25。

## MROUND

得出四捨五入後最接近其他數字的倍數之數字。

### 語法

MROUND(Number; Multiple)

得出四捨五入為 Multiple 最接近的倍數之 Number。

其他運算方式包括 Multiple * ROUND(Number/Multiple)。

### 範例

=MROUND(15.5;3) 傳回 15，因為比起 18 (= 3*6)，15.5 更接近 15 (= 3*5)。

=MROUND(1.4;0.5) 傳回 1.5 (= 0.5*3)。

## MULTINOMIAL

Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.

### 語法

MULTINOMIAL(Number(s))

Number(s) 是指可多達 30 個數字的清單。

### 範例

若 F11 到 H11 包含值 2、3 與 4，則 =MULTINOMIAL(F11:H11) 傳回 1260。對應的公式為 =(2+3+4)! / (2!*3!*4!)。

## ODD

將正數向上捨入成最接近的奇數，將負數向下捨入成最接近的奇數。

### 語法

ODD(Number)

傳回 (向著背離零的奇整數方向) 向上捨入為下一個奇數整數的 Number。

### 範例

=ODD(1.2) 傳回 3。

=ODD(1) 傳回 1。

=ODD(0) 傳回 1。

=ODD(-3.1) 傳回 -5。

## PI

傳回 3.14159265358979 (數學常數 PI 的值至 14 位小數點位數)。

### 語法

PI()

### 範例

=PI() 傳回 3.14159265358979。

## POWER

得出乘冪之後的數字。

### 語法

POWER(基數; 指數)

傳回基數的指數次方。

使用乘冪運算子 ^ 可能得到相同的結果：

基數^指數

### 範例

=POWER(4;3) 傳回 64，表示 4 的 3 次方。

=4^3 也傳回 4 的 3 次方。

## PRODUCT

將作為引數指定的所有數字相乘並傳回乘積。

### 語法

PRODUCT(Number1; Number2; ...; Number30)

Number1 到 30 是指可多達 30 個將計算其乘積的引數。

PRODUCT 傳回 number1 * number2 * number3 * ...

### 範例

=PRODUCT(2;3;4) 傳回 24。

## QUOTIENT

得出除法運算的整數部分。

### 語法

QUOTIENT(Numerator; Denominator)

傳回 Numerator 除以 Denominator 的整數部分。

QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).

### 範例

=QUOTIENT(11;3) 傳回 3。捨去餘數 2。

## RADIANS

將度轉換為弧度。

### 語法

RADIANS(Number)

Number 是指要轉換為弧度的角度度數。

### 範例

=RADIANS(90) 傳回 1.5707963267949，此為接近 Calc 精準度的 PI/2。

## RAND

傳回 0 到 1 之間的隨機數。

### 語法

RAND( )

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

若要產生從未重複計算的隨機數，請複製每個包含 =RAND() 的儲存格，然後使用 [編輯] - [選擇性貼上] (不核取 [全部插入] 與 [公式] 但核取 [數字])。

### 範例

=RAND() 傳回介於 0 與 1 之間的隨機數。

## RANDBETWEEN

得出指定範圍內的隨機整數。

### 語法

RANDBETWEEN(Bottom; Top)

傳回介於 Bottom 與 Top (包含兩者) 整數之間的隨機整數。

此函式會在每次 Calc 重新計算時產生新的隨機數。若要手動強制 Calc 重新計算，請按 Shift+Command Ctrl
+F9。

若要產生從未重複計算的隨機數，請複製包含此函式的儲存格，然後使用 [編輯] - [選擇性貼上] (不核取 [全部插入] 與 [公式] 但核取 [數字])。

### 範例

=RANDBETWEEN(20;30) 傳回介於 20 與 30 之間的整數。

## ROUND

將一個數四捨五入為一定小數點位數的數字。

### 語法

ROUND(Number; Count)

傳回捨入到 Count 個小數點位數的 Number。若 Count 省略或為零，函式會捨入為最接近的整數。若 Count 為負值，則函式會捨入為最接近的 10、100、1000 等。

此函式會四捨五入至最接近的數字。另可使用 ROUNDDOWN 和 ROUNDUP。

### 範例

=ROUND(2.348;2) 傳回 2.35。

=ROUND(-32.4834;3) 傳回 -32.483。變更儲存格格式可檢視所有小數。

=ROUND(2.348;0) 傳回 2。

=ROUND(2.5) 傳回 3。

=ROUND(987.65;-2) 傳回 1000。

## ROUNDDOWN

按指定位數向下捨入 (沿絕對值減小的方向) 數字。

### 語法

ROUNDDOWN(Number; Count)

傳回趨向零而向下捨入到 Count 個小數點位數的 Number。若 Count 省略或為零，函式會向下捨入為整數。若 Count 為負值，函式會向下捨入到下一個 10、100、1000 等。

此函式會 (沿絕對值減小的方向) 進行四捨五入。另可使用 ROUNDUP 和 ROUND。

### 範例

=ROUNDDOWN(1.234;2) 傳回 1.23。

=ROUNDDOWN(45.67;0) 傳回 45。

=ROUNDDOWN(-45.67) 傳回 -45。

=ROUNDDOWN(987.65;-2) 傳回 900。

## ROUNDUP

按指定位數向上 (沿絕對值增大的方向) 捨入數字。

### 語法

ROUNDUP(Number; Count)

傳回 (背離零) 向上捨入到 Count 個小數點位數的 Number。若 Count 省略或為零，函式會向上捨入為整數。若 Count 為負值，函式會向上捨入到下一個 10、100、1000 等。

此函式沿絕對值增大的方向四捨五入。另可使用 ROUNDDOWN 和 ROUND。

### 範例

=ROUNDUP(1.1111;2) 傳回 1.12。

=ROUNDUP(1.2345;1) 傳回 1.3。

=ROUNDUP(45.67;0) 傳回 46。

=ROUNDUP(-45.67) 傳回 -46。

=ROUNDUP(987.65;-2) 傳回 1000。

## SEC

回傳給定角度 (單位：弧度) 的正割值。角度的正割值等於 1 除以該角度的餘弦值

### 語法

SEC(Number)

回傳角度 Number 的 (三角) 正割值，用弧度表示角度。

若要以角度為單位回傳正割值，請使用 RADIANS 函式。

### 範例

=SEC(PI()/4) 回傳值大約為 1.4142135624，即 PI/4 弧度餘弦值的倒數。

=SEC(RADIANS(60)) 回傳 2，即 60 度角的正割值。

## SECH

還傳一個數的雙曲正割值。

### 語法

SECH(Number)

傳回 Number 的雙曲正割值。

### 範例

=SECH(0) 回傳 1，即 0 的雙曲正割值。

## SERIESSUM

計算第一次乘冪級數的總和。

SERIESSUM(x;n;m;coefficients) = coefficient_1*x^n + coefficient_2*x^(n+m) + coefficient_3*x^(n+2m) +...+ coefficient_i*x^(n+(i-1)m)

### 語法

SERIESSUM(X; N; M; Coefficients)

X 是指乘冪級數的輸入值。

N 是指初始乘冪。

M 是指增加 N 的增量

Coefficients 是指係數序列。每加入一個係數，序列總和會擴展一部分。

## SIGN

傳回一個數字的正負符號。如果數字為正值，則傳回 1；如果為負值，則傳回 -1；如果為零，則傳回 0。

### 語法

SIGN(Number)

Number 是要決定其正負符號的數字。

### 範例

=SIGN(3.4) 傳回 1。

=SIGN(-4.5) 傳回 -1。

## SIN

得出指定角度 (弧度) 的正弦值。

### 語法

SIN(Number)

傳回 Number 的 (三角) 正弦值，此為弧度的角度。

若要以角度得出正弦值，請使用 RADIANS 函式。

### 範例

=SIN(PI()/2) 傳回 1，PI/2 弧度的正弦值。

=SIN(RADIANS(30)) 傳回 0.5，30 度的正弦值。

## SINH

傳回一個數字的雙曲正弦值。

### 語法

SINH(Number)

傳回 Number 的雙曲正弦值。

### 範例

=SINH(0) 傳回 0，0 的雙曲正弦值。

## SQRT

得出一個數的正平方根。

### 語法

SQRT(Number)

傳回 Number 的正平方根。

Number 必須是負數。

### 範例

=SQRT(16) 傳回 4。

=SQRT(-16) 傳回一個引數無效錯誤。

## SQRTPI

得出 (PI 乘以一個數) 的平方根。

### 語法

SQRTPI(number)

傳回 (PI 乘以 Number) 的正平方根。

這等於 SQRT(PI()*Number)。

### 範例

=SQRTPI(2) 傳回 (2PI) 的平方根，近似值為 2.506628。

## SUBTOTAL

計算小計。 如果一個範圍已包含小計，則其不能用於進一步計算。將此函式和 [自動篩選] 同時使用，以僅對篩選出的資料條目進行計算。

### 語法

SUBTOTAL(Function; Range)

Function 是指代表下列其中一個函式的數值：

函式索引 (includes hidden values) | Function index (ignores hidden values) | 函式
1 | 101 | AVERAGE
2 | 102 | COUNT
3 | 103 | COUNTA
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODUCT
7 | 107 | STDEV
8 | 108 | STDEVP
9 | 109 | SUM
10 | 110 | VAR
11 | 111 | VARP

Use numbers 1-11 to include manually hidden rows or 101-111 to exclude them; filtered-out cells are always excluded.

Range 是要加入其儲存格的範圍。

### 範例

You have a table in the cell range A1:B6 containing a bill of material for 10 students. Row 2 (Pen) is manually hidden. You want to see the sum of the figures that are displayed; that is, just the subtotal for the filtered rows. In this case the correct formula would be:

| A | B
1 | ITEM | QUANTITY
2 | Pen | 10
3 | Pencil | 10
4 | Notebook | 10
5 | Rubber | 10
6 | Sharpener | 10

=SUBTOTAL(9;B2:B6) returns 50.

=SUBTOTAL(109;B2:B6) returns 40.

## SUM

將某一儲存格範圍中的所有數字相加。

### 語法

SUM(Number1; Number2; ...; Number30)

Number 1 到 Number 30 是指可多達 30 個將計算其總和的引數。

### 範例

若在 Number 1、Number 2 與 Number 3 文字方塊中，分別輸入數字 2、3 與 4，則會傳回結果 9。

=SUM(A1;A3;B5) 計算三個儲存格的總和。=SUM (A1:E10) 計算 A1 至 E10 儲存格範圍內所有儲存格的總和。

由 AND 連結的條件可以依以下方式與函式 SUM() 一同使用：

範例假設：您在表格中輸入發票。欄 A 包含發票的日期值，欄 B 包含金額。您想尋找可用以傳回特定月份所有金額總計的公式，例如僅限 >=2008-01-01 到 <2008-02-01 期間的金額。包含日期值的範圍涵蓋 A1:A40，包含要加總的金額之範圍為 B1:B40。C1 是要包含的發票開始日期 2008-01-01，C2 是不再包含的日期 2008-02-01。

輸入以下公式作為陣列公式：

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

為將此輸入為陣列公式，您必須按 Shift+Command + Ctrl
+ Enter 組合鍵，而非只按 Enter 鍵關閉公式。然後在 [公式] 列中將會顯示此公式，且前後括有大括號。

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

公式指出，若符合條件，則比較結果為 1；若不符合條件，則比較結果為 0。個別比較結果會視為陣列並用於矩陣乘法中，最後再加總個別值以得出結果矩陣。

## SUMIF

增加給定條件所指定的儲存格。 當您搜尋特定值時，此函式用於瀏覽區域。

搜尋可支援常規表示式。例如，您可以輸入「all.*」，尋找「all」開頭之任何字元首次出現的位置。若要搜尋本身也是常規表示式的文字，則必須在每個字元前加上 \ 字元。您可以在以下位置切換常規表示式的自動評估開關：[LibreOffice] - [喜好設定][工具] - [選項]
- [LibreOffice Calc] - [計算]。

### 語法

SUMIF(Range; Criteria; SumRange)

Range 是要套用條件的範圍。

Criteria 是要在其中顯示搜尋條件的儲存格，或搜尋條件本身。若將條件寫成公式，則該條件必須括在雙引號內。

SumRange 是加總值的範圍。若尚未指定此參數，則會加總「範圍」中找到的值。

SUMIF 僅支援 Criteria 參數中的參照連結運算子 (~)，而且只有在未指定選擇性的 SumRange 參數時才支援。

### 範例

僅加總負數：=SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:10) - 只有在範圍 A1:A10 的對應值 >0 時，才加總範圍 B1:B10 的值。

請參閱 COUNTIF() 以取得更多可與 SUMIF() 一起使用的語法範例。

## SUMSQ

如果您要計算數字平方的總合 (引數平方的總計)，將這些輸入文字欄位。

### 語法

SUMSQ(Number1; Number2; ...; Number30)

Number1 到 30 是指可多達 30 個將計算其平方和的引數。

### 範例

若在 Number 1、Number 2 與 Number 3 文字方塊中，分別輸入數字 2、3 與 4，則會傳回結果 29。

## TAN

得出指定角度 (弧度) 的正切值。

### 語法

TAN(Number)

傳回 Number 的 (三角) 正切值，此為弧度的角度。

若要以角度得出正切值，請使用 RADIANS 函式。

### 範例

=TAN(PI()/4) 傳回 1，PI/4 弧度的正切值。

=TAN(RADIANS(45)) 傳回 1，45 度的正切值。

## TANH

傳回一個數字的雙曲正切值。

### 語法

TANH(Number)

傳回 Number 的雙曲正切值。

### 範例

=TANH(0) 傳回 0，0 的雙曲正切值。

## TRUNC

去除小數點位數以截斷數字。

### 語法

TRUNC(Number; Count)

傳回最多 Count 個小數點位數的 Number。不論正負號，會直接捨去多餘的小數點位數。

TRUNC(Number; 0) 以正整數的 INT(Number) 進行運作，但對於負數，則會有效地以趨向零的方向四捨五入。

可視的結果小數點位置，指定於 [LibreOffice] - [喜好設定][工具] - [選項]
- [LibreOffice Calc] - [計算] 之中。

### 範例

=TRUNC(1.239;2) 傳回 1.23。捨去 9。

=TRUNC(-1.234999;3) 傳回 -1.234。所有 9s 皆遺失。

## 歐元轉換

將舊的歐洲國家貨幣轉換成歐元，或從歐元轉換成舊的歐洲國家貨幣。

### 語法

EUROCONVERT(Value; "From_currency"; "To_currency", full_precision, triangulation_precision)

Value 是指要轉換的貨幣金額。

From_currency 與 To_currency 分別是轉換的來源與目標貨幣單位。這些項目必須是文字，代表貨幣的正式縮寫 (例如「EUR」)。匯率 (以每歐元表示) 由歐盟執行委員會 (European Commission) 設定。

Full_precision 為選用項目。若省略或為 False，則結果會依據「目標」貨幣的小數點四捨五入。若 Full_precision 為 True，則結果不會四捨五入。

Triangulation_precision 為選用項目。若提供 Triangulation_precision 且 >=3，則三角轉換的中間結果 (currency1,EUR,currency2) 會四捨五入為該精度。若省略 Triangulation_precision，則中間結果不會四捨五入。此外，若「目標貨幣」為「歐元」，則就像需要三角測量一樣會使用 Triangulation_precision，同時套用從歐元轉換為歐元。

### 範例

=EUROCONVERT(100;"ATS";"EUR") 可將 100 奧地利先令轉換成歐元。

=EUROCONVERT(100;"EUR";"DEM") 可將 100 歐元轉換成德國馬克。

相關主題

Functions by Category