Modül
İçerikler
Dizin 🔎︎

## EĞERORTALAMA işlevi

Verilen koşulu sağlayan tüm hücrelerin aritmetik ortalamasını döndürür. EĞERORTALAMA fonksiyonu verilen mantıksal teste uyan tüm değerleri toplar ve değer sayısına böler.

### Syntax

EĞERORTALAMA(Aralık; Kriter [; Ortalama_Aralığı ])

Aralık – gerekli değişken. Bir dizi, isimlendirilmiş bir dizinin adı veya sayılar içeren satır ya da sütun etiketi veya koşul için sayılar veya metin.

Koşul – gerekli değişken. İfade formundaki bir durum ya da sayım için hangi hücrelerin kullanılması gerektiğini tanımlayan bir ifadeye hücre referansı. İfade, metin, sayı, normal ifadeler (hesaplama seçeneklerinde etkinleştirilmişse) veya joker karakterler (hesaplama seçeneklerinde etkinleştirilmişse) içerebilir.

Ortalama_Aralık – seçimsel. Ortalamanın hesaplanması için bir değer aralığıdır.

Ortalama_Aralık belirtilmezse Aralık değerinin hem ortalamanın hesaplanmasında, hem de duruma göre aramada kullanılacağını unutmayın. Ortalama_Aralık belirtilirse Aralık sadece durum testinde kullanırken, Ortalama_Aralık ortalama hesaplanmasında kullanılır.
Kriter bir dizi ifadesi olmalıdır, özellikle işlev adları, hücre başvuruları ve bir dizgi birleştirme işleminin (&) çalışması dışında Kriter tırnak içinde yazılmalıdır ("Kriter").

Bu fonksiyon Ofis Uygulamaları (OpenDocument) standardının sürüm 1.2 Açık Belge Biçiminin bir parçasıdır. (ISO/IEC 26300:2-2015)

Ortalama hesaplamak için bir değer aralığında bir hücre boşsa veya metin içeriyorsa, EĞERORTALAMA işlevi bu hücreyi yok sayar.
Tüm aralık boşsa, yalnızca metin içeriyorsa veya aralığın tüm değerleri koşulu karşılamıyorsa (veya bunların herhangi bir kombinasyonu), işlev #DIV/0! hatasını döndürür.

### Example

#### Şu tabloyu düşünün

| A | B | C
1 | Ürün Adı | Satış | Hasılat
2 | kurşun kalem | 20 | 65
3 | kalem | 35 | 85
4 | defter | 20 | 190
5 | kitap | 17 | 180
6 | kalem kutusu | değil | değil

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

Aşağıdaki tüm hesaplamalarda, ortalama hesabı için aralık, satır #6 yı içeriyor fakat bu satır görmezden gelindi çünkü metin içeriyor.

#### Basit kullanım

=EĞERORTALAMA(B2:B6;"<35")

B2:B6 aralığının 35'ten küçük değerlerinin ortalamasını hesaplar. İkinci satır hesaplamaya katılmadığından 19'u döndürür.

=EĞERORTALAMA(B2:B6;"<"&MAK(B2:B6))

Aynı aralığın bu aralığın maksimum değerinden küçük değerler için ortalamasını hesaplar. En büyük değer (ikinci satır) hesaplamaya katılmadığı için 19'u döndürür.

=EĞERORTALAMA(B2:B6;">"&KÜÇÜK(B2:B6;1))

Bu aralığın ilk en küçük değerinden daha büyük olan aynı aralıktaki değerlerin ortalamasını hesaplar. İlk küçük değer (dördüncü satır) hesaplamaya katılmadığı için 25 döndürür.

#### Ortalama_Aralık kullanımı

=EĞERORTALAMA(B2:B6;"<35";C2:C6)

İşlev, B2:B6 aralığında hangi değerlerin 35'in altında olduğunu araştırır ve C2:C6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. İkinci satır hesaplamaya katılmadığı için 145 döndürür.

=EĞERORTALAMA(B2:B6;">"&MİN(B2:B6);C2:C6)

İşlev, B2:B6 aralığındaki hangi değerlerin B2:B6 aralığındaki en düşük değerden büyük olduğunu ve C2:C6 aralığındaki ilgili değerlerin ortalamasını hesaplar. Dördüncü satır (B2:B6 aralığındaki en düşük değer bulunduğu yerde) hesaplamaya katılmadığı için 113.3 döndürür.

=EĞERORTALAMA(B2:B6;"<"&BÜYÜK(B2:B6;2);C2:C6)

İşlev, B2: B6 aralığındaki hangi değerlerin B2:B6 aralığındaki ikinci büyük değerden küçük olduğunu ve C2:C6 aralığındaki ilgili değerlerin ortalamasını hesaplar. Hesaplamaya yalnızca dördüncü satır katıldığından 180 döndürür.

#### Düzenli ifadeleri kullanmak

=EĞERORTALAMA(A2:A6;"kalem";B2:B6)

İşlev, A2:A6 aralığındaki hücrelerin yalnızca "kalem" kelimesini içeren ve B2:B6 aralığındaki ilgili değerlerin ortalamasını hesaplar. Hesaplamaya yalnızca ikinci satır katıldığı için 35 döndürür. Arama A2:A6 aralığında yapılır, ancak değerler B2:B6 aralığından döndürülür.

=EĞERORTALAMA(A2:A6;"kalem.*";B2:B6)

İşlev, A2:A6 aralığındaki hücrelerin herhangi bir miktarda diğer karakterle biten "kalem" ile başlayan ve B2:B6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. 27,5'i döndürdür, çünkü artık "kalem" de durumu karşılar ve her iki hesapta birinci ve ikinci satırlar katılır.

=EĞERORTALAMA(A1:A6;".*kitap.*";B2:B6)

İşlev A2:A6 aralığındaki hücrelerde "kitap" karakterlerini önünde ve sonunda başka karakterler ile birlikte arar ve onlara karşılık gelen B2:B6 aralığındaki değerlerin ortalamasını hesaplar. Sadece üçüncü ve dördüncü satırlar hesaplamaya dahil edildiğinden 18.5 döndürür.

#### Bir kriter olarak bir hücreye başvuru

Bir ölçütü kolayca değiştirmek istiyorsanız, onu ayrı bir hücrede belirtmek ve EĞERORTALAMA işlevi koşulunda bu hücreye bir referans kullanmak isteyebilirsiniz.

=EĞERORTALAMA(A2:A6;".*"&E2&".*";B2:B6)

İşlev, A2:A6 aralığındaki hücrelerin, E2'de belirtilen karakterlerin birleşimini içerdiğini ve herhangi bir sayıda karakterle başlayıp bitmesini araştırır ve B2:B6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. E2 = kitap ise, işlev 18.5 döndürür.

=EĞERORTALAMA(B2:B6;"<"&E2;C2:C6)

İşlev, B2:B6 aralığındaki hücrelerin E2'de belirtilen değerden küçük olanları arar ve C2:C6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. E2 = 35 ise, işlev 145 döndürür.

İlgili Konular

AVERAGE, AVERAGEA, AVEDEV

ÇOKEĞERSAY, MINIFS, MAXIFS, ÇOKEĞERORTALAMA, ÇOKETOPLA

Düzenli İfadeler Listesi