Modül
İçerikler
Dizin 🔎︎

# Hesap Tablosu İşlevleri

Bu kısım Hesap tablosu işlevlerini bir örnek ile birlikte açıklar.

Bu komuta erişmek...

Ekle - İşlev - Kategori Hesap Tablosu

## HATA.TÜRÜ

Belirli bir Hata türüne karşılık gelen bir sayı, eğer böyle bir hata yoksa #N/A hata değerini döndürür.

## ADDRESS

Verilen belirli satır ve sütun sayıları ile bir hücre adresini metin olarak oluşturur. Adres'in mutlak (örneğin, $A$1) veya bağıl adres (as A1) veya karışık olarak(A$1 veya $A1) ele alınmasını MUTLAKDEĞER alanı girdisi ile belirleyebilirsiniz. Ayrıca sayfa adını da belirleyebilirsiniz.

İç uyumluluk açısından ADRES ve DOLAYLI işlevleri seçime bağlı bir parametreyi destekler. Bu parametre yardımıyla olağan A1 şeklinde gösterim yerine R1C1 adres gösterimi kullanılabilir.

ADRES işlevinda, parametre dördüncü parametre olarak eklenir, seçime bağlı çalışma sayfası ismi parametresi beşinci parametreye kaydırılır.

DOLAYLI işlevinda parametre ikinci parametre olarak sona eklenir.

Her iki işlevde, parametre 0 olarak eklenirse, R1C1 söz dizimi kullanılır. Eğer parametre verilmezse veya 0 değerinden farklı ise A1 söz dizimi kullanılır.

R1C1 söz diziminde, ADRES sayfa ismi ayracı olarak, ünlem işareti kullanan '!' adres dizgisiyle döner, ve DOLAYLI ünlem işaretinin sayfa ismi ayracı olmasını bekler. Her iki işlevde hala nokta '.' ayracını A1 gösteriminde kullanır.

ODF 1.0/1.1 biçimindeki belgeleri açtığınız zaman, dördüncü parametre olarak sayfa ismini gösteren ADRES işlevlerinde sayfa ismi beşinci parametreye kaydırılacaktır. 1 değerine sahip olan yeni bir dördüncü parametre eklenecektir.

ODF 1.0/1.1 biçimindeki belgeleri kaydettiğiniz zaman, dördüncü parametreye sahip ADRES işlevlerinden, bu parametre kaldırılacaktır.

Eğer dördüncü parametresi 0 değerinde olan ADRES işlevleri kullanıyorsanız, hesap tablolarınızı ODF 1.0/1.1 biçiminde kaydetmeyin.

DOLAYLI işlevi ODF 1.0/1.1 biçimine dönüştürülmeksizin kaydedilir. Eğer ikinci parametre var ise, eski Calc sürümleri bu işlev için hata değeri döndürür.

### Syntax

ADRES(satır; sütun; MUTLAKDEĞER; A1; "çalışma sayfası")

Satır hücre başvurusu için satır numarasını temsil eder

Sütun hücre başvurusu için sütun sayısını gösterir (sayıdır, harf değil)

MUTLAKDEĞER başvurunun türünü belirler:

1: mutlak ($A$1)

2: satır başvurusu tipi mutlak; sütun başvurusu görecelidir (A$1)

3: satır (göreceli); sütun (mutlak) ($A1)

4: göreceli (A1)

A1 (isteğe bağlı) - eğer 0 olarak ayarlanırsa, R1C1 söz dizimi kullanılır. Eğer bu parametre yoksa veya 0 değerinden farklı bir değere ayarlanmışsa, A1 söz dizimi kullanılır.

Çalışma sayfası çalışma sayfasının adını gösterir. Çift tırnak karakterleri içine alınmalıdır.

### Örnek:

=ADRES(1;1;2;"Çalışma Sayfası2") şöyle döner: Çalışma Sayfası2.A$1

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

## ALANSAY

Bir başvurudaki alanların sayısını verir. Başvuruda çoklu alanlar ve tek hücreler de bulunabilir. Alan, bir bitişik hücreler aralığı ya da tek bir hücredir.

Fonksiyona tek bir argüman belirtilmelidir. Çoklu aralık belirtirseniz, aralıkları ek parantezler ile kapamalısınız. Çoklu aralıklar, bölen gibi noktalı virgül (;) kullanılarak girilebilir, ancak bu otomatik olarak tildaya (~) dönüştürülür.

### Syntax

ALANSAY(başvuru)

Başvuru, hücre veya hücre aralığına kurulan ilgili temsil eder.

### Example

=ALANLAR((A1:B3;F2;G1)) 3 döndürür zira bu üç hücre ve/veya alana bir başvurudur. Girdi sonrası bu =ALANSAY((A1:B3~F2~G1)) şekline dönüştürülür.

=ALANSAY(Tümü) eğer Veri - Aralık Tanımlamenüsünde, Tümü için sadece bir aralık belirlediyseniz, 1 değerini verir.

## ARA

