Module
Contents
Index 🔎︎

# Statistical Functions Part One

## COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

## B

Returns the probability of a sample with binomial distribution.

### Syntax

B(Trials; SP; T1; T2)

Trials is the number of independent trials.

SP is the probability of success on each trial.

T1 defines the lower limit for the number of trials.

T2 (optional) defines the upper limit for the number of trials.

### Example

What is the probability with ten throws of the dice, that a six will come up exactly twice? The probability of a six (or any other number) is 1/6. The following formula combines these factors:

=B(10;1/6;2) returns a probability of 29%.

## BETA.DIST

Returns the beta function.

### Syntax

BETA.DIST(Number; Alpha; Beta; Cumulative; Start; End)

Number (required) is the value between Start and End at which to evaluate the function.

Alpha (required) is a parameter to the distribution.

Beta (required) is a parameter to the distribution.

Cumulative (required) can be 0 or False to calculate the probability density function. It can be any other value or True to calculate the cumulative distribution function.

Start (optional) is the lower bound for Number.

End (optional) is the upper bound for Number.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=BETA.DIST(2;8;10;1;1;3) returns the value 0.6854706

=BETA.DIST(2;8;10;0;1;3) returns the value 1.4837646

## BETA.INV

Returns the inverse of the cumulative beta probability density function.

### Syntax

BETA.INV(Number; Alpha; Beta; Start; End)

Number is the value between Start and End at which to evaluate the function.

Alpha is a parameter to the distribution.

Beta is a parameter to the distribution.

Start (optional) is the lower bound for Number.

End (optional) is the upper bound for Number.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=BETA.INV(0.5;5;10) returns the value 0.3257511553.

## BETADIST

Returns the beta function.

### Syntax

BETADIST(Number; Alpha; Beta; Start; End; Cumulative)

Number is the value between Start and End at which to evaluate the function.

Alpha is a parameter to the distribution.

Beta is a parameter to the distribution.

Start (optional) is the lower bound for Number.

End (optional) is the upper bound for Number.

Cumulative (optional) can be 0 or False to calculate the probability density function. It can be any other value or True or omitted to calculate the cumulative distribution function.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=BETADIST(0.75;3;4) returns the value 0.96.

## BETAINV

Returns the inverse of the cumulative beta probability density function.

### Syntax

BETAINV(Number; Alpha; Beta; Start; End)

Number is the value between Start and End at which to evaluate the function.

Alpha is a parameter to the distribution.

Beta is a parameter to the distribution.

Start (optional) is the lower bound for Number.

End (optional) is the upper bound for Number.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=BETAINV(0.5;5;10) returns the value 0.33.

## BINOM.DIST

Returns the individual term binomial distribution probability.

### Syntax

BINOM.DIST(X; Trials; SP; C)

X is the number of successes in a set of trials.

Trials is the number of independent trials.

SP is the probability of success on each trial.

C = 0 calculates the probability of a single event and C = 1 calculates the cumulative probability.

### Example

=BINOM.DIST(A1;12;0.5;0) shows (if the values 0 to 12 are entered in A1) the probabilities for 12 flips of a coin that Heads will come up exactly the number of times entered in A1.

=BINOM.DIST(A1;12;0.5;1) shows the cumulative probabilities for the same series. For example, if A1 = 4, the cumulative probability of the series is 0, 1, 2, 3 or 4 times Heads (non-exclusive OR).

## BINOM.INV

Returns the smallest value for which the cumulative binomial distribution is greater than or equal to a criterion value.

### Syntax

BINOM.INV(Trials; SP; Alpha)

Trials The total number of trials.

SP is the probability of success on each trial.

Alpha The border probability that is attained or exceeded.

### Example

=BINOM.INV(8;0.6;0.9) returns 7, the smallest value for which the cumulative binomial distribution is greater than or equal to a criterion value.

## BINOMDIST

Returns the individual term binomial distribution probability.

### Syntax

BINOMDIST(X; Trials; SP; C)

X is the number of successes in a set of trials.

Trials is the number of independent trials.

SP is the probability of success on each trial.

