Modul
Vsebina
Kazalo 🔎︎

# Funkcije za delo z zbirkami podatkov

Ta del opisuje funkcije, ki jih uporabljamo s podatki, urejenimi kot ena vrstica podatkov za en zapis.

Kategorijo Zbirka podatkov imate lahko pomotoma za zbirko podatkov, ki je integrirana v LibreOffice. Vendar med zbirkami podatkov v LibreOffice in kategorijo Zbirka podatkov v LibreOffice Calc ni nobene povezave.

### Vzorčna zbirka podatkov:

V nekaterih primerih za opis funkcije bodo uporabljeni naslednji podatki:

V obsegu A1:E10 je seznam otrok, ki so povabljeni na Joejevo zabavo za rojstni dan. Za vsak vnos imamo naslednje informacije: v stolpcu A je ime, v B razred, potem starost v letih, razdalja do šole v metrih in teža v kilogramih.

| A | B | C | D | E
1 | Ime | Razred | Starost | Razdalja do šole | Teža
2 | Andrej | 3 | 9 | 150 | 40
3 | Betka | 4 | 10 | 1000 | 42
4 | Karel | 3 | 10 | 300 | 51
5 | Danijel | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Frane | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Haris | 3 | 9 | 1200 | 44
10 | Irena | 2 | 8 | 1000 | 42
11 |  |  |  |  |
12 |  |  |  |  |
13 | Ime | Razred | Starost | Razdalja do šole | Teža
14 |  |  |  | >600 |
15 |  |  |  |  |
16 | DCOUNT | 5 |  |  |

Formula v celici B16 je =DCOUNT(A1:E10;D1;A13:E14)

### Parametri funkcije za zbirko podatkov:

Sledijo definicije parametrov vseh funkcij zbirk podatkov:

Zbirka_podatkov je obseg celic, ki definirajo zbirko podatkov.

Potem ko se uveljavijo iskalni pogoji prvega parametra in so izbrane vrstice s podatki, polje_zbirke_podatkov določi, v katerem stolpcu bo funkcija operirala. Polje ni povezano s samimi iskalnimi pogoji. Ves obseg podatkov lahko določite s številom 0. Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

Iskalni_pogoji pomenijo obseg celic, ki vsebuje pogoje iskanja. Če v isto vrstico vpišete več pogojev, bodo med seboj povezani z AND. Če pogoje vpišete v različne vrstice, bodo povezani z OR. Prazne celice v iskalnih pogojih ne bodo upoštevane.

Če želite določiti, kako naj LibreOffice Calc išče enake vnose, izberite LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

Oglejte si tudi stran wiki Pogojno štetje in seštevanje.

## DAVERAGE

