Module
Contents
Index 🔎︎

## WEEKDAY

Returns the day of the week for the given date value. The day is returned as an integer between 1 (Sunday) and 7 (Saturday) if no type or type=1 is specified. For other types, see the table below.

### Sintakse

WEEKDAY(Number; Type)

Number, as a date value, is a decimal for which the weekday is to be returned.

Type is optional and determines the type of calculation.

Type | Weekday number returned
1 or omitted | 1 (Sunday) through 7 (Saturday). For compatibility with Microsoft Excel.
2 | 1 (Monday) through 7 (Sunday).
3 | 0 (Monday) through 6 (Sunday)
11 | 1 (Monday) through 7 (Sunday).
12 | 1 (Tuesday) through 7 (Monday).
13 | 1 (Wednesday) through 7 (Tuesday).
14 | 1 (Thursday) through 7 (Wednesday).
15 | 1 (Friday) through 7 (Thursday).
16 | 1 (Saturday) through 7 (Friday).
17 | 1 (Sunday) through 7 (Saturday).

These values apply only to the standard date format that you select under LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Piemēri

=WEEKDAY("2000-06-14") returns 4 (the Type parameter is missing, therefore the standard count is used. The standard count starts with Sunday as day number 1. June 14, 2000 was a Wednesday and therefore day number 4).

=WEEKDAY("1996-07-24";2) returns 3 (the Type parameter is 2, therefore Monday is day number 1. July 24, 1996 was a Wednesday and therefore day number 3).

=WEEKDAY("1996-07-24";1) returns 4 (the Type parameter is 1, therefore Sunday is day number 1. July 24, 1996 was a Wednesday and therefore day number 4).

=WEEKDAY("2017-05-02";14) returns 6 (the Type parameter is 14, therefore Thursday is day number 1. May 2, 2017 was a Tuesday and therefore day number 6)

=WEEKDAY(NOW()) returns the number of the current day.

To obtain a function indicating whether a day in A1 is a business day, use the IF and WEEKDAY functions as follows:
IF(WEEKDAY(A1;2)<6;"Business day";"Weekend")