C = 0 calculates the probability of a single event and C = 1 calculates the cumulative probability.

### Example

=BINOMDIST(A1;12;0.5;0) shows (if the values 0 to 12 are entered in A1) the probabilities for 12 flips of a coin that Heads will come up exactly the number of times entered in A1.

=BINOMDIST(A1;12;0.5;1) shows the cumulative probabilities for the same series. For example, if A1 = 4, the cumulative probability of the series is 0, 1, 2, 3 or 4 times Heads (non-exclusive OR).

## CHIDIST

Returns the probability value from the indicated Chi square that a hypothesis is confirmed. CHIDIST compares the Chi square value to be given for a random sample that is calculated from the sum of (observed value-expected value)^2/expected value for all values with the theoretical Chi square distribution and determines from this the probability of error for the hypothesis to be tested.

जो प्रॉबेबिलिटी CHIDIST द्वारा निर्धारित की जाती है वह CHITEST द्वारा भी की जाती है.

### Syntax

CHIDIST(Number; DegreesFreedom)

Number is the chi-square value of the random sample used to determine the error probability.

DegreesFreedom are the degrees of freedom of the experiment.

### Example

=CHIDIST(13.27; 5) equals 0.02.

If the Chi square value of the random sample is 13.27 and if the experiment has 5 degrees of freedom, then the hypothesis is assured with a probability of error of 2%.

## CHIINV

Returns the inverse of the one-tailed probability of the chi-squared distribution.

### Syntax

CHIINV(Number; DegreesFreedom)

Number is the value of the error probability.

DegreesFreedom is the degrees of freedom of the experiment.

### Example

A die is thrown 1020 times. The numbers on the die 1 through 6 come up 195, 151, 148, 189, 183 and 154 times (observation values). The hypothesis that the die is not fixed is to be tested.

The Chi square distribution of the random sample is determined by the formula given above. Since the expected value for a given number on the die for n throws is n times 1/6, thus 1020/6 = 170, the formula returns a Chi square value of 13.27.

If the (observed) Chi square is greater than or equal to the (theoretical) Chi square CHIINV, the hypothesis will be discarded, since the deviation between theory and experiment is too great. If the observed Chi square is less that CHIINV, the hypothesis is confirmed with the indicated probability of error.

=CHIINV(0.05;5) returns 11.07.

=CHIINV(0.02;5) returns 13.39.

If the probability of error is 5%, the die is not true. If the probability of error is 2%, there is no reason to believe it is fixed.

## CHISQ.DIST

Returns the probability density function or the cumulative distribution function for the chi-square distribution.

### Syntax

CHISQ.DIST(Number; DegreesFreedom; Cumulative)

Number is the chi-square value of the random sample used to determine the error probability.

DegreesFreedom are the degrees of freedom of the experiment.

Cumulative can be 0 or False to calculate the probability density function. It can be any other value or True to calculate the cumulative distribution function.

### Example

=CHISQ.DIST(3; 2; 0) equals 0.1115650801, the probability density function with 2 degrees of freedom, at x = 3.

=CHISQ.DIST(3; 2; 1) equals 0.7768698399, the cumulative chi-square distribution with 2 degrees of freedom, at the value x = 3.

## CHISQ.DIST.RT

Returns the probability value from the indicated Chi square that a hypothesis is confirmed. CHISQ.DIST.RT compares the Chi square value to be given for a random sample that is calculated from the sum of (observed value-expected value)^2/expected value for all values with the theoretical Chi square distribution and determines from this the probability of error for the hypothesis to be tested.

जो प्रॉबेबिलिटी CHIDIST द्वारा निर्धारित की जाती है वह CHITEST द्वारा भी की जाती है.

### Syntax

CHISQ.DIST.RT(Number; DegreesFreedom)

Number is the chi-square value of the random sample used to determine the error probability.

DegreesFreedom are the degrees of freedom of the experiment.

### Example

=CHISQ.DIST.RT(13.27; 5) equals 0.0209757694.

If the Chi square value of the random sample is 13.27 and if the experiment has 5 degrees of freedom, then the hypothesis is assured with a probability of error of 2%.