DAVERAGE izračuna povprečje vrednosti vseh celic (polj) v vseh vrsticah (zapisih v zbirkah podatkov), ki ustrezajo izbranim iskalnim pogojem.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DAVERAGE(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti povprečno težo vseh otrok enake starosti v zgornjem primeru (glejte višje na tej strani), v celico B16 vnesite to formulo:

=DAVERAGE(A1:E10;"Teža";A13:E14)

V 14. vrstico, pod Starost, vnesite 7, 8, 9, itd. eno za drugo. Pojavi se povprečna teža vseh otrok enake starosti.

## DCOUNT

DCOUNT prešteje število vrstic (zapisov) v zbirki podatkov, ki ustrezajo izbranim iskalnim pogojem in vsebujejo številčne vrednosti v stolpcu polje_zbirke_podatkov.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DCOUNT(zbirka_podatkov; [polje_zbirke_podatkov]; iskalni_pogoji)

Če je parameter polje_zbirke_podatkov izpuščen, DCOUNT vrne število vseh zapisov, ki ustrezajo iskalnim_pogojem. Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

V zgornjem primeru (glejte višje na tej strani) nas zanima, koliko otrok ima do šole več kot 600 metrov. Rezultat želimo shraniti v celici B16. Kazalko postavite v celico B16. V celico B16 vnesite formulo =DCOUNT(A1:E10;D1;A13:E14). Čarovnik za funkcije vam je v pomoč pri vnosu obsegov.

Zbirka_podatkov je obseg podatkov, ki bodo vrednoteni, vključno z glavami: v tem primeru A1:E10. Polje_zbirke_podatkov določa stolpec za iskalne pogoje: v tem primeru stolpec z vrednostmi numerične oddaljenost. Iskalni_pogoj je obseg, kamor lahko vnesete iskalne parametre: v tem primeru A13:E14.

Če želite izvedeti, koliko otrok v drugem razredu je starejših od 7 let, izbrišite vnos >600 v celici D14, vnesite 2 v celico B14 pod Razred in vnesite >7 v celico C14 na desni. Rezultat je 2. Dva otroka v drugem razredu sta starejša od 7 let. Ker sta oba pogoja v isti vrstici, sta povezana z AND.

## DCOUNTA

DCOUNTA prešteje število vrstic (zapisov) v zbirki podatkov, ki ustrezajo določenim iskalnim pogojem in vsebujejo številčne ali črkovno-številčne vrednosti.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DCOUNTA(zbirka_podatkov; [polje_zbirke_podatkov]; iskalni_pogoji)

Če je parameter polje_zbirke_podatkov izpuščen, DCOUNTA vrne število vseh zapisov, ki ustrezajo iskalnim_pogojem. Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

V zgornjem primeru (pomaknite se, prosimo, navzgor) lahko iščete število otrok, katerih ime se začne z E ali sledečimi črkami. Uredite formulo v celici B16, da bo vsebina sledeča: =DCOUNTA(A1:E10;"Ime";A13:E14). Izbrišite stari pogoj iskanja in vnesite >=E v polje A14 pod Ime. Rezultat je 5. Če zdaj izbrišete vse vrednosti za Greta v vrstici 8, se rezultat spremeni v 4. Vrstica 8 ni več vključena v štetje, ker ne vsebuje vrednosti. Ime Greta je besedilo in ne vrednost. Bodite pozorni na to, da mora parameter Polje_zbirke_podatkov kazati na stolpec, ki lahko vsebuje vrednosti.

## DGET

DGET najde vsebino določene celice v zbirki podatkov, ki ustreza izbranim iskalnim pogojem.Kadar pride do napake, funkcija vrne sporočilo #VALUE!, če ni našla nobene vrstice, oziroma ERR502, če je našla več kot eno celico.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DGET(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

V zgornjem primeru (glejte višje na tej strani) želimo ugotoviti, v katerem razredu je otrok, ki je napisan v celici A14. Formulo vnesemo v celico B16 in je malo drugačna od prejšnjih primerov, saj lahko za Polje_zbirke_podatkov vnesemo samo en stolpec (eno polje zbirke podatkov). Vnesite naslednjo formulo:

=DGET(A1:E10;"Razred";A13:E14)

V celico A14 vnesite ime Franci in dobili boste rezultat 2. Franci je v drugem razredu. Če namesto »Razred« vnesete »Starost«, boste dobili Francijevo starost.

Ali pa vnesite vrednost 11 samo v celico C14 in izbrišite ostale vnose v tej vrstici. Formulo B16 uredite tako:

=DGET(A1:E10;"Ime";A13:E14)

Namesto po razredu sprašujemo po imenu. Odgovor se pojavi takoj: Daniel je edini otrok, ki je star 11 let.

## DMAX

DMAX najde največjo vsebino celice (polja) v zbirki podatkov (vsi zapisi), ki ustreza izbranim iskalnim pogojem.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DMAX(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti, koliko v zgornjem primeru (glejte višje na tej strani) tehta najtežji otrok v vsakem razredu, v celico B16 vnesite to formulo:

=DMAX(A1:E10;"Teža";A13:E14)

Pod »Razred« vnesite 1, 2, 3 itd. eno za drugo. Po vnosu številke razreda se pojavi teža najtežjega otroka v tem razredu.

## DMIN

DMIN vrne najmanjšo vsebino celice (polja) v zbirki podatkov, ki ustreza izbranim iskalnim pogojem.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DMIN(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite pri zgornjem primeru (glejte višje na tej strani) ugotoviti, kdo ima v vsakem razredu najkrajšo pot do šole, v celico B16 vnesite to formulo:

=DMIN(A1:E10;"Razdalja do šole";A13:E14)

V 14. vrstico, pod »Razred«, vnesite 1, 2, 3 itn. eno za drugo. Za vsak razred se pojavi najkrajša razdalja do šole.

## DPRODUCT

DPRODUCT zmnoži vse celice tistega obsega podatkov, kjer vsebina celic ustreza iskalnim pogojem.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DPRODUCT(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

V zgornjem primeru z zabavo za rojstni dan (glejte višje na tej strani) se te funkcije ne da smiselno uporabiti.

## DSTDEV

DSTDEV na podlagi vzorca izračuna standardni odklon populacije z uporabo številk v stolpcu zbirke podatkov, ki ustreza danim pogojem. Zapisi so obravnavani kot vzorec podatkov. To pomeni, da so otroci v zgornjem primeru tipični predstavniki vseh otrok. Če je vzorec manj kot tisoč, ne morete dobiti reprezentativnega rezultata.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DSTDEV(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti standardni odklon teže vseh otrok enake starosti v zgornjem primeru (glejte višje na tej strani), v celico B16 vnesite naslednjo formulo:

=DSTDEV(A1:E10;"Teža";A13:E14)

V 14. vrstico, pod Starost, vnesite 7, 8, 9, itd. eno za drugo. Dobljeni rezultat je standardni odklon teže vseh otrok te starosti.

## DSTDEVP

DSTDEVP izračuna standardni odklon populacije na podlagi vseh celic tistega obsega podatkov, ki ustreza iskalnim pogojem. Zapisi iz primera so obravnavani kot celotna populacija.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DSTDEVP(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti standardni odklon teže vseh otrok enake starosti na zabavi ob Jankovem rojstnem dnevu v zgornjem primeru (glejte višje na tej strani), v celico B16 vnesite naslednjo formulo:

=DSTDEVP(A1:E10;"Teža";A13:E14)

V 14. vrstico, pod Starost, vnesite 7, 8, 9, itd. eno za drugo. Rezultat je standardni odklon teže vseh otrok iste starosti, katerih teža je bila preverjena.

## DSUM

DSUM izračuna vsoto vseh celic v polju zbirke podatkov v vseh vrsticah (zapisih), ki ustrezajo izbranim iskalnim pogojem.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DSUM(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti skupno razdaljo do šole za vse otroke na zabavi za Jožetov rojstni dan (glejte višje na tej strani), ki so v drugem razredu, v celico B16 vnesite to formulo:

=DSUM(A1:E10;"Razdalja do šole";A13:E14)

V 14. vrstico, pod Razred, vnesite 2. Prikazana je vsota (1950) razdalj do šole vseh otrok, ki so v drugem razredu.

## DVAR

DVAR izračuna varianco vseh celic polja zbirke podatkov v vseh zapisih, ki ustrezajo izbranim iskalnim pogojem.Zapisi iz primera so obravnavani kot vzorec podatkov. Če je vzorec populacije manj kot tisoč, ne morete dobiti reprezentativnega rezultata.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DVAR(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti varianco teže vseh otrok enake starosti v zgornjem primeru (glejte višje na tej strani), v celico B16 vnesite to formulo:

=DVAR(A1:E10;"Teža";A13:E14)

V 14. vrstico, pod Starost, vnesite 7, 8, 9, itd. eno za drugo. Kot rezultat boste dobili varianco vrednosti teže vseh otrok te starosti.

## DVARP

DVARP izračuna varianco vseh vrednosti celic v polju zbirke podatkov v vseh zapisih, ki ustrezajo izbranim iskalnim pogojem.Zapisi iz primera so obravnavani kot celotna populacija.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v LibreOffice – Nastavitve Orodja – Možnosti
– LibreOffice Calc – Izračuni.

### Skladnja

DVARP(zbirka_podatkov; polje_zbirke_podatkov; iskalni_pogoji)

Če hočete za sklicevanje na stolpec uporabiti ime glave stolpca, dajte ime glave v narekovaje.

### Primer

Če želite izvedeti varianco teže vseh otrok enake starosti na zabavi ob Jožetovem rojstnem dnevu v zgornjem primeru (glejte višje na tej strani), v celico B16 vnesite to formulo:

=DVARP(A1:E10;"Teža";A13:E14)

V 14. vrstico, pod Starost, vnesite 7, 8, 9, itd. eno za drugo. Pokaže se varianca vrednosti tež vseh otrok te starosti, ki so prišli na Joejevo zabavo.

Podobne teme

Seznam funkcij po kategorijah