Module
Contents
Index 🔎︎

# Príklady programov pre ovládacie prvky v Editore dialógov

Nasledujúci príklad je pre nové dialógové okno pomenované "Dialog1". Použitím nástrojov z Panelu nástrojov v editore dialógových okien vytvorte dialógové okno a pridajte nasledujúce ovládacie prvky: Zaškrtávacie políčko nazvané "CheckBox1", Popisné pole nazvané "Label1",Tlačidlo nazvané "CommandButton1", a Posuvný zoznam nazvaný "ListBox1".

Uistite sa že použijete rovnaké veľké a malé písmená pri priraďovaní ovládacieho prvku k premennej objektu.

### Globálna funkcia pre načítavanie dialógov

    Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)

    Dim oLib as Object

    Dim oLibDialog as Object

    Dim oRuntimeDialog as Object

        If IsMissing(oLibContainer) Then

            oLibContainer = DialogLibraries

        End If

        oLibContainer.LoadLibrary(LibName)

        oLib = oLibContainer.GetByName(Libname)

        oLibDialog = oLib.GetByName(DialogName)

        oRuntimeDialog = CreateUnoDialog(oLibDialog)

        LoadDialog() = oRuntimeDialog

    End Function

### Zobrazenie dialógu

    REM globálna definícia premenných

    Dim oDialog1 AS Object

    Sub StartDialog1

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        oDialog1.Execute()

    End Sub

### Čítanie alebo úprava vlastností ovládacích prvkov v programe

    Sub Sample1

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM získanie dialógu model

        oDialog1Model = oDialog1.Model

        REM zobrazenie textu Label1

        oLabel1 = oDialog1.GetControl("Label1")

        MsgBox oLabel1.Text

        REM nastavenie nového textu pre ovládací prvok Label1

        oLabel1.Text = "Nové súbory"

        REM zobrazenie vlastností modelu pre ovládací prvok CheckBox1

        oCheckBox1Model = oDialog1Model.CheckBox1

        MsgBox oCheckBox1Model.Dbg_Properties

        REM nastavenie nového stavu pre CheckBox1 pre model ovládacieho prvku

        oCheckBox1Model.State = 1

        REM zobrazenie vlastností modelu pre ovládací prvok CommandButton1

        oCMD1Model = oDialog1Model.CommandButton1

        MsgBox oCMD1Model.Dbg_Properties

        REM zobrazenie vlastností pre ovládací prvok CommandButton1

        oCMD1 = oDialog1.GetControl("CommandButton1")

        MsgBox oCMD1.Dbg_Properties

        REM spustenie dialógu

        oDialog1.Execute()

    End Sub

### Pridanie položky do poľa zoznamu

    Sub AddEntry

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM pridanie novej položky do poľa zoznamu

        oDialog1Model = oDialog1.Model

        oListBox = oDialog1.GetControl("ListBox1")

        Dim iCount as integer

        iCount = oListbox.ItemCount

        oListbox.additem("Nová položka" & iCount,0)

    End Sub

### Odstránenie položky z poľa zoznamu

    Sub RemoveEntry

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM odstránenie prvej položky z poľa zoznamu

        oDialog1Model = oDialog1.Model

        oListBox = oDialog1.GetControl("ListBox1")

        oListbox.removeitems(0,1)

    End Sub

Related Topics

Zmena vlastností ovládacích prvkov v dialógovom okne editora

vytváranie dialógových okien Basic

Vytváranie ovládacích prvkov v Editore dialógových okien

Otvorenie dialógu pomocou programového kódu