Modül
İçerikler
Dizin 🔎︎

# Veritabanı İşlevleri

Bu kısım her bir satırı bir kayıt olan verilerle çalışan işlevlere değinmektedir.

veri tabanı kategorisi ile, LibreOffice'a entegre edilmiş veritabanı kafa karıştırabilir. Fakat LibreOffice Calc veritabanı kategorisi ile LibreOffice veritabanı arasında hiçbir bağlantı yoktur.

### Örnek Veri:

Takip eden veri bazı foksiyonların açıklanmasında kullanılacaktır.

A1:E10 aralığı Joe'nun yaş günü partisine katılan çocukların listesidir. Her giriş için şu bilgiler verilmiştir. Sütun A İsim görüntüler, B Sınıf, sonrakiler sırasıyla, yıllara göre Yaş, metre olarak Okula Uzaklık ve kilogram olarak Ağırlık.

| A | B | C | D | E
1 | İsim | Sınıf | Yaş | Okula Uzaklık | Ağırlık
2 | Andy | 3 | 9 | 150 | 40
3 | Betty | 4 | 10 | 1000 | 42
4 | Charles | 3 | 10 | 300 | 51
5 | Daniel | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Sınıf | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Harry | 3 | 9 | 1200 | 44
10 | Irene | 2 | 8 | 1000 | 42
11 |  |  |  |  |
12 |  |  |  |  |
13 | İsim | Sınıf | Yaş | Okula Uzaklık | Ağırlık
14 |  |  |  | >600 |
15 |  |  |  |  |
16 | VSEÇSAY | 5 |  |  |

B16 hücresindeki formül =VSEÇSAY(A1:E10;0;A13:E14)

### Veritabanı İşlev Parametreleri:

Sözü edilen öğeler veritabanı işlevlerinin parametre tanımlarıdır.

Veritabanı veritabanını tanımlayan hücre aralığıdır.

Veritabanı_alanı işlevin arama ölçütündeki parametresini araştıracağı ilk sütun ve seçili veri satırlarıdır. Bu alan arama ölçütleri ile doğrudan bağlantılı değildir.Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

Arama_ölçütleri bir hücre aralığında bulunmalıdır. Eğer çeşitli ölçütleri bir satırda yazarsanız, bunlar birbirlerine VE işlemiyle bağlanır. Ölçütleri farklı satırlara yazarsanız bu ölçütler VEYA işlemiyle bağlanır. Arama_ölçütleri alanında boş hücreler ihmal edilir.

Aynı girdiler içi arama yaparken LibreOffice uygulamasının nasıl davranacağını tanımlamak için LibreOffice - Tercihler Araçlar - Seçenekler
- LibreOffice Calc - Hesaplamayı seçin.

Şartlı Sayma ve Toplama Wiki sayfasına bakın.

## VAL

VAL Veri tabanı aralığında arama kriterine uyan hücrenin içeriği ile döner. Bir hata oluşması durumunda, uyan satır bulunamamışsa #VALUE! hatası görüntülenir. Birden fazla hücre bulunmuş ise Hata502 görüntülenir.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VAL(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Yukarıdaki örnekte (lütfen, yukarı bakın), ismi A14 hücresinde girilmiş olan çocuğun hangi sınıfta olduğunu tespit etmek istiyoruz. B16 hücresine girilen formül önceki örneklere göre biraz farklı olur. Çünkü sadece bir sütun ( bir veritabanı alanı) Veritabanı_alanı girilebilir. Takip eden formülü girin:

=Val(A1:E10;"Sınıf";A13:E14)

A14 hücresine Frank ismini girin, 2 sonucunu görürsünüz. Frank ikinci sınıftadır. "Sınıf" yerine "Yaş" girerek, Frank'ın yaşını öğrenebilirsiniz.

Veya sadece C14 hücresine 11 değerini girin, ve bu satırdaki diğer girişleri silin. B16'daki formülü şu şekilde yazın:

=VAL(A1:E10;"İsim";A13:E14)

Sınıf yerine, isim sorgulanır. Sonuç derhal görüntülenir: Daniel 11 yaşından büyük olan tek çocuktur.

## VSEÇMAK

