Funcions matemàtiques

Esta categoria conté les funcions matemàtiques del Calc. Per obrir l'Auxiliar de funcions, trieu Insereix ▸ Funció.

funció AGGREGATE

This function returns an aggregate result of the calculations in the range. You can use different aggregate functions listed below. The Aggregate function enables you to omit hidden rows, errors, SUBTOTAL and other AGGREGATE function results in the calculation.

RAWSUBTRACT

Subtracts a set of numbers and gives the result without eliminating small roundoff errors.

HORA

Return a numeric value calculated by a combination of three colors (red, green and blue) and the alpha channel, in the RGBA color system. The result depends on the color system used by your computer.

funció SUMASICONJUNT

Returns the sum of the values of cells in a range that meets multiple criteria in multiple ranges.

ABS

Retorna el valor absolut d'un nombre.

Syntax

ABS(Nombre)

Nombre és el nombre del qual s'ha de calcular el valor absolut. El valor absolut d'un nombre és el seu valor sense el signe +/-.

Example

=ABS(-56) retorna 56.

=ABS(12) retorna 12.

=ABS(0) retorna 0.

ACOS

Retorna el cosinus trigonomètric invers d'un nombre.

Syntax

ACOS(Nombre)

Esta funció retorna el cosinus trigonomètric invers de Nombre, és a dir, l'angle (en radians) el cosinus del qual és Nombre. L'angle que es retorna es troba entre 0 i PI.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Example

=ACOS(-1) retorna 3,14159265358979 (PI radians).

=GRAUS(ACOS(0,5)) retorna 60. El cosinus de 60 graus és 0,5.

ACOSH

Retorna el cosinus hiperbòlic invers d'un nombre.

Syntax

ACOSH(Nombre)

Esta funció retorna el cosinus hiperbòlic invers de Nombre, és a dir, el nombre el cosinus hiperbòlic del qual és Nombre.

El nombre ha de ser més gran o igual a 1.

Example

=ACOSH(1) retorna 0.

=ACOSH(COSH(4)) retorna 4.

ACOT