## CHISQ.INV

Returns the inverse of the left-tailed probability of the chi-square distribution.

### Syntax

CHISQ.INV(Probability; DegreesFreedom)

Probability is the probability value for which the inverse of the chi-square distribution is to be calculated.

Degrees Of Freedom is the degrees of freedom for the chi-square function.

### Example

=CHISQ.INV(0,5;1) returns 0.4549364231.

## CHISQ.INV.RT

Returns the inverse of the one-tailed probability of the chi-squared distribution.

### Syntax

CHISQ.INV.RT(Number; DegreesFreedom)

Number is the value of the error probability.

DegreesFreedom is the degrees of freedom of the experiment.

### Example

A die is thrown 1020 times. The numbers on the die 1 through 6 come up 195, 151, 148, 189, 183 and 154 times (observation values). The hypothesis that the die is not fixed is to be tested.

The Chi square distribution of the random sample is determined by the formula given above. Since the expected value for a given number on the die for n throws is n times 1/6, thus 1020/6 = 170, the formula returns a Chi square value of 13.27.

If the (observed) Chi square is greater than or equal to the (theoretical) Chi square CHIINV, the hypothesis will be discarded, since the deviation between theory and experiment is too great. If the observed Chi square is less that CHIINV, the hypothesis is confirmed with the indicated probability of error.

=CHISQ.INV.RT(0.05;5) returns 11.0704976935.

=CHISQ.INV.RT(0.02;5) returns 13.388222599.

If the probability of error is 5%, the die is not true. If the probability of error is 2%, there is no reason to believe it is fixed.

## CHISQ.TEST

Returns the probability of a deviance from a random distribution of two test series based on the chi-squared test for independence. CHISQ.TEST returns the chi-squared distribution of the data.

The probability determined by CHISQ.TEST can also be determined with CHISQ.DIST, in which case the Chi square of the random sample must then be passed as a parameter instead of the data row.

### Syntax

CHISQ.TEST(DataB; DataE)

DataB is the array of the observations.

DataE is the range of the expected values.

### Example

| डाटा_B (ऑबज़र्व्ड) | डाटा_E (अपेक्षित)
1 | 195 | 170
2 | 151 | 170
3 | 148 | 170
4 | 189 | 170
5 | 183 | 170
6 | 154 | 170

=CHISQ.TEST(A1:A6;B1:B6) equals 0.0209708029. This is the probability which suffices the observed data of the theoretical Chi-square distribution.

## CHISQDIST

Returns the value of the probability density function or the cumulative distribution function for the chi-square distribution.

### Syntax

CHISQDIST(Number; Degrees Of Freedom; Cumulative)

Number is the number for which the function is to be calculated.

Degrees Of Freedom is the degrees of freedom for the chi-square function.

Cumulative (optional): 0 or False calculates the probability density function. Other values or True or omitted calculates the cumulative distribution function.

## CHISQINV

Returns the inverse of CHISQDIST.

### Syntax

Probability is the probability value for which the inverse of the chi-square distribution is to be calculated.

Degrees Of Freedom is the degrees of freedom for the chi-square function.

## CHITEST

Returns the probability of a deviance from a random distribution of two test series based on the chi-squared test for independence. CHITEST returns the chi-squared distribution of the data.

The probability determined by CHITEST can also be determined with CHIDIST, in which case the Chi square of the random sample must then be passed as a parameter instead of the data row.

### Syntax

CHITEST(DataB; DataE)

DataB is the array of the observations.

DataE is the range of the expected values.

### Example

| डाटा_B (ऑबज़र्व्ड) | डाटा_E (अपेक्षित)
1 | 195 | 170
2 | 151 | 170
3 | 148 | 170
4 | 189 | 170
5 | 183 | 170
6 | 154 | 170

=CHITEST(A1:A6;B1:B6) equals 0.02. This is the probability which suffices the observed data of the theoretical Chi-square distribution.

## COUNT

Counts how many numbers are in the list of arguments. Text entries are ignored.

### Syntax