VSEÇMAK Bir listenin veya veritabanının bir sütunundaki belirttiğiniz koşullarla eşleşen satırlardaki en büyük sayıyı verir.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇMAK(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Üstteki örnekte her sınıftaki arama ölçütünden daha ağır çocukların kaç tane olduğunu öğrenmek için(Lütfen yukarıdaki tabloya bakın), bu formülü B16 hücresine girin:

=VSEÇMAK(A1:E10;"Ağırlık";A13:E14)

Sınıf etiketi altına sırasıyla 1, 2, 3,. bir sınıf numarası girildikten sonra, bu sınıftaki en ağır çocuğun ağırlığı görülür.

## VSEÇMİN

VSEÇMİN Veri aralığındaki arama kriterlerine uyan hücrelerdeki en küçük içerik değeri ile geri döner.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇMİN(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Üstteki örnekte, her sınıftaki çocukların en kısa uzaklık değerini bulmak için (lütfen yukarıya bakın), takip eden formülü B16 hücresine girin:

=VSEÇMİN(A1:E10;"Okula Uzaklık";A13:E14)

Satır 14'de, Sınıf etiketi altında sırasıyla 1, 2, 3, değerlerini girin. Her sınıf için en kısa uzaklık görüntülenir..

## VSEÇORT

VSEÇORT Bir listenin veya veritabanının bir sütunundaki, belirttiğiniz koşulları karşılayan değerlerin ortalamasını alır.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇORT(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Aynı yaştaki bütün çocukların ortalama ağırlıklarını öğrenmek için (lütfen yukarı bakın), takip eden formülü B16 hücresine girin:

=VSEÇORT(A1:E10;"Ağırlık";A13:E14)

Yaş etiketi altındaki 14. satıra, sırasıyla 7, 8, 9, değerlerini girin. Aynı yaşlardaki bütün çocukların ortalama ağırlıkları görüntülenir.

## VSEÇSAY

VSEÇSAY Bir listenin veya veritabanının bir sütunundaki belirttiğiniz koşulları ve sayısal değerleri karşılayan satırları sayar.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇSAY(Veritabanı; [Veritabanı_alanı]; AramaÖlçütleri)

Eğer VeritabanıAlanı değişkeni atlanırsa VSEÇSAY Kritere uygun tüm kayıtların sayısını döndürür. Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Yukarıdaki örnekte (lütfen yukarıya bakın), kaç tane çocuğun okula 600 metreden daha fazla yolu olduğunu öğrenmek istiyoruz. Sonuç B16 hücresinde görüntülenecektir. İmleci B16 hücresine yerleştirin. =VSEÇSAY(A1:E10;0;A13:E14) formülünü B16 hücresine girin. İşlev Sihirbazı girdi aralıkları için size yardım eder.

Veritabanı başlıkları bulunan, verinin değerlendirileceği aralıktır: bu durumda A1:E10. Veritabanı_alanı arama ölçütü için sütun belirler: bu durumda bütün veritabanı. Arama_ölçütleri arama parametrelerini girebileceğiniz aralıktır: bu durumda, A13:E14.

İkinci sınıftaki çocuklardan 7 yaş üstünde olan çocukların sayısını öğrenmek için, D14 hücresindeki >600 girdisini silin. Sınıf etiketi altındaki B14 hücresine 2 girin, ve sağdaki C14 hücresine >7 girin. Sonuç 2 olur. İki çocuk ikinci sınıftadır ve yaşları 7 yaşından büyüktür. Aynı satırda olan her iki ölçütde, VE mantıksal işlemiyle değerlendirilir.

## VSEÇSAYDOLU

VSEÇSAYDOLU Bir listenin veya veritabanının bir sütunundaki belirttiğiniz koşullarla eşleşen boş olmayan bütün hücreleri (kayıtları) sayar. Kayıtlar sayısal ya da abecesayısal olabilir.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇSAYDOLU(Veritabanı; [Veritabanı_alanı]; AramaÖlçütleri)

Eğer VeritabanıAlanı değişkeni atlanırsa VSEÇSAYDOLU Kritere uygun tüm kayıtların sayısını döndürür. Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Yukarıdaki örnekte (lütfen, yukarıya bakın), İsmi E harfi ya da daha büyük harfler ile başlayan çocukları araştırabilirsiniz. B16 hücresindeki formülü, =VSEÇSAYDOLU(A1:E10;"Yaş";A13:E14) olacak şekilde düzenleyelim. Eski arama ölçütünü silin ve isim alanındaki A14 hücresine >=E metnini girin. Sonuç 5 olur. Eğer satır 8'deki Greta için bütün sayı değerlerini silerseniz, sonuç 4 olarak değişir. Satır 8 artık hesaplamaya dahil edilmemektedir çünkü hiç bir veri içermemektedir. Greta sayı değil bir metindir. Şunu da not edelim, VeritabanıAlanı sayıların olduğu bir sütunu işaret etmelidir.

## VSEÇSTDSAPMA

VSEÇSTDSAPMA Veri aralığında arama kriterine uyan sütundaki hücre içeriği sayılarını kullanarak, bir örnek üzerindeki popülasyonun standart sapmasını hesaplar. Örnekten alınan kayıtlar veri örneği olarak işlenir. Bu örnekteki çocuklar bütün çocuklara karşı bir kesit olarak ele alınır. Şayet örnek popülasyonu binden az ise görüntülenebilir bir sonuç elde edilemez.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇSTDSAPMA(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Örnekteki aynı yaştaki bütün çocukların ağırlıklarının standart sapmasını öğrenmek için (lütfen yukarıya bakın), bu formülü B16 hücresine girin:

=VSEÇSTDSAPMA(A1:E10;"Ağırlık";A13:E14)

Yaş etiketi altındaki 14. satıra, sırasıyla 7, 8, 9, değerlerini girin. Joe'nun yaş günü partisine katılan, belirtilen yaşlardaki bütün çocukların ağırlıklarının standart sapması görüntülenir.

## VSEÇSTDSAPMAS

VSEÇSTDSAPMAS Bir veri alanındaki aranan kriterlere uyan bütün hücrelerin popülasyon tabanınında standart sapmasını hesaplar. Örnekteki kayıtlar bütün popülasyon olarak ele alınır.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇSTDSAPMAS(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Joe'nun yaş günü partisindeki aynı yaştaki bütün çocukların ağırlıklarının standart sapmasını bulmak için (Lütfen yukarıdaki tabloya bakın), bu formülü B16 hücresine girin:

=VSEÇSTDSAPMAS(A1:E10;"Ağırlık";A13:E14)

Satır 14'de, Yaş etiketinin altına sırasıyla 7, 8, 9, girin. Sonuçlar aynı yaş aralığındaki bütün çocukların ağırlıklarının standart sapmasıdır.

## VSEÇTOPLA

VSEÇTOPLA Veri tabanı aralığındaki arama kriterlerine uyan hücrelerin bütün satırlarındaki (Kayıtlar) toplamı ile döner.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇTOPLA(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Joe'nun yaş günündeki ikinci sınıftaki bütün çocukların Okula uzaklık birleşmiş toplamını öğrenmek için (lütfen yukarıya bakın), bu formülü B16 hücresine girin:

=VSEÇTOPLA(A1:E10;"Okula uzaklık";A13:E14)

Satır 14'de Sınıf etiketi altında 2 değerini girin. İkinci sınıftaki bütün çocukların okula uzaklık toplamı (1950) görüntülenecektir.

## VSEÇVAR

VSEÇVAR Veri aralığındaki arama kriterlerine uyan bütün hücrelerin varyansı ile geri döner. Örnekten alınan kayıtlar veri örneği olarak işlenir. Şayet örnek popülasyonu binden az ise görüntülenebilir bir sonuç elde edilemez.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇVAR(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Aynı yaştaki bütün çocukların ağırlıklarının (Varyans) değişimini bulmak için (Lütfen yukarıdaki tabloya bakın), bu formülü B16 hücresine girin:

=VSEÇVAR(A1:E10;"Ağırlık";A13:E14)

Yaş etiketi altındaki 14. satıra, sırasıyla 7, 8, 9, değerlerini girin. Belirtilen yaşlardaki bütün çocukların ağırlıklarının (Varyans) değişim sonucunun görüntülendiğini göreceksiniz.

## VSEÇVARS

VSEÇVARS Bir listenin veya veritabanının belirttiğiniz koşullarla eşleşen bir sütunundaki sayıları kullanarak, bir popülasyonun varyansını popülasyonun tümüne bağlı olarak hesaplar. Örnekteki kayıtlar bütün popülasyon'un örneği olarak işlenir.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇVARS(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Joe'nun yaş günü partisindeki aynı yaştaki bütün çocukların ağırlıklarının (Varyans) değişimini bulmak için (Lütfen yukarıdaki tabloya bakın), bu formülü B16 hücresine girin:

=VSEÇVARS(A1:E10;"Ağırlık";A13:E14)

Yaş etiketi altındaki 14. satıra, sırasıyla 7, 8, 9, değerlerini girin. Joe'nun yaş günü partisine katılan, belirtilen yaşlardaki bütün çocukların ağırlıklarının değişimi (Varyans) görüntülenir.

## VSEÇÇARP

VSEÇÇARP Veri aralığındaki Arama kriterlerine uyan bütün hücreleri çarpar.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

VSEÇÇARP(Veritabanı; Veritabanı_alanı; Arama_ölçütleri)

Veritabanı_alanı parametresi için hücre üstbilgisine bir referans veya Veritabanı alanında sütunu belirleyen 1'den başlayarak artan bir sayı girebilirsiniz. Sütun üstbilgi adı ile bir sütuna başvurmak için üstbilgi adının başına tırnak işaretleri koyun.

### Example

Yukarıdaki Yaş günü partisi örneğiyle (lütfen yukarı bakın), bu işlevin anlamlı bir uygulaması yoktur.

İlgili Konular

Kategoriler Halinde Fonksiyonlar