Bir satır veya bir sütun aralığındaki veya bir dizideki değerleri arar. Arama bölgesi bir satır veya sütun da olabilir. Seçmeli olarak, atanan değer (aynı indisdeki) farklı bir sütun veya satırdan geri döner. DÜŞEYARA ve YATAYARAya karşıt olarak, Arama ve sonuç vektörleri farklı yerlerde olabilir. Bitişik olmalarına gerek yoktur. Ek olarak, ARA için arama vektörü artan sıralama ile sıralanmış olmalıdır. Aksi takdirde arama kullanılabilir olmayan yanlış sonuçlarla dönecektir.

Eğer ARA işlevi, arama ölçütüne uyan değer bulamazsa, arama vektöründeki arama ölçütünden küçük ya da eşit olan en büyük sayı ile döner.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

ARA(Arama ölçütü; Arama vektörü; Sonuç vektörü)

Arama ölçütüaranılacak olan değerdir; bir sayı, metin, mantıksal bir değer ya da bir değere başvuruda bulunan bir ad ya da başvuru olabilir.

Arama vektörü yalnızca bir satır ya da bir sütun içeren aralıktır. Arama vektöründeki değerler metin, sayı ya da mantıksal değer olabilir.

SonuçVektörü fonksiyonun sonucunun alındığı bir başka tek-satırlık veya tek-sütünluk aralıktır. Sonuç arama vektöründe bulunan örnekle aynı indis değerli sonuç vektörünün hücresidir.

Boş Hücrelerin Değerlendirilmesi

### Example

=ARA(A1;D1:D100;F1:F100) D1:D100 hücre aralığında A1 hücresinde verilmiş değere karşılık gelen hücreyi araştırır. Bulunması halinde indeksi belirler, örneğin aralıktaki 12.nci hücre, Sonuç vektöründeki 12.nci hücrenin içeriği ile geri döner.

## BİÇEM

Formulün bulunduğu hücreye bir biçem uygular. Ayarlanan süre geçtikten sonra, bir başka biçem hücreye uygulanır. Bu işlev daima bir 0 değeri döndürür. Hücreye başka değer üreten formülleri de sonucu değişmeksizin ekleyebilirsiniz. GEÇERLİ işlevi ile birlikte, hücre değerine bağlı olarak hücreye bir renk uygulayabilirsiniz. Örneğin: =...+BİÇEM(EĞER(GEÇERLİ()>3;"red";"green")) formulü ile hücre değeri 3'den büyükse "red" biçemi uygulanır, 3'den büyük değilse "green" biçemi uygulanır. "red" ve "green" hücre biçimleri önceden tanımlanmış olmalıdır.

### Syntax

BİÇEM("Biçem"; Zaman; "Biçem2")

Biçem hücreye atanacak biçemin adıdır. Biçem adları çift tırnak karakterleri arasında girilmelidir.

Zaman seçimlik saniye cinsinden zaman aralığıdır. Şayet parametre verilmezse biçem belli bir süre sonunda değiştirilmeyecektir.

Biçem2 seçimlik belirlenen zaman geçtikten sonra hücreye uygulanacak biçemin adıdır. Bu parametre verilmezse veya verilen biçem yoksa "Varsayılan" biçim olduğu kabul edilir.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=BİÇEM("Görünmez";60;"Varsayılan") hücreye formül girildikten, veya belge yüklendikten sonra, veya yeniden hesaplandıktan sonra, 60 saniye boyunca şeffaf olarak biçimler, sonra varsayılan biçimi uygular. formül girilmeden önce her iki hücre biçemide tanımlanmış olmalıdır.

Madem ki BİÇEM() sıfır olarak sayısal bir değerle döner, bu dönen değer karakterlerin sonuna takılır. Bu durumdan T() işlevi aşağıdaki gibi kullanılarak sakınılabilir:

="Metin"&T(STYLE("myStyle"))

Bir başka örnek için GEÇERLİ() işlevina bakın.

## DDE

DDE-temelli bir sonuç döner. Bağlanmış alan veya kısım değişir ise geri dönen değer de değişir. Bunun için Hesap tablonuzu yeniden yüklemeli ya da, Düzenle - Bağlantılar menü komutuyla bağlantıları güncellemelisiniz. Karşıt-platform bağlantılarına, örneğin Windows'da yüklenmiş olan LibreOffice ile Linux altında yaratılmış bir belgeye bağlantıya izin verilmez.

### Syntax

DDE("sunucu"; "Dosya"; "aralık"; Kip)

Sunucu sunucu uygulamasının adıdır. LibreOffice uygulamaları "soffice" sunucu adına sahiptir.

Dosya tam dosya adıdır, yol bilgileri de bulunmalıdır.

aralık hesaplanacak veriyi içeren alandır.

Kip DDE sunucusunun kendi verilerini sayıya dönüştürdüğü yöntemi kontrol eden seçimsel bir parametredir.

Kip | Etki
0 veya yok | "Varsayılan" hücre biçemindeki sayı biçimi
1 | Veri daima ABD İngilizcesi standart biçimiyle işlenir.
2 | Veri metin olarak alınmıştır; sayılar üzerinde dönüşüm yapılmamıştır

### Example

=DDE("soffice";"c:\office\belge\data1.ods";"Çalışma Sayfası1.A1") formülü, LibreOffice Calc hesap tablosu data1.ods belgesindeki, Çalışma sayfası1 sayfasında A1 hücresinin içeriğini okur.