Retorna la cotangent inversa (l'arc cotangent) del nombre donat.

Syntax

ACOT(Nombre)

Esta funció retorna la cotangent trigonomètrica inversa de Nombre, és a dir, l'angle (en radians) la cotangent del qual és Nombre. L'angle que es retorna es troba entre 0 i PI.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Example

=ACOT(1) retorna 0,785398163397448 (PI/4 radians).

=GRAUS(ACOT(1)) retorna 45. La tangent de 45 graus és 1.

ACOTH

Retorna la cotangent hiperbòlica inversa del nombre indicat.

Syntax

ACOTH(Nombre)

Esta funció retorna la cotangent hiperbòlica inversa de Nombre, que és el nombre la cotangent hiperbòlica del qual és Nombre.

Si el nombre es troba entre -1 i 1 (inclosos), la funció retorna un error.

Example

=ACOTH(1,1) retorna la cotangent hiperbòlica inversa d'1,1; aproximadament, 1,52226.

ALEAT

Retorna un nombre aleatori entre 0 i 1.

Syntax

ALEAT()

Esta funció genera un nombre aleatori nou cada vegada que el Calc recalcula. Per a forçar manualment que el Calc recalculi, premeu F9.

Per generar nombres aleatoris que no es tornen a calcular, copieu les cel·les que continguen =ALEAT() i utilitzeu Edita ▸ Enganxament especial (amb les opcions Enganxa-ho tot i Fórmules desactivades, i l'opció Números activada).

Example

=ALEAT() retorna un nombre aleatori entre 0 i 1.

ALEATENTRE

Retorna un nombre enter aleatori dins d'un interval determinat.

Syntax

ALEATENTRE(Inferior; Superior)

Retorna un nombre enter aleatori entre els enters Inferior i Superior (inclosos).

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

Per generar nombres aleatoris que no es tornen a calcular, copieu les cel·les que contenen esta funció i utilitzeu Edita ▸ Enganxament especial (amb les opcions Enganxa-ho tot i Fórmules desactivades, i l'opció Nombres activada).

Example

=ALEATENTRE(20;30) retorna un enter entre 20 i 30.

ARRELQ

Retorna l'arrel quadrada positiva d'un nombre.

Syntax

ARRELQ(Nombre)

Retorna l'arrel quadrada positiva de Nombre.

El nombre ha de ser positiu.

Example

=ARRELQ(16) retorna 4.

=ARRELQ(-16) retorna l'error: l'argument no és vàlid.

ARRELQPI

Retorna l'arrel quadrada de (PI vegades un nombre).

Syntax

ARRELQPI(Nombre)

Retorna l'arrel quadrada positiva de (PI multiplicat per Nombre).

Això equival a ARRELQ(PI()*Nombre).

Example

=ARRELQPI(2) retorna l'arrel quadrada de (2PI), aproximadament 2,506628.

ARROD

Arrodoneix un nombre a un nombre determinat de xifres decimals.

Syntax

ARROD(Nombre; Comptatge)

Retorna Nombre arrodonit a les xifres decimals de Comptatge. Si Comptatge s'omet o és zero, s'arrodoneix la funció a l'enter més proper. Si Comptatge és negatiu, la funció s'arrodoneix fins al proper 10, 100, 1000, etcètera.

Esta funció arrodoneix al nombre més proper. Vegeu ARRODAVALL i ARRODAMUNT per veure funcions alternatives.

Example

=ARROD(2.348;2) retorna 2,35.

=ARROD(-32,4834;3) retorna -32,483. Canvieu el format de la cel·la per veure tots els decimals.

=ARROD(2,348;0) retorna 2.

=ARROD(2,5) retorna 3.

=ARROD(987,65;-2) retorna 1000.

ARRODAMUNT

Arrodoneix un nombre a l'alça, allunyat de zero, amb una precisió determinada.

Syntax

ARRODAMUNT(Nombre; Comptatge)

Retorna el Nombre arrodonit a l'alça (allunyat de zero) amb les xifres decimals de Comptatge. Si Comptatge s'omet o és zero, la funció arrodoneix a un enter. Si Comptatge és negatiu, la funció arrodoneix a l'alça fins al proper 10, 100, 1000, etcètera.

Esta funció s'allunya del zero en arrodonir. Vegeu ARRODAVALL i ARROD per veure funcions alternatives.

Example

=ARRODAMUNT(1,1111;2) retorna 1,12.

=ARRODAMUNT(1,2345;1) retorna 1,3.

=ARRODAMUNT(45,67;0) retorna 46.

=ARRODAMUNT(-45,67) retorna -46.

=ARRODAMUNT(987,65;-2) retorna 1000.

ARRODAVALL

Arrodoneix un nombre cap avall, cap a zero, a una precisió determinada.

Syntax

ARRODAVALL(Nombre; Comptatge)

Retorna el Nombre arrodonit a la baixa (cap a zero) amb les xifres decimals de Comptatge. Si Comptatge s'omet o és zero, la funció arrodoneix a la baixa fins a un enter. Si Comptatge és negatiu, la funció arrodoneix a la baixa fins al proper 10, 100, 1000, etcètera.

Esta funció arrodoneix a zero. Vegeu ARRODAMUNT i ARROD per veure funcions alternatives.

Example

=ARRODAVALL(1,234;2) retorna 1,23.

=ARRODAVALL(45,67;0) retorna 45.

=ARRODAVALL(-45,67) retorna -45.

=ARRODAVALL(987,65;-2) retorna 900.

ARRODM

Retorna un nombre arrodonit al múltiple més proper d'un altre nombre.

Syntax

ARRODM(Nombre; Múltiple)

Retorna el Nombre arrodonit al múltiple més proper de Múltiple.

Una implementació alternativa seria Múltiple * ARROD(Nombre/Múltiple).

Example

=ARRODM(15,5;3) retorna 15, ja que 15,5 és més proper a 15 (= 3*5) que a 18 (= 3*6).

=ARRODM(1.4;0,5) retorna 1,5 (= 0,5*3).

ARRODMULTINF

Arrodoneix un nombre a la baixa cap al múltiple més proper de Precisió.

Syntax

ARRODMULTINF(Nombre; Precisió; Mode)

Nombre és el nombre que s'ha d'arrodonir a la baixa.

Precisió és el valor al múltiple del qual s'ha d'arrodonir a la baixa el nombre.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded towards zero. If the Mode value is equal to zero or is not given, negative numbers are rounded away from zero.

Icona d'avís

If the spreadsheet is exported to Microsoft Excel, the FLOOR function is exported as the equivalent FLOOR.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either FLOOR.PRECISE that exists since Excel 2010, or FLOOR.XCL that is exported as the FLOOR function compatible with all Excel versions. Note that FLOOR.XCL always rounds towards zero.


Example

=ARRODMULTINF( -11;-2) retorna -12.

=ARRODMULTINF( -11;-2;0) retorna -12.

=ARRODMULTINF( -11;-2;1) retorna -10.

ARRODMULTINF.PRECIS

Arrodoneix un nombre cap avall al múltiple més proper de la Precisió, sense importar el signe de la Precisió

Syntax

ARRODMULTINF.PRECIS(Nombre; Precisió)

Nombre és el nombre que s'ha d'arrodonir a la baixa.

Precisió és el valor al múltiple del qual s'ha d'arrodonir a la baixa el nombre.

Example

=ARRODMULTINF.PRECIS( -11;-2) retorna -12

ARRODMULTSUP

Arrodoneix un nombre cap al múltiple més proper d'Importància.

Syntax

ARRODMULTSUP(Nombre; Precisió; Mode)

Nombre és el nombre que s'ha d'arrodonir a l'alça.

Importància és el nombre al múltiple del qual s'ha d'arrodonir a l'alça el valor.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

Icona d'avís

If the spreadsheet is exported to Microsoft Excel, the CEILING function is exported as the equivalent CEILING.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either CEILING.PRECISE that exists since Excel 2010, or CEILING.XCL that is exported as the CEILING function compatible with all Excel versions. Note that CEILING.XCL always rounds away from zero.


Example

=ARRODMULTSUP(-11;-2) retorna -10.

=ARRODMULTSUP(-11;-2;0) retorna -10.

=ARRODMULTSUP(-11;-2;1) retorna -12.

ARRODMULTSUP.ISO

Arrodoneix un nombre cap amunt al múltiple més proper de la Precisió, sense importar el signe de la Precisió

Syntax

ARRODMULTSUP.ISO(Nombre; Precisió)

Nombre (necessari) és el nombre que s'ha d'arrodonir a l'alça.

Precisió (opcional) és el nombre al múltiple del qual s'ha d'arrodonir a l'alça el valor.

Example

=ARRODMULTSUP.ISO(-11;-2) retorna -10

ARRODMULTSUP.PRECIS

Arrodoneix un nombre cap amunt al múltiple més proper de la Precisió, sense importar el signe de la Precisió.

Syntax

ARRODMULTSUP.PRECIS(Nombre;Precisió)

Nombre (necessari) és el nombre que s'ha d'arrodonir a l'alça.

Precisió (opcional) és el nombre al múltiple del qual s'ha d'arrodonir a l'alça el valor.

Example

=ARRODMULTSUP.PRECIS(-11;-2) retorna -10

ASIN

Retorna el sinus trigonomètric invers d'un nombre.

Syntax

ASIN(Nombre)

Esta funció retorna el sinus trigonomètric invers de Nombre, és a dir, l'angle (en radians) el sinus del qual és Nombre. L'angle que es retorna es troba entre -PI/2 i +PI/2.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Example

=ASIN(0) retorna 0.

=ASIN(1) retorna 1,5707963267949 (PI/2 radians).

=GRAUS(ASIN(0,5)) retorna 30. El sinus de 30 graus és 0,5.

ASINH

Retorna el sinus hiperbòlic invers d'un nombre.

Syntax

ASINH(Nombre)

Esta funció retorna el sinus hiperbòlic invers de Nombre, que és el nombre el sinus hiperbòlic del qual és Nombre.

Example

=ASINH(-90) retorna aproximadament -5,1929877.

=ASINH(SINH(4)) retorna 4.

ATAN

Retorna la tangent trigonomètrica inversa d'un nombre.

Syntax

ATAN(Nombre)

Esta funció retorna la tangent trigonomètrica inversa de Nombre, que és l'angle (en radians) la tangent del qual és Nombre. L'angle que es retorna és entre -PI/2 i PI/2.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Example

=ATAN(1) retorna 0,785398163397448 (PI/4 radians).

=GRAUS(ATAN(1)) retorna 45. La tangent de 45 graus és 1.

ATAN2

Retorna la tangent trigonomètrica inversa de les coordenades x i y que s'han indicat.

Syntax

ATAN2(NombreX; NombreY)

NombreX és el valor de la coordenada x.

NombreY és el valor de la coordenada y.

ATAN2 retorna la tangent trigonomètrica inversa, és a dir, l'angle (en radians) entre l'eix x i una línia des del punt NombreX, NombreY a l'origen. L'angle que es retorna es troba entre -PI i PI.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Example

=ATAN2(20;20) retorna 0,785398163397448 (PI/4 radians).

=GRAUS(ATAN2(12,3;12,3)) retorna 45. La tangent de 45 graus és 1.

ATANH

Retorna la tangent hiperbòlica inversa d'un nombre.

Syntax

ATANH(Nombre)

Esta funció retorna la tangent hiperbòlica inversa de Nombre, és a dir, el nombre la tangent hiperbòlica del qual és Nombre.

El nombre ha de complir la condició -1 < nombre < 1.

Example

=ATANH(0) retorna 0.

CEILING.MATH

Rounds a number up to the nearest multiple of Significance.

Syntax

CEILING.MATH(Number; Significance; Mode)

Number is the number that is to be rounded up.

Significance is the number to whose multiple the value is to be rounded up.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

Icona d'avís

This function exists for interoperability with Microsoft Excel 2013 or newer.


Example

=CEILING.MATH(-10;-3) returns -9

=CEILING.MATH(-10;-3;0) returns -9

=CEILING.MATH(-10;-3;1) returns -12

CEILING.XCL

Rounds a number away from zero to the nearest multiple of Significance.

Syntax

CEILING.XCL(Number; Significance)

Number is the number that is to be rounded.

Significance is the number to whose multiple the value is to be rounded.

Icona d'avís

This function exists for interoperability with Microsoft Excel 2007 or older versions.


Example

=CEILING.XCL(1;3) returns 3

=CEILING.XCL(7;4) returns 8

=CEILING.XCL(-10;-3) returns -12

COMBINAT

Retorna el nombre de combinacions per a elements sense repetició.

Syntax

COMBINAT(Comptatge1; Comptatge2)

Comptatge1 és el nombre d'elements del conjunt.

Comptatge2 és el nombre d'elements que s'han de triar del conjunt.

COMBINAT retorna el nombre de maneres ordenades de triar estos elements. Per exemple, si hi ha 3 elements A, B i C en un conjunt, podeu triar 2 elements de tres maneres diferents: AB, AC i BC.

COMBINAT implementa la fórmula següent: Comptatge1!/(Comptatge2!*(Comptatge1-Comptatge2)!).

Example

=COMBINAT(3;2) retorna 3.

COMBINATA

Retorna el nombre de combinacions d'un subconjunt d'elements, incloses les repeticions.

Syntax

COMBINATA(Comptatge1; Comptatge2)

Comptatge1 és el nombre d'elements del conjunt.

Comptatge2 és el nombre d'elements que s'han de triar del conjunt.

COMBINATA retorna el nombre de maneres úniques de triar estos elements, on l'orde de tria és irrellevant i es permet la repetició d'elements. Per exemple, si hi ha 3 elements A, B i C en un conjunt, podeu triar 2 elements de sis maneres diferents: AA, AB, AC, BB, BC i CC.

COMBINATA implementa la fórmula següent: (Comptatge1+Comptatge2-1)! / (Comptatge2!(Comptatge1-1)!)

Example

=COMBINATA(3;2) retorna 6.

CONVERSIOEURO

Converteix les antigues monedes nacionals europees en euros, i viceversa.

Syntax

CONVERSIOEURO(Valor; "Moneda_origen"; "Moneda_destí", Màxima_precisió, Precisió_triangulació)

Valor és la quantitat de la moneda que s'ha de convertir.

Moneda_origen és la unitat monetària que s'ha de convertir; Moneda_destí és la unitat monetària en què s'ha de convertir la primera. L'abreviatura de la moneda ha de ser text (per exemple, "EUR"). Les taxes (que es mostren en euros) les va establir la Comissió Europea.

Màxima_precisió és opcional. Si s'omet o és Fals, el resultat s'arrodoneix segons els decimals de la Moneda_destí. Si Màxima_precisió és Cert, el resultat no s'arrodoneix.

Precisió_triangulació és opcional. Si s'indica la Precisió_triangulació i és >=3, el resultat intermedi d'una conversió triangular (moneda1,EUR,moneda2) s'arrodoneix a esta precisió. Si s'omet la Precisió_triangulació, el resultat intermedi no s'arrodoneix. A més, si la Moneda_destí és "EUR", la Precisió_triangulació s'utilitza com si es necessités la triangulació i s'apliqués la conversió d'EUR a EUR.

Exemples

=CONVERSIOEURO(100;"ATS";"EUR") converteix 100 xílings austríacs en euros.

=CONVERSIOEURO(100;"EUR";"DEM") converteix 100 euros en marcs alemanys.

CONVERT_OOO

Converteix un valor d'una unitat de mesura en una altra. Els factors de conversió es mostren en una llista a la configuració.

Anteriorment, la llista de factors de conversió incloïen les monedes antigues europees i l'euro (vegeu els exemples següents). És recomanable utilitzar la funció nova CONVERSIOEURO per convertir estes monedes.

Syntax

CONVERT_OOO(value;"text";"text")

Example

=CONVERT_OOO(100;"ATS";"EUR") returns the Euro value of 100 Austrian Schillings.

=CONVERT_OOO(100;"EUR";"DEM") converts 100 Euros into German Marks.

COS

Retorna el cosinus de l'angle que s'ha indicat (en radians).

Syntax

COS(Nombre)

Retorna el cosinus (trigonomètric) de Nombre, l'angle en radians.

Per calcular el cosinus d'un angle en graus, utilitzeu la funció RADIANS.

Example

=COS(PI()/2) retorna 0, el cosinus de PI/2 radians.

=COS(RADIANS(60)) retorna 0,5, el cosinus de 60 graus.

COSH

Retorna el cosinus hiperbòlic d'un nombre.

Syntax

COSH(Nombre)

Retorna el cosinus hiperbòlic d'un Nombre.

Example

=COSH(0) retorna 1, el cosinus hiperbòlic de 0.

COT

Retorna la cotangent de l'angle indicat (en radians).

Syntax

COT(Nombre)

Retorna la cotangent (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la cotangent d'un angle en graus, utilitzeu la funció RADIANS.

La cotangent d'un angle és equivalent a 1 dividit entre la tangent d'este angle.

Exemples:

=COT(PI()/4) retorna 1, la cotangent de PI/4 radians.

=COT(RADIANS(45)) retorna 1, la cotangent de 45 graus.

COTH

Retorna la cotangent hiperbòlica d'un nombre donat (angle).

Syntax

COTH(Nombre)

Retorna la cotangent hiperbòlica d'un Nombre.

Example

=COTH(1) retorna la cotangent hiperbòlica d'1, aproximadament 1,3130.

CSC

Retorna la cosecant de l'angle indicat (en radians). La cosecant d'un angle és equivalent a 1 dividit entre el sinus d'este angle

Syntax

CSC(Nombre)

Retorna la cosecant (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la cosecant d'un angle en graus, utilitzeu la funció RADIANS.

Example

=CSC(PI()/4) retorna aproximadament 1,4142135624, la inversa del sinus de PI/4 radians.

=CSC(RADIANS(30)) retorna 2, la cosecant de 30 graus.

CSCH

Retorna la cosecant hiperbòlica d'un nombre.

Syntax

CSCH(Nombre)

Retorna la cosecant hiperbòlica d'un nombre.

Example

=CSCH(1) retorna aproximadament 0,8509181282, la cosecant hiperbòlica d'1.

ENT

Arrodoneix un nombre a la baixa a l'enter més proper.

Syntax

ENT(Nombre)

Retorna el Nombre arrodonit a la baixa cap a l'enter més proper.

Els nombres negatius s'arrodoneixen a l'enter inferior.

Example

=ENT(5,7) retorna 5.

=ENT(-1,3) retorna -2.

EXP

Retorna e elevada a la potència d'un nombre. La constant e té un valor aproximat de 2,71828182845904.

Syntax

EXP(Nombre)

Nombre és la potència a la qual s'eleva e.

Example

=EXP(1) retorna 2,71828182845904, la constant matemàtica e a la precisió del Calc.

FACT

Retorna el factorial d'un nombre.

Syntax

FACT(Nombre)

Retorna Nombre!, el factorial de Nombre, calculat com a 1*2*3*4* ... * Nombre.

=FACT(0) retorna 1 per definició.

El factorial d'un nombre negatiu retorna l'error "L'argument no és vàlid".

Example

=FACT(3) retorna 6.

=FACT(0) retorna 1.

GCD_EXCEL2003

The result is the greatest common divisor of a list of numbers.

Icona de nota

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per obtindre resultats basats en els estàndards internacionals.


Syntax

GCD_EXCEL2003(Number(s))

Nombre(s) és una llista de fins a 30 nombres.

Example

=GCD_EXCEL2003(5;15;25) returns 5.

GRAUS

Converteix radians a graus.

Syntax

GRAUS(Nombre)

Nombre és l'angle en radians que s'ha de convertir en graus.

Example

=GRAUS(PI()) retorna 180 graus.

LCM_EXCEL2003

The result is the lowest common multiple of a list of numbers.

Icona de nota

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per obtindre resultats basats en els estàndards internacionals.


Syntax

LCM_EXCEL2003(Number(s))

Nombre(s) és una llista de fins a 30 nombres.

Example

=LCM_EXCEL2003(5;15;25) returns 75.

LN

Retorna el logaritme natural a partir de la constant e d'un nombre. La constant e té un valor aproximat de 2,71828182845904.

Syntax

LN(Nombre)

Nombre és el valor del qual s'ha de calcular el logaritme natural.

Example

=LN(3) retorna el logaritme natural de 3 (aproximadament 1,0986).

=LN(EXP(321)) retorna 321.

LOG

Retorna el logaritme d'un nombre a la base indicada.

Syntax

LOG(Nombre; Base)

Nombre és el valor el logaritme del qual s'ha de calcular.

Base (opcional) és la base per al càlcul del logaritme. Si s'omet, s'utilitzarà la base 10.

Example

=LOG(10;3) retorna el logaritme en base 3 de 10 (aproximadament 2,0959).

=LOG(7^4;7) retorna 4.

LOG10

Retorna el logaritme de base-10 d'un nombre.

Syntax

LOG10(Nombre)

Retorna el logaritme en base 10 de Nombre.

Example

=LOG10(5) retorna el logaritme en base 10 de 5 (aproximadament 0,69897).

MCD

Retorna el màxim comú divisor de dos enters o més.

El màxim comú divisor és l'enter positiu més gran que divideix, sense residu, cadascun dels enters indicats.

Syntax

MCD(Enter1; Enter2; ...; Enter30)

Enter1 a 30 són fins a 30 enters dels quals s'ha de calcular el màxim comú divisor.

Example

=MCD(16;32;24) dóna el resultat 8 perquè 8 és el nombre més gran que pot dividir 16, 24 i 32 sense residu.

=MCD(B1:B3) on les cel·les B1, B2 i B3 contenen 9, 12 i 9 dóna 3.

MCM

Retorna el mínim comú múltiple d'un enter o més d'un.

Syntax

MCM(Enter1; Enter2; ...; Enter30)

Enter1 a 30 són fins a 30 enters dels quals s'ha de calcular el mínim comú múltiple.

Example

Si introduïu els nombres 512, 1024 i 2000 en els quadres de text Enter 1, 2 i 3, el resultat serà 128.000.

MOD

Retorna el residu quan es divideix un enter per un altre.

Syntax

MOD(Dividend; Divisor)

Per als arguments enters, esta funció retorna el residu quan el Dividend es divideix pel Divisor.

Esta funció s'implementa Dividend - Divisor * ENT(Dividend/Divisor), i esta fórmula dóna el resultat si els arguments no són enters.

Example

=MOD(22;3) retorna 1, el residu quan es divideix 22 entre 3.

=MOD(11,25;2,5) retorna 1,25.

MULTINOMIAL

Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.

Syntax

MULTINOMIAL(Nombre(s))

Nombre(s) és una llista de fins a 30 nombres.

Example

=MULTINOMIAL(F11:H11) retorna 1260, si F11 a H11 contenen els valors 2, 3 i 4. Este resultat correspon a la fórmula =(2+3+4)! / (2!*3!*4!).

PARELL

Arrodoneix un nombre positiu cap a l'enter parell superior i un nombre negatiu cap a l'enter parell inferior.

Syntax

PARELL(Nombre)

Retorna Nombre arrodonit cap a l'enter parell superior, allunyat de zero.

Example

=PARELL(2,3) retorna 4.

=PARELL(2) retorna 2.

=PARELL(0) retorna 0.

=PARELL(-0,5) retorna -2.

PI

Retorna 3,14159265358979, el valor de la constant matemàtica PI amb 14 decimals.

Syntax

PI()

Example

=PI() retorna 3,14159265358979.

POTENCIA

Retorna un nombre elevat a un altre nombre.

Syntax

POTENCIA(Base; Exponent)

Retorna la Base elevada a la potència que s'indica a Exponent.

Podeu obtindre el mateix resultat si utilitzeu l'operador d'exponent ^:

Base^Exponent

Example

=POTENCIA(4;3) retorna 64, que és 4 elevat a la potència de 3.

=4^3 també retorna la potència de 4 elevat a 3.

PRODUCTE

Multiplica tots els nombres que s'han indicat com a arguments i en retorna el producte.

Syntax

PRODUCTE(Nombre1; Nombre2; ...; Nombre30)

Nombre1 fins a 30 són fins a 30 arguments el producte dels quals s'ha de calcular.

PRODUCTE retorna nombre1 * nombre2 * nombre3 * ...

Example

=PRODUCTE(2;3;4) retorna 24.

QUOCIENT

Retorna la part entera d'una divisió.

Syntax

QUOCIENT(Numerador; Denominador)

Retorna la part entera de Numerador dividida entre Denominador.

QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).

Example

=QUOCIENT(11;3) retorna 3. El residu de 2 es perd.

RADIANS

Converteix graus a radians.

Syntax

RADIANS(Nombre)

Nombre és l'angle en graus que s'ha de convertir en radians.

Example

=RADIANS(90) retorna 1,5707963267949, que és PI/2 segons la precisió del Calc.

SEC

Retorna la secant de l'angle indicat (en radians). La secant d'un angle és equivalent a 1 dividit entre el cosinus d'este angle

Syntax

SEC(Nombre)

Retorna la secant (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la secant d'un angle en graus, utilitzeu la funció RADIANS.

Example

=SEC(PI()/4) retorna aproximadament 1,4142135624, la inversa del cosinus de PI/4 radians.

=SEC(RADIANS(60)) retorna 2, la secant de 60 graus.

SECH

Retorna la secant hiperbòlica d'un nombre.

Syntax

SECH(Nombre)

Retorna la secant hiperbòlica d'un nombre.

Example

=SECH(0) retorna 1, la secant hiperbòlica de 0.

SENAR

Arrodoneix un nombre positiu a l'alça cap a l'enter senar més proper i un nombre negatiu a la baixa cap a l'enter senar més proper.

Syntax

SENAR(Nombre)

Retorna Nombre arrodonit a l'alça cap a l'enter senar més proper, allunyat de zero.

Example

=SENAR(1,2) retorna 3.

=SENAR(1) retorna 1.

=SENAR(0) retorna 1.

=SENAR(-3,1) retorna -5.

SIGNE

Retorna el signe d'un nombre. Retorna 1 si el nombre és positiu, -1 si és negatiu i 0 si és zero.

Syntax

SIGNE(Nombre)

Nombre és el nombre del qual es determinarà el signe.

Example

=SIGNE(3,4) retorna 1.

=SIGNE(-4,5) retorna -1.

SIN

Retorna el sinus de l'angle que s'ha indicat (en radians).

Syntax

SIN(Nombre)

Retorna el sinus (trigonomètric) de Nombre, l'angle en radians.

Per calcular el sinus d'un angle en graus, utilitzeu la funció RADIANS.

Example

=SIN(PI()/2) retorna 1, el sinus de PI/2 radians.

=SIN(RADIANS(30)) retorna 0,5, el sinus de 30 graus.

SINH

Retorna el sinus hiperbòlic d'un nombre.

Syntax

SINH(Nombre)

Retorna el sinus hiperbòlic d'un Nombre.

Example

=SINH(0) retorna 0, el sinus hiperbòlic de 0.

SUBTOTAL

Calcula subtotals. Si un interval ja conté subtotals, no s'utilitzen per fer altres càlculs. Utilitzeu esta funció amb els filtres automàtics per tindre en compte només els registres filtrats.

Syntax

SUBTOTAL(Funció; Interval)

Funció és un nombre que representa una de les funcions següents:

Índex de funcions

(includes hidden values)

Function index

(ignores hidden values)

Funció

1

101

MITJANA

2

102

COMPTA

3

103

COMPTAA

4

104

MAX

5

105

MIN

6

106

PRODUCTE

7

107

DESVEST

8

108

DESVESTP

9

109

SUMA

10

110

VAR

11

111

VARP


Use numbers 1-11 to include manually hidden rows or 101-111 to exclude them; filtered-out cells are always excluded.

Interval és l'interval les cel·les del qual s'inclouen.

Example

You have a table in the cell range A1:B6 containing a bill of material for 10 students. Row 2 (Pen) is manually hidden. You want to see the sum of the figures that are displayed; that is, just the subtotal for the filtered rows. In this case the correct formula would be:

A

B

1

ITEM

QUANTITY

2

Pen

10

3

Pencil

10

4

Notebook

10

5

Rubber

10

6

Sharpener

10


=SUBTOTAL(9;B2:B6) returns 50.

=SUBTOTAL(109;B2:B6) returns 40.

SUM

Suma tots els nombres d'un interval de cel·les.

Syntax

SUMA(Nombre1; Nombre2; ...; Nombre30)

Nombre1 a Nombre30 són fins a 30 arguments dels quals s'ha de calcular la suma.

Example

Si introduïu els nombres 2, 3 i 4 en els quadres de text Nombre 1, 2 i 3, es retornarà 9 com a resultat.

=SUMA(A1;A3;B5) calcula la suma de les tres cel·les. =SUMA (A1:E10) calcula la suma de totes les cel·les situades en l'interval d'A1 a E10.

Les condicions enllaçades amb I poden utilitzar-se amb la funció SUMA() de la manera següent:

Exemple hipotètic: heu introduït factures en una taula. La columna A conté el valor de data de la factura i la columna B, els imports. Voleu trobar una fórmula que pugueu utilitzar per calcular el total de tots els imports d'un mes determinat, p. ex., només l'import del període >=01-01-2008 a <01-02-2008. L'interval dels valors de dates és A1:A40; l'interval que conté els imports que s'han de totalitzar és B1:B40. C1 conté la data d'inici, 01-01-2008, de les factures que s'han d'incloure; C2 conté la data, 01-02-2008, que ja no s'inclou.

Introduïu la fórmula següent com una fórmula matricial:

=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Per introduir-ho com a fórmula matricial, heu de prémer les tecles Maj+Retorn en comptes de prémer només la tecla Retorn per tancar la fórmula. La fórmula es mostrarà llavors a la barra Fórmula, tancada entre claus.

{=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

La fórmula es basa en el fet que el resultat d'una comparació és 1 si es compleix el criteri de busca i 0 si no es compleix. Els resultats de la comparació individual es tractaran com una matriu i s'utilitzaran en una multiplicació matricial; tot seguit, es totalitzaran els valors individuals per donar la matriu del resultat.

SUMAQUAD

Si voleu calcular la suma dels quadrats dels nombres (el total dels quals correspondrà als quadrats dels arguments), introduïu-los en els camps de text.

Syntax

SUMAQUAD(Nombre1; Nombre2; ...; Nombre30)

Nombre1 a 30 són fins a 30 arguments dels quals s'ha de calcular la suma dels quadrats.

Example

Si introduïu els nombres 2, 3 i 4 en els quadres de text Nombre 1, 2 i 3, es retornarà 29 com a resultat.

SUMASERIES

Suma els primers termes d'una sèrie de potències.

SUMASERIES(x;n;m;coeficients) = coeficient_1*x^n + coeficient_2*x^(n+m) + coeficient_3*x^(n+2m) +...+ coeficient_i*x^(n+(i-1)m)

Syntax

SUMASERIES(X; N; M; Coeficients)

X és el valor d'entrada de la sèrie de potències.

N és la potència inicial.

M és la potència a la qual s'eleva N.

Coeficients és una sèrie de coeficients. La suma de sèries s'amplia una secció per a cada coeficient.

SUMIF

Suma les cel·les que s'han indicat segons uns criteris determinats. Esta funció s'utilitza per buscar un valor determinat en un interval.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in - LibreOffice Calc - Calculate.

Syntax

SUMASI(Interval; Criteris; IntervalDeSuma)

Interval és l'interval de cel·les on s'han d'aplicar els criteris.

Criteris és la cel·la on es mostra el criteri de busca, o el mateix criteri. Si s'escriu el criteri en la fórmula, s'ha de posar entre cometes dobles.

IntervalDeSuma és l'interval a partir del qual se sumen els valors. Si no s'ha indicat el paràmetre, se sumen els valors de l'Interval.

Icona de nota

SUMASI només admet l'operador de concatenació de referència (~) en el paràmetre Criteris, i només si no s'indica el paràmetre opcional IntervalDeSuma.


Example

Per sumar només els nombres negatius: =SUMASI(A1:A10;"<0").

=SUMASI(A1:A10;">0";B1:10): suma els valors de l'interval B1:B10 només si els valors corresponents de l'interval A1:A10 són >0.

Vegeu COMPTASI() per veure altres exemples de sintaxi que podeu utilitzar amb la funció SUMASI().

TAN

Retorna la tangent de l'angle indicat (en radians).

Syntax

TAN(Nombre)

Retorna la tangent (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la tangent d'un angle en graus, utilitzeu la funció RADIANS.

Example

=TAN(PI()/4) retorna 1, la tangent de PI/4 radians.

=TAN(RADIANS(45)) retorna 1, la tangent de 45 graus.

TANH

Retorna la tangent hiperbòlica d'un nombre.

Syntax

TANH(Nombre)

Retorna la tangent hiperbòlica d'un Nombre.

Example

=TANH(0) retorna 0, la tangent hiperbòlica de 0.

TRUNCA

Trunca un nombre mitjançant l'eliminació dels decimals.

Syntax

TRUNCA(Nombre; Comptatge)

Retorna el Nombre amb, com a màxim, els decimals de Comptatge. Els decimals que sobren s'eliminen, independentment del signe que tinguen.

TRUNCA(Nombre; 0) es comporta com ENT(Nombre) amb els nombres positius, però arrodoneix cap a zero els nombres negatius.

Icona d'avís

El nombre de decimals visibles del resultat s'indica a - LibreOffice Calc - Càlcul.


Example

=TRUNCA(1,239;2) retorna 1,23. El 9 es perd.

=TRUNCA(-1,234999;3) retorna -1,234. Tots els 9 es perden.