COUNT(Value1; Value2; ...; Value30)

Value1; Value2, ..., Value30 are 1 to 30 values or ranges representing the values to be counted.

### Example

The entries 2, 4, 6 and eight in the Value 1-4 fields are to be counted.

=COUNT(2;4;6;"eight") = 3. The count of numbers is therefore 3.

## COUNTA

Counts how many values are in the list of arguments. Text entries are also counted, even when they contain an empty string of length 0. If an argument is an array or reference, empty cells within the array or reference are ignored.

### Syntax

COUNTA(Value1; Value2; ...; Value30)

Value1; Value2, ..., Value30 are 1 to 30 arguments representing the values to be counted.

### Example

The entries 2, 4, 6 and eight in the Value 1-4 fields are to be counted.

=COUNTA(2;4;6;"eight") = 4. The count of values is therefore 4.

## COUNTBLANK

Returns the number of empty cells.

### Syntax

COUNTBLANK(Range)

Returns the number of empty cells in the cell range Range.

### Example

=COUNTBLANK(A1:B2) returns 4 if cells A1, A2, B1, and B2 are all empty.

## COUNTIF

Returns the number of cells that meet with certain criteria within a cell range.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

### Syntax

COUNTIF(Range; Criteria)

Range is the range to which the criteria are to be applied.

Criteria indicates the criteria in the form of a number, an expression or a character string. These criteria determine which cells are counted. If regular expressions are enabled in calculation options you may also enter a search text in the form of a regular expression, e.g. b.* for all cells that begin with b. If wildcards are enabled in calculation options you may enter a search text with wildcards, e.g. b* for all cells that begin with b. You may also indicate a cell address that contains the search criterion. If you search for literal text, enclose the text in double quotes.

### Example

A1:A10 is a cell range containing the numbers 2000 to 2009. Cell B1 contains the number 2006. In cell B2, you enter a formula:

=COUNTIF(A1:A10;2006) - this returns 1.

=COUNTIF(A1:A10;B1) - this returns 1.

=COUNTIF(A1:A10;">=2006") - this returns 4.

=COUNTIF(A1:A10;"<"&B1) - when B1 contains 2006, this returns 6.

=COUNTIF(A1:A10;C2) where cell C2 contains the text >2006 counts the number of cells in the range A1:A10 which are >2006.

To count only negative numbers: =COUNTIF(A1:A10;"<0")

## EXPON.DIST

Returns the exponential distribution.

### Syntax

EXPON.DIST(Number; Lambda; C)

Number is the value of the function.

Lambda is the parameter value.

C is a logical value that determines the form of the function. C = 0 calculates the density function, and C = 1 calculates the distribution.

### Example

=EXPON.DIST(3;0.5;1) returns 0.7768698399.

## EXPONDIST

Returns the exponential distribution.

### Syntax

EXPONDIST(Number; Lambda; C)

Number is the value of the function.

Lambda is the parameter value.

C is a logical value that determines the form of the function. C = 0 calculates the density function, and C = 1 calculates the distribution.

### Example

=EXPONDIST(3;0.5;1) returns 0.78.

## INTERCEPT

Calculates the point at which a line will intersect the y-values by using known x-values and y-values.

### Syntax

INTERCEPT(DataY; DataX)

DataY is the dependent set of observations or data.

DataX is the independent set of observations or data.

Names, arrays or references containing numbers must be used here. Numbers can also be entered directly.

### Example

To calculate the intercept, use cells D3:D9 as the y value and C3:C9 as the x value from the example spreadsheet. Input will be as follows:

=INTERCEPT(D3:D9;C3:C9) = 2.15.

## RSQ

Returns the square of the Pearson correlation coefficient based on the given values. RSQ (also called determination coefficient) is a measure for the accuracy of an adjustment and can be used to produce a regression analysis.

### Syntax

RSQ(DataY; DataX)

DataY is an array or range of data points.

DataX is an array or range of data points.

### Example

=RSQ(A1:A20;B1:B20) calculates the determination coefficient for both data sets in columns A and B.

Related Topics

Functions by Category