Module
Inhoud
Index 🔎︎

# MAX.ALS functie

Geeft het maximum van de waarden van de cellen in een bereik die aan meerdere criteria in meerdere bereiken voldoen.

### Syntaxis

MAX.ALS(Functiebereik; Bereik1; Criterium1 [ ; Bereik2; Criterium2 [;...]]))

Functiebereik – vereist argument. Het is een reeks cellen, een naam van een benoemd bereik of een label van een kolom of een rij met waarden, voor de berekening van het gemiddelde.

Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Bereik2 – Optioneel. Bereik2 en alle volgende hebben dezelfde betekenis als Bereik1.

Criterium2 – Optioneel. Criterium2 en alle volgende hebben dezelfde betekenis als Criterium1.

Functiebereik enBereik1, Bereik2... moeten hetzelfde formaat hebben, anders geeft de functie fout:502 - Ongeldig argument.

De logische relatie tussen criteria kan worden gedefinieerd als logische EN (conjunctie). Met andere woorden, als en alleen als aan alle gegeven criteria is voldaan, wordt een waarde uit de overeenkomstige cel van de gegeven Functiebereik in de berekening meegenomen.

De functie kan maximaal 255 argumenten bevatten, wat betekent dat u 127 bereiken en voorwaarden kunt opgeven.

Als een cel WAAR bevat, wordt het behandeld als 1, als een cel ONWAAR bevat als 0 (nul).

Deze functie maakt deel uit van het Open Document Format voor Office Applications (OpenDocument) standaard versie 1.2. (ISO/IEC 26300: 2-2015)

### Voorbeeld

#### Overweeg de volgende tabel

| A | B | C
1 | Productnaam | Verkopen | Ontvangsten
2 | potlood | 20 | 65
3 | pen | 35 | 85
4 | kladblok | 20 | 190
5 | boek | 17 | 180
6 | etui | niet | niet

In alle onderstaande voorbeelden, bevatten bereiken voor berekening de rij # 6, die genegeerd wordt omdat deze tekst bevat.

#### Eenvoudig gebruik

=MAX.ALS(B2:B6;B2:B6;"<35")

Berekent het maximum van de waarden van het bereik B2:B6 die groter of gelijk zijn aan 20. Dit geeft 35, omdat de vijfde rij niet aan het criterium voldoet.

=MAX.ALS(C2:C6;B2:B6;">=20";C2:C6;"<90")

Berekent het maximum van waarden van het bereik C2:C6 die lager zijn dan 90 en corresponderen met cellen van het bereik B2:B6 met waarden groter dan of gelijk aan 20. Retourneert 85, omdat de vierde en vijfde rij niet voldoen aan tenminste één criterium.

#### Met behulp van reguliere expressies en geneste functies

=MAX.ALS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berekent het maximum van de waarden van het bereik C2:C6, die overeenkomen met alle waarden van het bereik B2:B6 behalve het minimum en het maximum. Dit geeft 190, omdat alleen de vierde rij aan het criterium voldoet.

=MAX.ALS(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MAX(B2:B6))

Berekent het maximum van waarden van het bereik C2:C6 dat overeenkomt met alle cellen van het bereik A2: A6 beginnend met "pen" en met alle cellen van het bereik B2:B6, behalve het maximum. Retourneert 85, omdat alleen de derde rij aan alle criteria voldoet.

#### Refereer naar een cel als een criterium

Als u een criterium gemakkelijk wilt wijzigen, kunt u dit in een afzonderlijke cel opgeven en een verwijzing naar deze cel gebruiken in de voorwaarde van de MAX.ALS-functie. De bovenstaande functie kan bijvoorbeeld als volgt worden herschreven:

=MAX.ALS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Als E2 = "pen", geeft de functie 65, omdat de koppeling naar de cel wordt vervangen met de inhoud ervan.

Verwante onderwerpen

MAX, MAXA, MIN, MINA,

AANTAL.ALS, MIN.ALS, MAX.ALS, GEMIDDELDE.ALS, SOM.ALS

Lijst met reguliere expressies