Module
Contents
Index 🔎︎

## funció COMPTASICONJUNT

Returns the count of cells that meet criteria in multiple ranges.

### Sintaxi

COUNTIFS(Range1; Criterion1 [; Range2; Criterion2 [; ...]])

Range1 – required argument. It is a range of cells, a name of a named range or a label of a column or a row containing values for counting and finding the corresponding criterion.

Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion1.

Range1, Range2, ... and Criterion1, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

This function is part of the Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

### Exemples

#### Considereu la taula següent

| A | B | C
1 | Nom del producte | Vendes | Ingressos
2 | llapis | 20 | 65
3 | llapis | 35 | 85
4 | bloc de notes | 20 | 190
5 | llibre | 17 | 180
6 | estoig | no | no

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

#### Ús simple

=COMPTASICONJUNT(B2:B6;">=20")

Compta la quantitat de files de l'interval B2:B6 amb valors majors o igual a 20. Retorna 3, perquè la cinquena i la sisena files no compleixen el criteri.

=COMPTASICONJUNT(B2:B6;">=20";C2:C6;">70")

Compta la quantitat de files que contenen simultàniament valors majors de 70 en l'interval C2:C6 i valors majors o iguals a 20 en l'interval B2:B6. Retorna 2, perquè la segona, la cinquena i la sisena files no compleixen almenys un criteri.

#### Ús d'expressions regulars i funcions imbricades

=COMPTASICONJUNT(B2:B6;"[:alpha:]*")

Compta la quantitat de files de l'interval B2:B6 que contenen només símbols alfabètics. Retorna 1, perquè només la sesena fila compleix el criteri.

=COMPTASICONJUNT(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Compta la quantitat de files de l'interval B2:B6 excloent les files amb valors mínims i màxims d'este interval. Retorna 2, perquè la tercera, la cinquena i la sisena files no compleixen com a mínim un criteri.

=COMPTASICONJUNT(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Compta la quantitat de files que corresponen a totes les cel·les de l'interval A2:A6 començant per "llapis" i a totes les cel·les de l'interval B2:B6 excepte el màxim. Retorna 1, perquè només la segona fila compleix tots els criteris.

#### Referència a una cel·la com a criteri

Si heu de canviar el criteri fàcilment, potser voleu indicar-lo en una cel·la separada i usar una referència a esta cel·la en la condició de la funció SUMASI. Per exemple, la funció superior es pot reescriure com a:

=COMPTASICONJUNT(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2 = llapis, la funció retorna 1, perquè l'enllaç a la cel·la se substitueix amb el seu contingut i funciona com a funció a dalt.

Temes relacionats

COUNT, COUNTIF, COUNTBLANK, COUNTA

funció COMPTASICONJUNT, MINIFS, MAXIFS, funció MITJANASICONJUNT, funció SUMASICONJUNT

Llista d'expressions regulars