# The JaCoCo Plugin

✨ | The JaCoCo plugin is currently incubating. Please be aware that the DSL and other configuration may change in later Gradle versions.

The JaCoCo plugin provides code coverage metrics for Java code via integration with JaCoCo.

## Getting Started

To get started, apply the JaCoCo plugin to the project you want to calculate code coverage for.

### Example: Applying the JaCoCo plugin

build.gradle

    apply plugin: "jacoco"

If the Java plugin is also applied to your project, a new task named `jacocoTestReport` is created that depends on the `test` task. The report is available at `$buildDir/reports/jacoco/test`. By default, a HTML report is generated.

## Configuring the JaCoCo Plugin

The JaCoCo plugin adds a project extension named `jacoco` of type JacocoPluginExtension, which allows configuring defaults for JaCoCo usage in your build.

### Example: Configuring JaCoCo plugin settings

build.gradle

    jacoco {
        toolVersion = "0.8.1"
        reportsDir = file("$buildDir/customJacocoReportDir")
    }

Table 1. Gradle defaults for JaCoCo properties
Property | Gradle default
--- | ---
reportsDir | `$buildDir/reports/jacoco`

## JaCoCo Report configuration

The JacocoReport task can be used to generate code coverage reports in different formats. It implements the standard Gradle type Reporting and exposes a report container of type JacocoReportsContainer.

### Example: Configuring test task

build.gradle

    jacocoTestReport {
        reports {
            xml.enabled false
            csv.enabled false
            html.destination file("${buildDir}/jacocoHtml")
        }
    }

## Enforcing code coverage metrics

✨ | This feature requires the use of JaCoCo version 0.6.3 or higher.

The JacocoCoverageVerification task can be used to verify if code coverage metrics are met based on configured rules. Its API exposes the method JacocoCoverageVerification.violationRules(org.gradle.api.Action) which is used as main entry point for configuring rules. Invoking any of those methods returns an instance of JacocoViolationRulesContainer providing extensive configuration options. The build fails if any of the configured rules are not met. JaCoCo only reports the first violated rule.

Code coverage requirements can be specified for a project as a whole, for individual files, and for particular JaCoCo-specific types of coverage, e.g., lines covered or branches covered. The following example describes the syntax.

### Example: Configuring violation rules

build.gradle

    jacocoTestCoverageVerification {
        violationRules {
            rule {
                limit {
                    minimum = 0.5
                }
            }

            rule {
                enabled = false
                element = 'CLASS'
                includes = ['org.gradle.*']

                limit {
                    counter = 'LINE'
                    value = 'TOTALCOUNT'
                    maximum = 0.3
                }
            }
        }
    }

✨ | The code for this example can be found at `samples/testing/jacoco/quickstart` in the ‘-all’ distribution of Gradle.

The JacocoCoverageVerification task is not a task dependency of the `check` task provided by the Java plugin. There is a good reason for it. The task is currently not incremental as it doesn’t declare any outputs. Any violation of the declared rules would automatically result in a failed build when executing the `check` task. This behavior might not be desirable for all users. Future versions of Gradle might change the behavior.

## JaCoCo specific task configuration

The JaCoCo plugin adds a JacocoTaskExtension extension to all tasks of type Test. This extension allows the configuration of the JaCoCo specific properties of the test task.

### Example: Configuring test task

build.gradle

    test {
        jacoco {
            append = false
            destinationFile = file("$buildDir/jacoco/jacocoTest.exec")
            classDumpDir = file("$buildDir/jacoco/classpathdumps")
        }
    }

✨ | Using the configuration `append = true` (the default) causes the JaCoCo agent to append to a shared output file that may be left over from a different test execution. If `append = true`, Gradle disables caching for the Test task since it cannot guarantee the same results each time.

Default values of the JaCoCo Task extension

    test {
        jacoco {
            append = true
            enabled = true
            destPath = "$buildDir/jacoco"
            includes = []
            excludes = []
            excludeClassLoaders = []
            includeNoLocationClasses = false
            sessionId = "<auto-generated value>"
            dumpOnExit = true
            classDumpDir = null
            output = Output.FILE
            address = "localhost"
            port = 6300
            jmx = false
        }
    }

While all tasks of type Test are automatically enhanced to provide coverage information when the `java` plugin has been applied, any task that implements JavaForkOptions can be enhanced by the JaCoCo plugin. That is, any task that forks Java processes can be used to generate coverage information.

For example you can configure your build to generate code coverage using the `application` plugin.

### Example: Using application plugin to generate code coverage data

build.gradle

    apply plugin: "application"
    apply plugin: "jacoco"

    mainClassName = "org.gradle.MyMain"

    jacoco {
        applyTo run
    }

    task applicationCodeCoverageReport(type:JacocoReport){
        executionData run
        sourceSets sourceSets.main
    }

✨ | The code for this example can be found at `samples/testing/jacoco/application` in the ‘-all’ distribution of Gradle.

Coverage reports generated by applicationCodeCoverageReport

    .
    └── build
        ├── jacoco
        │   └── run.exec
        └── reports
            └── jacoco
                └── applicationCodeCoverageReport
                    └── html
                        └── index.html

## Tasks

For projects that also apply the Java Plugin, the JaCoCo plugin automatically adds the following tasks:

`jacocoTestReport` — JacocoReport

  Generates code coverage report for the test task.

`jacocoTestCoverageVerification` — JacocoCoverageVerification

  Verifies code coverage metrics based on specified rules for the test task.

## Dependency management

The JaCoCo plugin adds the following dependency configurations:

Table 2. JaCoCo plugin - dependency configurations
Name | Meaning
--- | ---
`jacocoAnt` | The JaCoCo Ant library used for running the `JacocoReport`, `JacocoMerge` and `JacocoCoverageVerification` tasks.
`jacocoAgent` | The JaCoCo agent library used for instrumenting the code under test.