Module
Contents
Index 🔎︎

# Programmēšanas piemēri vadīklām dialogu redaktorā

The following examples are for a new dialog called "Dialog1". Use the tools on the Toolbox bar in the dialog editor to create the dialog and add the following controls: a Check Box called "CheckBox1", a Label Field called "Label1", a Button called "CommandButton1", and a List Box called "ListBox1".

Be consistent with uppercase and lowercase letter when you attach a control to an object variable.

### Globālā funkcija dialogu ielādēšanai

    Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)

    Dim oLib as Object

    Dim oLibDialog as Object

    Dim oRuntimeDialog as Object

        If IsMissing(oLibContainer) Then

            oLibContainer = DialogLibraries

        End If

        oLibContainer.LoadLibrary(LibName)

        oLib = oLibContainer.GetByName(Libname)

        oLibDialog = oLib.GetByName(DialogName)

        oRuntimeDialog = CreateUnoDialog(oLibDialog)

        LoadDialog() = oRuntimeDialog

    End Function

### Dialoga attēlošana

    Mainīgo REM globālā definīcija

    Dim oDialog1 AS Object

    Sub StartDialog1

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        oDialog1.Execute()

    End Sub

### Vadīklu nolasīšana vai rediģēšana programmā

    Sub Sample1

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM iegūt dialoga modeli

        oDialog1Model = oDialog1.Model

        REM Label1 displeja teksts

        oLabel1 = oDialog1.GetControl("Label1")

        MsgBox oLabel1.Text

        REM iestatīt jaunu tekstu vadīklai Label1

        oLabel1.Text = "Jaunas datnes"

        REM displeja modeļa īpašības vadīklai CheckBox1

        oCheckBox1Model = oDialog1Model.CheckBox1

        MsgBox oCheckBox1Model.Dbg_Properties

        REM iestatīt jaunu stāvokli priekš CheckBox1 priekš vadīklas modeļa

        oCheckBox1Model.State = 1

        REM displeja modeļa īpašības vadīklai CommandButton1

        oCMD1Model = oDialog1Model.CommandButton1

        MsgBox oCMD1Model.Dbg_Properties

        REM vadīklas CommandButton1 displeja īpašības

        oCMD1 = oDialog1.GetControl("CommandButton1")

        MsgBox oCMD1.Dbg_Properties

        REM izpildīšanas dialoglodziņš

        oDialog1.Execute()

    End Sub

### Pievienot ierakstu pie ListBox

    Sub AddEntry

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM pievieno jaunu ierakstu pie ListBox

        oDialog1Model = oDialog1.Model

        oListBox = oDialog1.GetControl("ListBox1")

        Dim iCount as integer

        iCount = oListbox.ItemCount

        oListbox.additem("New Item" & iCount,0)

    End Sub

### Noņemt ierakstu no ListBox

    Sub RemoveEntry

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM noņem pirmo ierakstu no ListBox

        oDialog1Model = oDialog1.Model

        oListBox = oDialog1.GetControl("ListBox1")

        oListbox.removeitems(0,1)

    End Sub

Saistītie temati

Vadīklu īpašību izmainīšana dialogu redaktorā

Basic dialoga izveidošana

Vadīklu izveidošana dialogu redaktorā

Dialoga atvēršana ar programmas kodu