=DDE("soffice";"c:\ofis\belge\slogan.odt";"Günün sloganı") formülü bulunan hücreye slogan metnini döndürür. Önce, slogan.odt dosyasına slogan metnini içeren bir satır girmelisiniz ve bölümdeki ilk satırı Günün sloganı adıyla tanımlamalısınız ( LibreOffice Writer'da Ekle - Bölüm menüsünde). Eğer LibreOffice Writer belgesindeki, slogan düzenlenir ve kaydedilirse, LibreOffice Calc belgesinde DDE formülü ile tanımlanmış olan bütün hücreler güncellenir ve yeni sloganı gösterirler.

## DOLAYLI

Bir metin dizisi olarak verilmiş olan, başvuru değeriyle döner. Bu işlev aynı zamanda aralıklar içinde kullanılabilir.

İç uyumluluk açısından ADRES ve DOLAYLI işlevleri seçime bağlı bir parametreyi destekler. Bu parametre yardımıyla olağan A1 şeklinde gösterim yerine R1C1 adres gösterimi kullanılabilir.

ADRES işlevinda, parametre dördüncü parametre olarak eklenir, seçime bağlı çalışma sayfası ismi parametresi beşinci parametreye kaydırılır.

DOLAYLI işlevinda parametre ikinci parametre olarak sona eklenir.

Her iki işlevde, parametre 0 olarak eklenirse, R1C1 söz dizimi kullanılır. Eğer parametre verilmezse veya 0 değerinden farklı ise A1 söz dizimi kullanılır.

R1C1 söz diziminde, ADRES sayfa ismi ayracı olarak, ünlem işareti kullanan '!' adres dizgisiyle döner, ve DOLAYLI ünlem işaretinin sayfa ismi ayracı olmasını bekler. Her iki işlevde hala nokta '.' ayracını A1 gösteriminde kullanır.

ODF 1.0/1.1 biçimindeki belgeleri açtığınız zaman, dördüncü parametre olarak sayfa ismini gösteren ADRES işlevlerinde sayfa ismi beşinci parametreye kaydırılacaktır. 1 değerine sahip olan yeni bir dördüncü parametre eklenecektir.

ODF 1.0/1.1 biçimindeki belgeleri kaydettiğiniz zaman, dördüncü parametreye sahip ADRES işlevlerinden, bu parametre kaldırılacaktır.

Eğer dördüncü parametresi 0 değerinde olan ADRES işlevleri kullanıyorsanız, hesap tablolarınızı ODF 1.0/1.1 biçiminde kaydetmeyin.

DOLAYLI işlevi ODF 1.0/1.1 biçimine dönüştürülmeksizin kaydedilir. Eğer ikinci parametre var ise, eski Calc sürümleri bu işlev için hata değeri döndürür.

### Syntax

DOLAYLI(başv; A1)

Başv içeriğin döndürüleceği bir hücreye ya da bir alana (metin biçiminde) bir başvuruyu simgeler.

A1 (isteğe bağlı) - eğer 0 olarak ayarlanırsa, R1C1 söz dizimi kullanılır. Eğer bu parametre yoksa veya 0 değerinden farklı bir değere ayarlanmışsa, A1 söz dizimi kullanılır.

If you open an Excel spreadsheet that uses indirect addresses calculated from string functions, the sheet addresses will not be translated automatically. For example, the Excel address in INDIRECT("[filename]sheetname!"&B1) is not converted into the Calc address in INDIRECT("filename#sheetname."&B1).

### Example

=DOLAYLI(A1) eğer A1 hücresi C108 metnini bu hücrenin başvurusu olarak içeriyorsa, ve C108 hücresinde 100 sayısı varsa, A1 hücresinde işlev sonucu olarak 100 değeri görüntülenir.

=TOPLA(DOLAYLI("a1:" & ADRES(1;3))) A1 hücresi ile satır 1 sütun 3 ile adresi tanımlanan (C1), hücre aralığını toplar. Bunun anlamı, A1:C1 alanı toplanır.

## DÜŞEYARA

Bir dizinin ilk sütununa bakar ve bir hücrenin değerini vermek için satır boyunca sağa hareket eder. Bir tablonun en soldaki sütununda belirli bir değeri arar ve İndis ile belirtilen tablodaki sütundan aynı satır değerini verir. Eğer Sıralı parametresi verilmemişse veya 1 olarak ya da DOĞRU olarak ayarlanmışsa verinin artan sıralamada sıralandığı kabul edilir. Bu durumda, eğer tam Arama_ölçütü bulunmazsa aranan değerden küçük olan son değer geri döner. Eğer Sıralı YANLIŞ ya da 0 olarak ayarlanırsa, tam eşleşen bulunmalıdır, aksi takdirde Hata: Değer mevcut değil hatası sonuç olacaktır. Bu şekilde 0 değeri varsa, verinin artan sırada sıralanmış olması gereksizdir.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

=DÜŞEYARA(arama_ölçütü; dizi; İndis; Sıralanmış)

Arama ölçütü dizinin ilk sütununda bulunacak değerdir. Arama ölçütü bir değer, başvuru veya metin dizesi olabilir.

Dizi en azından iki sütunu kapsayan bir başvurudur.

İndis aralıkta geri döndürülmesi gereken değerin bulunduğu sütunun sayısıdır. İlk sütun 1 değerine sahiptir.

Sıralı (isteğe bağlı) dizideki ilk sütunda bulunan verinin artan düzende sıralanmış olduğunu gösterir. Eğer veri artan düzende sıralanmamışsa mantıksal YANLIŞ değeri veya 0 sayısını girin. Sıralanmış sütunlar daha hızlı aranır ve aranılan değer bulunamamış olsa dahi, sıralı listede en küçük ile en büyük değer arasında ise, işlev daima bir değer ile döner. Sıralanmamış listelerde, aranılan değer tamamen aynı olmalıdır. Aksi takdirde işlev bu iletiyi verecektir: Hata: Değer mevcut değil.

Boş Hücrelerin Değerlendirilmesi

### Example

A1 hücresinde menüde olan bir yemek için sayı girerek, ve hemen yanındaki komşu B1 hücresinde yemeğin adının anında metin olarak görüntülenmesi istiyorsunuz. Yemek adlarıyla numaraları D1:E100 hücre aralığında listelenmiştir. D1 100 sayısını içerir, E1 Sebze Çorbası yemeğinin ismini içerir, ve 100 menü elemanı için bu liste böylece uzar gider. D sütunundaki sayılar artan sıralama ile sıralanmışlardır; bu yüzden, isteğe bağlı Sıralı parametresi gereksizdir.

Şu formülü B1 hücresine girin:

=DÜŞEYARA(A1;D1:E100;2)

A1 hücresine bir değer girer girmez, B1 hücresinde D1:E100 başvurusunun ikinci sütunundan karşılık gelen metin görüntülenecektir. Olmayan bir sayının girilmesi, aranan sayıdan küçük olan en yakın sayının bulunduğu satırdaki metnin görüntülenmesine neden olur. Bundan sakınmak için, formülde son parametreyi YANLIŞ olarak girin, böylece hücrede aranan sayının bulunamadığını bildiren bir ileti görüntülenir.

## ELEMAN

30'a kadar elemanı bulunan bir değerler listesinden bir değer almak için indis kullanır.

### Syntax

ELEMAN(Dizin; değer 1: değer 2; ...; değer 30)

Dizin 1 ile 30 değerleri arasında bir başvuru veya sayıdır ki karşılığı olan değer listeden alınır.

Değer1, Değer2, ..., Değer 30 hücre başvuruları olarak girilen değerlerin listesi veya tek tek değerlerdir.

### Example

=ELEMAN(A1;B1;B2;B3;"Bugün";"Dün";"Yarın") işlevi, örneğin, A1 = 2 ise B2 hücresinin içeriğini döndürür; A1 = 4 içinse "Bugün" metnini döndürür.

## HATA.TİPİ

Bir başka hücredeki hata değeri'ne karşılık gelen sayıyı döndürür. Bu sayı yardımıyla hata için bir hata mesajı yaratabilirsiniz.

Eğer bir hata oluşursa, fonksiyon bir mantıksal veya sayısal değer döndürür.

Eğer hata oluşan hücreyi tıklarsanız, durum çubuğunda LibreOffice ön tanımlı hata kodu gösterilir.

### Syntax

HATA.TİPİ(Başvuru)

Başvuru hatanın meydana geldiği hücrenin adresidir.

### Example

Eğer A1 hücresinde Hata:518 varsa, işlev =HATATİPİ(A1) 518 sayısıyla döner.

## KAYDIR

Bir hücre veya hücre aralığındaki belirtilen sütun ve satır sayısında bir aralığın hücre içeriğini verir.

### Syntax

KAYDIR(başvuru; satır; sütun; yükseklik; genişlik)

Başvuru işlevin yeni başvuruyu araştıracağı başvurudur. Başvuru, bir hücre veya komşu hücrelerin aralığına başvurmalıdır.

Satırlar başvurunun yukarı (negatif değer) veya aşağı doğru düzeltildiği satırların sayısıdır.

Satırlar başvurunun yukarı (negatif değer) veya aşağı doğru düzeltildiği satırların sayısıdır.

yükseklik (isteğe bağlı) Yeni bir başvuru noktasında başlayan, bir alan için dikey yüksekliktir.

genişlik (isteğe bağlı) verilen başvurunun sahip olmasını istediğiniz, sütun sayısı içindeki genişliktir. Genişlik pozitif bir sayı olmalıdır.

Satırlar ve Sütunlar değişkenleri sıfır olarak bırakılmamalı veya negatif başlangıç satırı veya sütunu olmamalıdır

Yükseklik ve Genişlik değişkenleri sıfır olarak bırakılmamalı veya negatif başlangıç satırı veya sütunu olmamalıdır.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=KAYDIR(A1;2;2) C3 hücresindeki değer ile geri döner (A1 hücresi iki satır aşağıya ve iki sütun sağa kaydırılır). Eğer C3 hücresi 100 sayısını içeriyorsa, bu işlev sonucu 100 sayısı döner.

=KAYDIR(B2:C3;1;1) B2:C3 aralığının bir satır aşağı kayması ve 1 sütun sağa kaymasıyla oluşan başvuruyu verir (C3:D4 aralığı).

=Kaydır(B2:C3;-1;-1) B2:C3 hücre aralığı başvurusunu bir satır yukarı bir sütun sola kaydırarak döner, yani (A1:B2) başvurusu elde edilir.

=KAYDIR(B2:C3;0;0;3;4) B2:C3 aralığının 3 satır ve 4 sütuna genişletilmiş başvurusunu döndürür, yani (B2:E4).

=KAYDIR(B2:C3;1;0;3;4) B2:C3 aralığının bir satır aşağı kayması ve 3 satır ile 4 sütuna genişletilmiş başvurusunu döndürür (B3:E5 aralığı).

=TOPLA(KAYDIR(A1;2;2;5;6)) C3 hücresiyle başlayan 5 satır yüksekliğinde ve 6 sütun genişliğindeki hücre aralığının toplamını alır (alan=C3:H7).

Genişlik veya yükseklik dahil edildiğinde KAYDIR fonksiyonu bir aralık döndürür ve bir dizi fonksiyonu olarak girilmelidir. Genişlik ve yükseklik bulunmadığında hücrenin kaynağı döndürülür.

## KAÇINCI

Bir dizide, belirtilen bir değere belirtilen şekilde uyan bir öğenin göreceli konumunu verir. Bu işlev arama_dizisi'nde bulunan değerin pozisyon numarası ile döner.Öğenin kendisi yerine uyan bir aralık öğesinin konumuna gereksinim duyduğunuzda bu işlevi kullanın.

### Syntax

KAÇINCI(Arama ölçütü; arama_dizisi; Tür)

Arama ölçütü bir tek satırlı veya tek sütunlu dizide aranılacak olan değerdir.

arama_dizisi olası aranan değerleri içeren bitişik bir hücre aralığıdır. Bir arama_dizisi tek satır, tek sütun veya tek sütun ile tek satırın parçası olabilir.

Tür 1, 0, veya -1 değerlerini alabilir. Eğer Tür = 1 ise, veya isteğe bağlı parametre yok ise, arama dizisindeki ilk sütun artan sıralama ile sıralanmış kabul edilir. Eğer Tür = -1 ise, sütunun azalan sıralama ile sıralanmış olduğu kabul edilir. Bu Microsoft Excel ile aynı işleve karşılık gelir.

Eğer Tür = 0 ise, sadece tam olarak eşleşenler bulunur. Eğer aranan değer birden fazla bulunuyorsa, işlev ilk eşleşen değerin indis sayısıyla döner. Sadece Tür = 0 ise, düzenli ifadelerle (hesaplama seçeneklerinden etkinleştirilmişse) veya joker karakterlerle (hesaplama seçeneklerinden etkinleştirilmişse) arama yapabilirsiniz.

Eğer tür = 1 ise KAÇINCI işlevi aranan_değerden küçük ya da eşit olan en büyük son değerin indisini bulur. Bu Arama_dizisi sıralanmamış olsa bile uygulanır. tür = -1 ise, KAÇINCI işlevi arama_ölçütünden büyük ya da eşit olan ilk değeri bulur.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Example

=KAÇINCI(200;D1:D100) D sütununa göre sıralanmış D1:D100 aralığını ararar, bu değer bulunur bulunmaz değerin bulunduğu satır sayısı sonuç olarak döner. Eğer sütun aranırken daha yüksek bir değer bulunursa, bir önceki satır değeri geri döndürülür.

## KÖPRÜ

KÖPRÜ işlevi bulunan bir hücreye tıklarsanız, köprü çalışarak ilgili adres açılır.

HücreMetni isteğe bağlı parametresini kullanmazsanız, formüle yerleştirilen adres, hücrede metin olarak görüntülenir.

Köprülenmiş bir hücredeki adresi klavye ile açmak için, hücreyi seçin, F2 tuşuna bakarak düzenleme kipine geçin, imleci köprünün önüne yerleştirin, Shift+F10 tuşuna basın, ve sonra Köprüyü Aç'ı seçin.

### Syntax

KÖPRÜ("Adres") veya KÖPRÜ("Adres"; "HücreMetni")

Adres ile bağlantı hedefi belirlenir. HücreMetni parametresi isteğe bağlıdır. Parametre hücrede görüntülenen metindir ve işlevin sonucudur. Eğer HücreMetni parametresi verilmezse, Adres işlev sonucu olarak hücrede görüntülenir.

Boş hücreler ve matrix ögeleri için 0 döndürülür.

### Example

=KÖPRÜ("http://www.example.org") "http://www.example.org" metnini hücrede görüntüler ve tıklandığında http://www.example.org internet adresini varsayılan internet tarayıcınızla açar.

=KÖPRÜ("http://www.example.org"; "Buraya Tıklayın") hücrede "Buraya tıklayın" metnini görüntüler ve tıklandığında http://www.example.org internet adresini varsayılan internet tarayıcınızla açar.

=KÖPRÜ("http://www.example.org";12345) 12345 rakamlarını görüntüler ve tıklandığında http://www.example.org bağlantısını çalıştırır.

=KÖPRÜ($B4) formülü B4 hücresi "http://www.example.org" metnini içeriyor ise. işlev Adrese http://www.example.org ekler ve formül sonucu olarak bu metni görüntüler ve tıklandığında http://www.example.org internet adresini varsayılan internet tarayıcınızla açar.

=KÖPRÜ("http://www.";"Click ") & "example.org" hücrede Click example.org metnini görüntüler ve tıklandığında http://www.example.org bağlantısını çalıştırır.

=KÖPRÜ("#ÇalışmaSayfası1.A1";"En başa git") En başa git metnini görüntüler ve bu belgedeki ÇalışmaSayfası1.A1 hücresine atlar.

=KÖPRÜ("file:///C:/writer.odt#Specification";"Writer yer imine git") metin olarak, Writer yer imine git görüntüler, çalıştırıldığında belirlenmiş metin belgesini yükler ve "Specification" yer imine atlar.

## ROW

Bir başvurunun satır sayısını verir. Başvuru bir hücre ise, hücrenin satır numarası geri döner. Eğer Başvuru bir hücre aralığı ise, Dizi formülü Bir dizi formülü olarak. girilmişse karşılık gelen satır numaraları her bir sütunda görüntülenir. SATIR işlevi bir dizi formülü olarak kullanılmamışsa, sadece alandaki ilk hücrede satır numarası görüntülenir.

### Syntax

SATIR(başvuru)

Başvuru bir hücre, alan veya bir alan adıdır.

Satır sayısı için bir başvuru vermemişseniz, formülün girilmiş olduğu hücrenin satır sayısı bulunur. LibreOffice Calc başvuruyu otomatik olarak geçerli hücreye göre ayarlar.

### Example

=SATIR(B3) 3 sonucunu verir, çünkü başvuru tablodaki üçüncü satırdır.

{=SATIR(D5:D8)} tek sütunlu dizi ile döner (5, 6, 7, 8), çünkü başvuru satır 5 ile 8 aralığını kapsar.

=SATIR(D5:D8) 5 sonucuyla döner, çünkü SATIR işlevi bir dizi formülü olarak kullanılamaz ve sadece başvurudaki birinci satırın numarası olan sayı değeri döner.

{=SATIR(A1:E1)} ve =SATIR(A1:E1) formüllerinin her ikisi de 1 değerini döndürür. Çünkü başvuru tabloda ilk sütunda sadece bir satır bulundurmaktadır. (tek satırlı alanlar sadece bir satır numarasına sahiptir, bu yüzden formülü dizi formülü olarak girmekle düz formül olarak girmek arasında fark yoktur.)

=SATIR() eğer fomül çalışma sayfasındaki üçüncü satırda bulunan herhangi bir hücreye girilmişse, 3 sonucunu verir.

{=SATIR(Tavşan)} Eğer "Tavşan" C1:D3 hücre aralığının ismiyse, tek sütunlu bir diziyle döner (1, 2, 3).

## SATIRSAY

Bir dizide veya başvurudaki satır sayısını verir.

### Syntax

SATIRSAY(dizi)

dizi toplam satır sayısını öğrenmek istediğiniz bir dizi, veya hücre aralığı başvurusudur.

### Example

=SATIRSAY(B5) 1 sonucunu verir, çünkü bir hücre sadece tek satır bulundurabilir.

=SATIRSAY(A10:B12) üç satırlı bir başvuru olduğu için, 3 sonucunu verir.

=SATIRSAY(Tavşan) Eğer "tavşan" bir (C1:D3) isimlendirilmiş aralığıysa, 3 sonucunu verir.

## SHEET

Sayfa numarası veya metin olarak görüntülenen sayfa adını verir. Şayet herhangi bir parametre girmezseniz, sonuç formulün içinde bulunduğu, sayfanın numarası olarak görüntülenir.

### Syntax

ÇALIŞMA_SAYFASI(başvuru)

Başvuruisteğe bağlıdır ve bir hücre, alan ya da çalışma sayfasının isminin karekter dizgisi için yararlanılan bir kaynaktır.

### Example

=ÇALIŞMA_SAYFASI('Çalışma Sayfası2'.A1) 2 değerini verir, Çalışma sayfası2 sayfa sıralamasına göre ikinci sayfa olmalıdır.

## SÜTUN

Hücre başvurusunun sütun numarasını döndürür. Eğer başvuru bir hücre ise hücrenin sütun numarası döner; eğer parametre bir hücre alanı ise, karşılık gelen sütun numaraları tek satır dizi olarak döner, eğer girilen formül bir dizi formülü ise. Eğer COLUMN fonksiyonu alan başvuru parametresi ile beraber dizi formülü için kullanılmazsa, sadece alan içerisindeki ilk hücrenin sütun numarası belirlenir.

### Syntax

SÜTUN(başvuru)

Başvurubir hücre veya ilk sütun numarası bulunacak olan hücre alanı için yararlanılan bir başvurudur.

Eğer başvuru girilmezse, formülün bulunduğu hücrenin sütun sayısı bulunur. LibreOffice Calc başvuruyu geçerli hücreye otomatik ayarlar.

### Example

=SÜTUN(A1) 1 değerine eşittir. Sütun A tablodaki ilk sütundur.

=SÜTUN(C3:E3) 3'e eşittir. Sütun C tablodaki üçüncü sütundur.

=SÜTUN(D3:G10) 4 değerini verir, çünkü tabloda D dördüncü sütundur ve SÜTUN işlevi dizi işlevi olarak kullanılamaz. (Bu durumda, aralığın ilk değeri sonuç olarak kullanılmaktadır.)

{=SÜTUN(B2:B7)} ve =SÜTUN(B2:B7) işlevlerinin her ikisi de 2 sonucuyla döner, çünkü başvuru tabloda ikinci sütun olan sadece bir sütunu kapsar. Tek sütunlu alanlar sadece bir sütun numarasına sahiptir, bu sebeple formülü dizi formülü olarak girmekle, standart formül olarak girmek arasında bir fark yoktur.

=SÜTUN() eğer formül C sütununda bulunan herhangi bir hücreye girilmişse, 3 değerini verir.

{=SÜTUN(Tavşan)} Eğer "Tavşan" (C1:D3) hücre aralığının ismiyse, tek satırlı bir diziyle döner (3, 4).

## SÜTUNSAY

Bir dizi ya da başvurudaki sütunların sayısını verir.

### Syntax

SÜTUNSAY(dizi)

Dizi toplam sütun sayısı bulunacak hücre aralığına bir başvudur. Değişken tek bir hücrede olabilir.

### Example

=SÜTUNSAY(B5) 1 değerini verir, çünkü bir hücre sadece bir sütunu kapsayabilir.

=SÜTUNSAY(A1:C5) 3 ile sonuçlanır. Başvuru üç sütunu kapsar.

=SÜTUNSAY(Tavşan) Eğer Tavşan (C1:D3) aralığının adıysa, 2 sonucunu verir.

## YATAYARA

Seçilmiş olan hücre aralığında bir başvuru ya da değer aranılır. Bu işlev bir dizinin ilk satırını verilen değer için test ederek, bulunmuş ise, İndis, olarak isimlendirilmiş sütundaki karşılık gelen değeri geri döndürür.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

YATAYARA(arama_ölçütü; dizi; İndis; Sıralanmış)

Ayrıca bakın: DÜŞEYARA (sadece sütunlar ve satırlar değişik olur)

Boş Hücrelerin Değerlendirilmesi

## ÇALIŞMA_SAYFALARI

Bir başvurudaki sayfa sayısını geri döndürür. Herhangi parametre girmez iseniz, çalışılan belgedeki sayfa sayısı döndürülür.

### Syntax

ÇALIŞMA_SAYFALARI(başvuru)

Kaynak bir çalışma sayfasına veya alana başvurudur. Bu parametre seçimliktir.

### Example

=ÇALIŞMA_SAYFALARI('Çalışma sayfası1'.A1:'Çalışma sayfası3'.G12) eğer Çalışma sayfası1, Çalışma sayfası2 ve Çalışma sayfası3 ardışık olarak görüntülenmekteyse, 3 sonucunu verir.

## ÖZETVERİAL

GETPIVOTDATA nin işlevi, bir özet tablo bir sonuç değeri döndürmektir. Fonsiyon değeri alan ve öğe adları kullanılarak belirlenir, bu nedenle özet tablo düzen değişikliği halinde geçerli kalır.

### Syntax

İki farklı sözdizimi tanımı kullanılabilir:

ÖZETVERİAL(Veri_Alanı; veri pilotu; [Alan Adı/Öğesi1; Alan Adı/Öğesi1; ...])

ÖZETVERİAL(Veri Pilotu; Kısıtlamalar)

İkinci sözdiziminde, eğer tam olarak iki parametre verilmişse ilk parametrenin hücre veya hücre aralığı başvurusu olduğu kabul edilir. Diğer tüm hallerde ilk söz diziminin geçerli olduğu kabul edilir. İşlev sihirbazı ilk sözdizimini gösterir.

### Syntax

HedefAlanÖzet tablonun veri alanlarından birini seçen bir dizedir. Tabloda gösterildiği gibi bir dize (" Satış - Toplam" gibi) kaynak sütun adını veya veri alan adı olabilir.

özet tablo , özet tablo içinde konumlanmış ya da özet tablo içeren bir hücreye ya da hücre aralığına yapılan bir başvurudur. Hücre aralığı birden fazla özet tablo içeriyorsa en son yaratılan tablo kullanılır.

Eğer herhangi bir Alan n / Madde n çifti verilmemişse, genel toplamı verir. Diğer durumda her çift sonucun yerine getirmesi gereken bir kısıt ekler. Alan n özet tablodan alınan herhangi bir alanın adıdır. Madde n bu alandan alınan herhangi bir maddenin adıdır.

Eğer veri pilotu sadece tek sonuç değerleri içeriyorsa sabitlerin hepsini tamamlar ya da alt toplam sonucu toplanan tüm eşleşmiş değerlerin sonucunu döndürür.Eğer eşleşmiş sonuç ya da bir alt toplam yok ise bir hata döndürür.Bu durumlarda veri pilotunun içerdiği sonuçlar uygulanır.

Eğer kaynak veri özet tablonun ayarları ile gizlenen girişler içeriyorsa, bu girişler yoksayılır. Alan/Madde çiftlerinin sırası önemli değildir. Alan ve madde adları büyük / küçük harf duyarlı değildir.

Eğer bir sayfa alanı için herhangi bir kısıtlama getirilmemişse, alanın seçili değeri dolaylı olarak kullanılır. Eğer bir sayfa alanı için kısıtlama getirilmişse, bu alanın seçili değeri ile uyuşmalıdır, aksi halde bir hata döndürülür. Sayfa alanları veri pilotlarının sol üstünde yer alan alanlardır ve veri pilotu iletişim anahattının "Sayfa Alanı" bölümü kullanılarak doldurulurlar. Her bir sayfa alanından sadece bir madde (değer) seçilebilir ve sadece seçilen bu madde hesaplamalara dahil edilir.

Özet tablodan alınan ara toplam değerleri ancak "otomatik" işlevini kullandıklarında kullanılır (kısıtlarda belirtilmedikçe, bkz aşağıda İkinci Sözdizimi ).

### Syntax

veri pilotu ilk sözdizimindeki ile aynı anlama sahiptir.

Kısıtlamalar boşluklarla ayrılmış listedir. Girişler tek tırnak karakteri (') ile ayrılır. Bir başka hücredeki metne başvurmuyorsanız, Bütün karakter dizisi çift tırnak karakterleri (") içine alınmalıdır.

Girişlerden biri veri alan adı olabilir. Özet tablo yalnız bir veri alanı içeriyorsa veri alan adı dışarıda bırakılabilir; diğer durumda kullanılmalıdır.

Diğer girişlerin her biri Alan[Madde] (harfi harfine karakterler ile [ ve ]) biçiminde ya da madde ismi özet tabloda kullanılan tüm alanlar içinde eşsiz ise yalnız Madde biçiminde bir kısıt belirler.

Alan[Eleman;İşlev] bu formda bir işlev ismi eklenebilir, ki bu yapıda sadece sadece alttoplam değerlerinin eşleştirilebilmesi kısıtlamasına neden olur. Kullanılabilir işlev isimleri Sum, Count, Average, Max, Min, Product, Count (Sadece sayılar), StDev (Örnek), StDevP (Nüfus), Var (Örnek), and VarP (Nüfüs), büyük/küçük harf duyarlı. İşlevlerin Türkçe isimleri ise; sırasıyla Topla, Say, Ortalama, Azami, Asgari, Çarpım, SayA, Standartsapma, StandartsapmaS, Değişken, DeğişkenP.

## İNDİS

İNDİS başvurudan veya diziden bir değer seçmek için, kullanılır. İşlev ya dizi içindeki belirli bir hücrenin ya da hücreler dizisinin değerini verir. Ya da başvuru içindeki belirli bir hücreye ya da hücrelere bir başvuru verir.

### Syntax

İNDİS(başvuru; satır; sütun; aralık)

Başvuru bir ya da daha fazla hücre aralığına bir başvurudur, başvuru doğrudan girilebileceği gibi bir aralık adı olarak da girilebilir. Başvuru için bitişik olmayan bir çoklu aralık giriyorsanız, başvuruyu veya başvuru adını ayraç içine alın.

Satır (isteğe bağlı) bir değer döndürmek için, başvuru aralığının satır indisini gösterir. Sıfır olması durumunda (hiç satır olmaması durumu) bütün başvurulmuş satır değerleri döndürülür.

Sütun (isteğe bağlı) geri dönen değer için, başvuru aralığındaki sütun indisini gösterir. Sıfır olması durumunda (özel sütun yok), başvurulan bütün sütunlar dönerler.

Aralık (isteğe bağlı) bir çoklu aralıktaki alt aralığın indisini gösterir.

### Example

=İNDİS(Fiyatlar;4;1) Veri - Aralık Tanımla menüsüyle Fiyatlar olarak tanımlanmış olan aralıktaki, dördüncü satır ve birinci sütundaki hücrenin değeri ile döner.

=İNDİS(ToplamX;4;1) Aralık ismi Çalışma Sayfası - Adlandırılmış Aralıklar ve İfadeler - Tanımla yoluyla tanımlanmış olan, ToplamX aralığındaki dördüncü satır ve ilk sütundaki değeri döndürür.

=İNDİS(A1:B6;1) A1:B6 hücre aralığının ilk satırına başvuru ile döner.

=İNDİS(A1:B6;0;1) A1:B6 hücre aralığının ilk sütununa başvuru ile döner.

=INDEX((multi);4;1) Çalışma Sayfası - İsimlendirilen Aralıklar ve İfadeler - Tanımla üzerinden çoklu diye tanımladığınız aralık, 4üncü satırın 1inci sütununun değerini gösterir. Çoklu aralık, her birinde 4ncü satır ve 1inci sütun mevcut olmak üzere, birçok farklı dikdörtgenden oluşabilir. Eğer bu çoklu alanın ikinci bloğunu çağırmak için 2 aralık parametresi olarak girilmelidir.

=INDEX(A1:B6;1;1)üst -sol A1:B6 aralığının değerini belirtir.

=İNDİS((çoklu);0;0;2) çoklu aralığın ikinci aralığınının başvurusunu döndürür.

İlgili Konular

Kategoriler Halinde Fonksiyonlar