Modul
Indhold
Indholdsfortegnelse 🔎︎

## TÆL.FLERE.HVIS-funktion

Returnerer antallet af celler, der opfylder kriterierne i flere intervaller.

### Syntaks

TÆL.FLERE.HVIS(Område1; Kriterie1 [; Område2; Kriterie2 [; ...]])

Område1 – påkrævet argument. Et område af celler, navnet på et navngivet område eller en etiket for en kolonne eller række, som indeholder værdier for optælling og de korresponderende kriterier.

Kriterie1 – krævet argument. Et strengudtryk der repræsenterer en logisk betingelse eller en cellereference til et sådant udtryk. Udtrykket kan indeholde tekst, tal, regulære udtryk eller wildcards (hvis de er aktiveret i beregningsindstillingerne).

Område2 – Valgfri. Område2 og alle de følgende betyder det samme som Område1.

Kriterie2 – Valgfri. Kriterie2 og alle efterfølgende kriterier betyder det samme som Kriterie1.

Område1, Område2, ... og Kriterie1, Kriterie2, ... skal have den samme størrelse, ellers returnerer funktíonen err:502 - Ugyldigt argument.

Den logiske relation mellem kriterier kan defineres som logisk OG (Konjunktion). Med andre ord, hvis og kun hvis alle givne kriterier opfyldes, vil en værdi fra den korresponderende celle af det givne Funktions_område blive taget med i udregningen.

Funktionen kan have op til 255 argumenter, hviket betyder at du kan give 127 kriterieområder og kriterier for dem.

Hvis en celle indeholder SAND, betragtes det som 1, og hvis en celle indeholder FALSK betragtes det som 0 (nul).

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

### Eksempel

#### Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Salg | Indtægt
2 | blyant | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | penalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpel brug

=TÆL.FLERE.HVIS(B2:B6;">=20")

Tæller antallet af rækker i området B2:B6 med værdier større end eller lig med 20. Returner 3, fordi den femte og sjette række ikke opfylder kriteriet.

=TÆL.FLERE.HVIS(B2:B6;">=20";C2:C6;">70")

Tæller mængden af rækker, der samtidigt indeholder værdier større end 70 i C2: C6 område og værdier større end eller lig med 20 i B2: B6 område. Returnerer 2, fordi den anden, den femte og sjette række ikke opfylder mindst ét kriterium.

#### Bruger regulære udtryk og indlejrede funktioner

=TÆL.FLERE.HVIS(B2:B6;"[:alpha:]*")

Tæller antallet af rækker i området B2:B6 som alene indeholder alfabetiske tegn. Returnerer 1, fordi kun sjette række opfylder kriteriet.

=TÆL.FLERE.HVIS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Tæller antallet af rækker i området B2:B6, undtaget rækker med minimums- og maksimumsværdier i dette område. Returnerer 2, fordi tredje og sjette række ikke opfylder mindst et af kriterierne.

=TÆL.FLERE.HVIS(A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Tæller antallet af rækker der svarer til alle celler i området A2:A6 som begynder med "pen" og til alle celler i området B2:B6 med undtagelse af dettes maksimum. Returnerer 1, fordi kun anden række opfylder alle kriterier.

#### Reference til en celle som kriterium

Hvis du har brug for nemt at kunne ændre et kriterium, kn du med fordel angive dette i en celle og benytte en reference til denne celle i betingelsen for TÆL.HVIS funktionen. For eksempel, ovenstående funktion kan omskrives til følgende:

=TÆL.FLERE.HVIS(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Hvis E2 = pen, returnerer funktionen 1, fordi kæden til cellen erstattes med dennes indhold hvilket svarer til funktionen ovenfor.

Relaterede emner

TÆL, TÆL.HVIS, ANTAL.BLANKE, TÆLV

TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, MIDDEL.HVIS, SUM.FLERE.HVIS

Liste over regulære udtryk