Module
Contents
Index 🔎︎

# Funkce sešitu

V této sekci budou uvedeny popisy funkcí Sešitu spolu s příklady.

Pro přístup k tomuto příkazu...

Vložit - Funkce - Kategorie Sešit

## ERROR.TYPE

Vrátí číslo představující určitý typ chyby, nebo chybovou hodnotu #N/A, pokud se o chybu nejedná.

## ADDRESS

Vrátí adresu buňky (souřadnici) v textovém tvaru na základě zadaných čísel řádku a sloupce. Můžete určit, zda bude adresa interpretována jako absolutní (například $A$1) nebo jako relativní (A1) či ve smíšeném tvaru (A$1 nebo $A1). Můžete také zadat název pracovního listu.

Z důvodů interoperability podporují funkce ADDRESS a INDIRECT volitelný parametr, který určuje, zda se má použít notace R1C1 namísto obvyklé A1.

U funkce ADDRESS se parametr zapíše jako čtvrtý parametr a volitelný název listu se posune na páté místo.

U funkce INDIRECT se parametr zapíše jako druhý parametr.

U obou funkcí platí, že pokud má parametr hodnotu 0, použije se notace R1C1. Pokud není parametr uveden nebo má hodnotu jinou než 0, použije se notace A1.

Při použití notace R1C1 vrací ADDRESS řetězec, ve které je k oddělení názvu listu použit vykřičník, a INDIRECT očekává vykřičník jako oddělovač názvu listu. Při použití notace A1 obě funkce používají k oddělení názvu listu tečku.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Při ukládání do formátu ODF 1.0/1.1 a pokud má funkce ADDRESS čtvrtý parametr, se tento parametr odstraní.

Pokud jste použil u funkce ADDRESS nový čtvrtý parametr s hodnotou 0, neukládejte sešit ve starém formátu ODF 1.0/1.1.

Funkce INDIRECT se do formátu ODF 1.0/1.1 uloží bez konverze. Pokud bude přítomen druhý parametr, starší verze Calcu ohlásí u této funkce chybu.

### Syntaxe

ADDRESS(Řádek; Sloupec; Abs; A1; "List")

Řádek představuje číslo řádku pro souřadnici buňky

Sloupec představuje číslo sloupce pro souřadnici buňky (číslo, nikoli písmeno)

Abs určuje typ souřadnice:

1: absolutní adresa ($A$1)

2: absolutní adresa souřadnice řádku, relativní adresa souřadnice sloupce (A$1),

3: relativní adresa souřadnice řádku, absolutní adresa souřadnice sloupce ($A1),

4: relativní adresa (A1).

A1 (volitelný) - pokud je nastaveno na 0, je použita notace R1C1. Pokud tento parametr chybí nebo je nastaven na jinou hodnotu než 0, je použita notace A1.

List představuje název listu. Musí být umístěn v uvozovkách.

### Příklad:

=ADDRESS(1;1;2;;"List2") vrátí: List2.A$1

## AREAS

Vrátí počet jednotlivých oblastí buněk, které jsou součástí propojené oblasti. Oblastí se rozumí souvislá oblast buněk nebo jediná buňka.

Funkce očekává jediný parametr. Pokud zadáte více oblastí, musíte je uzavřít do dodatečných závorek. Více oblastí lze zadat s využitím středníku (;) jako oddělovače. Ten je automaticky převeden na vlnovku (~), která se používá ke spojování oblastí.

### Syntaxe

AREAS(Odkaz)

Odkaz představuje souřadnice buněk nebo oblasti buněk.

### Příklad

=AREAS((A1:B3;F2;G1)) vrátí 3, protože jde o odkaz na tři buňky a/nebo oblasti. Po potvrzení zadání je vzorec převeden na =AREAS((A1:B3~F2~G1)).

=AREAS(Vše) vrátí 1, pokud jste za pomoci dialogu Data - Definovat oblast definovali oblast Vše.

## CHOOSE

Použije index pro vrácení hodnoty ze seznamu až 30 hodnot.

### Syntaxe

CHOOSE(Index; Hodnota1; ...; Hodnota30)

Index je odkaz nebo číslo mezi 1 a 30 udávající, která hodnota se vezme ze seznamu.

Value1, Value2, ..., Value30 is the list of values entered as a reference to a cell or as individual values.

### Příklad

Například =CHOOSE(A1;B1;B2;B3;"Dnes";"Včera";"Zítra"), vrátí pro A1 = 2 obsah buňky B2; pro A1 = 4 funkce vrátí text "Dnes".

## COLUMN

Vrátí číslo sloupce odkazu na buňku. Odkazuje-li odkaz na buňku, je vráceno číslo sloupce odpovídající buňky. Je-li odkazováno na matici, jsou vráceny odpovídající čísla sloupců v jednořádkové matici pokud byl vzorec zadán jako maticový vzorec. Není-li funkce COLUMN odkazující se na matici použita jako maticový vzorec, potom je vráceno pouze číslo sloupce první buňky z matice.

### Syntaxe

COLUMN(odkaz)

Odkaz je odkaz na buňku nebo oblast pro kterou má být určeno číslo jejího prvního sloupce.

Není-li parametr odkaz zadán, potom je vráceno číslo sloupce buňky, ve které je samotná funkce zadána. LibreOffice Calc automaticky nastaví odkaz na aktuální buňku.

### Příklad

=COLUMN(A1) se rovná 1. Sloupec A je prvním sloupcem tabulky.

=COLUMN(C3:E3) se rovná 3. Sloupec C je třetím sloupcem tabulky.

=COLUMN(D3:G10) vrátí 4, protože sloupec D je čtvrtým sloupcem tabulky a funkce COLUMN není použita jako maticová funkce. (V tomto případě je jako výsledek vždy použita první hodnota matice.)

{=COLUMN(B2:B7)} a =COLUMN(B2:B7) obě vrátí 2, protože odkaz obsahuje pouze sloupec B, který je druhým sloupcem tabulky. Protože jednosloupcové oblasti mají jen jeden sloupec, nezáleží na tom, zda je funkce použita jako maticová funkce.

=COLUMN() vrátí 3, pokud byla funkce zadána ve sloupci C.

{=COLUMN(Rabbit)} vrátí jednořádkovou matici (3, 4), pokud je "Rabbit" pojmenovaná oblast (C1:D3).

## COLUMNS

Vrátí počet sloupců v zadané oblasti.

### Syntaxe

COLUMNS(oblast)

Oblast je odkaz na oblast buněk, pro kterou má být určen počet sloupců. Odkaz může odkazovat i na samostatnou buňku.

### Příklad

=COLUMNS(B5) vrátí 1, protože buňka obsahuje jen jeden sloupec.

=COLUMNS(A1:C5) se rovná 3. Odkaz je složen ze tří sloupců.

=COLUMNS(Rabbit) vrátí 2, pokud je Rabbit pojmenovaná oblast (C1:D3).

## DDE

Vrátí výsledek DDE propojení. Pokud se obsah propojené oblasti nebo oddílu změní, bude změněna i hodnota vrácená touto funkcí. Aby se změny projevily, je nutné buď sešit znovu otevřít, nebo zvolit Úpravy - Odkazy. Není možné použít meziplatformní odkazy, například z instalace LibreOffice na počítači se systémem Windows do dokumentu vytvořeného na linuxovém stroji.

### Syntaxe

DDE("Server"; "Soubor"; "Oblast"; Režim)

Server is the name of a server application. LibreOffice applications have the server name "soffice".

soubor je název souboru včetně cesty.

oblast určuje oblast obsahující data, která mají být vyhodnocena.

režim je nepovinný parametr, který určuje metodu, kterou DDE server použije k převodu dat na čísla.

režim | efekt
0 nebo nezadáno | Formát čísla podle výchozího formátu zadaného ve stylu buňky.
1 | Data budou interpretována ve výchozích formátech pro češtinu.
2 | Data nebudou převedena na čísla, ale vložena jako text.

### Příklad

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

## ERRORTYPE

Vrátí číslo odpovídající chybové hodnotě v jiné buňce. Pomocí tohoto čísla je možné vygenerovat text chybové zprávy.

Pokud nastane chyba, funkce vrací logickou nebo číselnou hodnotu.

Jestliže klepnete na buňku obsahující chybu, stavová řádka zobrazuje předdefinovaný chybový kód LibreOffice.

### Syntaxe

ERRORTYPE(Odkaz)

Odkaz obsahuje adresu buňky, ve které došlo k chybě.

### Příklad

Pokud se v buňce A1 zobrazuje Chyba:518, funkce =ERRORTYPE(A1) vrátí číslo 518.

## GETPIVOTDATA

Funkce GETPIVOTDATA vrací výslednou hodnotu z kontingenční tabulky. Hodnota je odkazována pomocí názvu pole a položek, takže zůstane platná, i když se změní rozvržení kontingenční tabulky.

### Syntaxe

Lze použít dvě různé syntaxe:

GETPIVOTDATA(CílovéPole; kontingenční tabulka; [ Pole 1; Položka 1; ... ])

GETPIVOTDATA(kontingenční tabulka; Omezení)

Druhá syntaxe se použije, pokud jsou zadány přesně dva parametry, z nichž první je buňka nebo oblast buněk. V ostatních případech se použije první syntaxe. Průvodce funkcí nabídne první syntaxi.

### První syntaxe

CílovéPole je řetězec, pomocí kterého se vybere jedno z datových polí kontingenční tabulky. Řetězec může být názvem zdrojového sloupce nebo názvem datového pole, který se zobrazuje v tabulce (například "Součet - tržby").

Kontingenční tabulka je odkaz na buňku nebo oblast buněk, která se nachází v kontingenční tabulce nebo kontingenční tabulku obsahuje. Pokud oblast buněk obsahuje několik kontingenčních tabulek, použije se naposledy vytvořená tabulka.

Pokud nejsou zadány dvojice Pole n / Položka n, vrátí funkce celkový součet. Jinak každá dvojice přidá omezující podmínku, kterou musí výsledek splnit. Pole n je název pole z kontingenční tabulky. Položka n je název položky z tohoto pole.

Pokud kontingenční tabulka obsahuje pouze jedinou výslednou hodnotu, která splňuje všechny podmínky, nebo mezisoučet, který sečte všechny odpovídající hodnoty, vrátí se výsledek. Pokud není nalezen žádný odpovídající výsledek nebo je výsledků několik, vrátí se chyba. Podmínky se aplikují na výsledky, které jsou obsaženy v kontingenční tabulce.

Pokud zdrojová data obsahují záznamy, které jsou nastavením kontingenční tabulky skryty, ignorují se. Na pořadí dvojic Pole/Položka nezáleží. U názvů polí a položek nezáleží na velikosti znaků.

Pokud není určena omezující podmínka pro pole stránky, zvolí se aktuálně použitá hodnota pole. Pokud je použita omezující podmínka, musí se shodovat s aktuální hodnotou pole, jinak je vrácena chyba. Pole stránky jsou pole v levé horní části kontingenční tabulky, přidaná přesunutím do oblasti "Pole stránky" v dialogu rozvržení kontingenční tabulky. Z každého pole stránky lze vybrat položku (hodnotu), což znamená, že se do výpočtu zahrne jen tato položka.

Hodnoty mezisoučtu z kontingenční tabulky se použijí, pouze pokud používají funkci "auto" (kromě případu, kdy jsou určeny v omezujících podmínkách, viz Druhá syntaxe níže).

### Druhá syntaxe

Kontingenční tabulka má stejný význam jako v první syntaxi.

Omezení je mezerami oddělený seznam. Položky mohou být uzavřeny v jednoduchých uvozovkách. Celý řetězec musí být uzavřen v dvojitých uvozovkách, pokud na řetězec neodkazujete do jiné buňky.

Jedna z položek může být název datového pole. Název datového pole lze vynechat, pokud kontingenční tabulka obsahuje jen jedno datové pole, jinak musí být přítomen.

Ostatní položky určují omezující podmínky v podobě Pole[Položka] (s hranatými závorkami [ a ]), nebo jen Položka, pokud je název položky jedinečný v rámci všech polí použitých v kontingenční tabulce.

Jméno funkce může být přidáno ve formě Pole[Položka;Funkce]. Takto stanovenému omezení budou vyhovovat pouze dílčí výsledky vypočtené zadanou funkcí. Možné názvy funkcí jsou Sum, Count, Average, Max, Min, Product, Count (pouze čísla), StDev (výběr), StDevP (základní soubor), Var (výběr), a VarP (základní soubor), nezáleží u nich na velikosti písmen.

## HLOOKUP

Hledá hodnotu a odkáže na buňky vybrané oblasti. Tato funkce ověřuje, zda první řádek oblasti obsahuje určitou hodnotu. Funkce potom vrátí hodnotu ze stejného sloupce, ale z řádku určeného v parametru Index.

Vyhledávání podporuje regulární výrazy. Například můžete zadat "all.*", abyste našli první výskyt "all" následovaný jakýmikoliv znaky. Chcete-li hledat text, který je rovněž regulárním výrazem, musíte před každý znak napsat znak \. Vypnout a zapnout automatické vyhodnocování regulárních výrazů můžete v LibreOffice - Předvolby Nástroje - Možnosti
- LibreOffice Calc - Výpočty.

### Syntaxe

HLOOKUP(SearchCriterion; Array; Index; Sorted)

See also: VLOOKUP (columns and rows are exchanged)

Práce s prázdnými buňkami

## HYPERLINK

Pokud klepnete na buňku, která obsahuje funkci HYPERLINK, otevře se hypertextový odkaz.

Jestliže použijete nepovinný parametr TextBuňky, vzorec najde adresu URL a poté zobrazí zadaný text nebo číslo.

Buňku s hypertextovým odkazem otevřete pomocí klávesnice tak, že nejprve vyberete buňku, stisknete F2, abyste se dostali do režimu úprav, přesunete kurzor před hypertextový odkaz, stisknete Shift+F10 a potom vyberete Otevřít hypertextový odkaz.

### Syntaxe

HYPERLINK("URL") nebo HYPERLINK("URL"; "TextBuňky")

URL udává cíl odkazu. Nepovinný parametr TextBuňky je text nebo číslo, které se zobrazí v buňce a vrátí se jako výsledek. Pokud není parametr TextBuňky zadán, v buňce se zobrazí a jako výsledek se vrátí URL.

Pro prázdné buňky a prvky matice se vrátí číslo 0.

### Příklad

=HYPERLINK("http://www.example.org") zobrazí v buňce text "http://www.example.org" a po klepnutí přejde na hypertextový odkaz http://www.example.org.

=HYPERLINK("http://www.example.org";"Klepněte sem") zobrazí v buňce text "Klepněte sem" a po klepnutí přejde na hypertextový odkaz http://www.example.org.

=HYPERLINK("http://www.example.org";12345) zobrazí číslo 12345 a po klepnutí přejde na hypertextový odkaz http://www.example.org.

=HYPERLINK($B4), kde B4 obsahuje http://www.example.org. Funkce vloží http://www.example.org do URL buňky s hypertextovým odkazem a jako výsledek vzorce vrátí stejný text.

=HYPERLINK("http://www.";"Klepněte na ") & "example.org" zobrazí v buňce text Klepněte na example.org a po kliknutí přejde na hypertextový odkaz http://www.example.org.

=HYPERLINK("#List1.A1";"Zpět na začátek") zobrazí text Zpět na začátek a přejde v dokumentu na buňku List1.A1.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

## INDEX

INDEX vrací podoblast specifikovanou čísly řádků a sloupců nebo volitelným indexem oblasti. V závislosti na obsahu INDEX vrací odkaz nebo obsah.

### Syntaxe

INDEX(Odkaz; Řádek; Sloupec; Oblast)

Odkaz je přímý odkaz nebo odkaz na pojmenovanou oblast. Pokud se rozhodnete odkazovat na vícenásobnou oblast, musíte odkaz na ní nebo její název uzavřít do závorek.

Řádek (nepovinné) určuje řádek odkazované oblasti, pro který mají být vráceny hodnoty. Pokud je nastavena hodnota nula (žádný určitý řádek), jsou vráceny všechny odkazované řádky.

Sloupec (nepovinné) určuje sloupec odkazované oblasti, pro který mají být vráceny hodnoty. Pokud je nastavena hodnota nula (žádný určitý sloupec), jsou vráceny všechny odkazované sloupce.

Oblast (nepovinné) určuje číslo podoblasti, pokud je odkazováno na vícenásobnou oblast.

### Příklad

=INDEX(Ceny;4;1) vrátí hodnotu z řádku 4 ve sloupci 1 z databázové oblasti s názvem Ceny, definované v dialogu Data - Definovat oblast.

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

=INDEX(A1:B6;1) vrátí odkaz na první řádek oblasti A1:B6.

=INDEX(A1:B6;0;1) vrátí odkaz na první sloupec oblasti A1:B6.

=INDEX((multi);4;1) indicates the value contained in row 4 and column 1 of the (multiple) range, which you named under Sheet - Named Ranges and Expressions - Define as multi. The multiple range may consist of several rectangular ranges, each with a row 4 and column 1. If you now want to call the second block of this multiple range enter the number 2 as the range parameter.

=INDEX(A1:B6;1;1) odkazuje na hodnotu v levém horním rohu oblasti A1:B6.

=INDEX((multi);0;0;2) vrátí odkaz na druhou oblast vícenásobné oblasti.

## INDIRECT

Vrátí odkaz určený textovým řetězcem. Tuto funkci je také možné použít k získání oblasti odpovídajícího názvu.

Z důvodů interoperability podporují funkce ADDRESS a INDIRECT volitelný parametr, který určuje, zda se má použít notace R1C1 namísto obvyklé A1.

U funkce ADDRESS se parametr zapíše jako čtvrtý parametr a volitelný název listu se posune na páté místo.

U funkce INDIRECT se parametr zapíše jako druhý parametr.

U obou funkcí platí, že pokud má parametr hodnotu 0, použije se notace R1C1. Pokud není parametr uveden nebo má hodnotu jinou než 0, použije se notace A1.

Při použití notace R1C1 vrací ADDRESS řetězec, ve které je k oddělení názvu listu použit vykřičník, a INDIRECT očekává vykřičník jako oddělovač názvu listu. Při použití notace A1 obě funkce používají k oddělení názvu listu tečku.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Při ukládání do formátu ODF 1.0/1.1 a pokud má funkce ADDRESS čtvrtý parametr, se tento parametr odstraní.

Pokud jste použil u funkce ADDRESS nový čtvrtý parametr s hodnotou 0, neukládejte sešit ve starém formátu ODF 1.0/1.1.

Funkce INDIRECT se do formátu ODF 1.0/1.1 uloží bez konverze. Pokud bude přítomen druhý parametr, starší verze Calcu ohlásí u této funkce chybu.

### Syntaxe

INDIRECT(Odkaz; A1)

Odkaz představuje odkaz na buňku nebo oblast (v textové podobě) pro kterou má být vrácen obsah.

A1 (volitelný) - pokud je nastaveno na 0, je použita notace R1C1. Pokud tento parametr chybí nebo je nastaven na jinou hodnotu než 0, je použita notace A1.

Otevřete-li sešit aplikace Microsoft Excel používající nepřímé adresy získávané pomocí řetězcových funkcí, potom tyto adresy nebudou automaticky přeloženy. Například adresa INDIRECT("filename!sheetname"&B1) nebude převedena na Calc adresu INDIRECT("filename.sheetname"&B1).

### Příklad

=INDIRECT(A1) se rovná 100 pokud A1 obsahuje odkaz na C108 a buňka C108 obsahuje hodnotu 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) sečte obsah buněk v oblasti A1 až po buňku s adresou definovanou v řádku 1 a sloupci 3. To znamená, že sečtena bude oblast A1:C1.

Obsahuje-li buňka A1 v listu2 hodnotu -6, můžete odkazovat nepřímo na adresu buňky s použitím funkce vložením do B2 =ABS(INDIRECT(B2)). Výsledkem je absolutní hodnota adresy buňky specifikované v B2, která je v tomto případě 6.

## LOOKUP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

Pokud LOOKUP nemůže najít kritérium vyhledávání, použije nejvyšší hodnotu prohlédaváného vektoru, která je menší nebo rovna kritériu vyhledávání.

Vyhledávání podporuje regulární výrazy. Například můžete zadat "all.*", abyste našli první výskyt "all" následovaný jakýmikoliv znaky. Chcete-li hledat text, který je rovněž regulárním výrazem, musíte před každý znak napsat znak \. Vypnout a zapnout automatické vyhodnocování regulárních výrazů můžete v LibreOffice - Předvolby Nástroje - Možnosti
- LibreOffice Calc - Výpočty.

### Syntaxe

LOOKUP(KritériumHledání; VyhledávacíVektor; VýsledkovýVektor)

KritériumHledání je hledaná hodnota zadaná přímo nebo jako odkaz.

VyhledávacíVektor je jednořádková nebo jednosloupcová oblast ve které má být hledáno.

VýsledkovýVektor je další jednořádková nebo jednosloupcová oblast, ze které má být načten výsledek funkce. Výsledkem je buňka výsledkového vektoru se stejným indexem jako buňka nalezená ve vyhledávacím vektoru.

Práce s prázdnými buňkami

### Příklad

=LOOKUP(A1;D1:D100;F1:F100) v oblasti D1:D100 vyhledá číslo zadané do buňky A1. Po nalezení je určen index nálezu, například 12. buňka oblasti. Jako výsledek je pak vrácen obsah 12. buňky výsledkového vektoru.

## MATCH

Vrátí relativní polohu prvku v poli, který se shoduje se zadanou hodnotou. Funkce vrací číselnou pozici hodnoty nalezené v vyhledávací_pole.

### Syntaxe

MATCH(KritériumHledání, VyhledávacíOblast, Typ)

KritériumHledání je hodnota, která má být vyhledána v jednořádkové nebo jednosloupcové oblasti.

VyhledávacíOblast je prohledávaný odkaz. Vyhledávací oblast může být jeden řádek nebo sloupec, nebo část jednoho řádku nebo sloupce.

Typ může nabývat hodnot 1, 0, nebo -1. Pokud se Type = 1 nebo tento parametr není uveden, předpokládá se, že první sloupec prohledávané matice je vzestupně seřazen. Pokud se Type = -1, předpokládá se, že je sloupec seřazen v sestupném pořadí. Tato funkce odpovídá stejné funkci v programu Microsoft Excel.

Je-li Typ=0, jsou nalezeny jen přesně odpovídající si hodnoty. Je-li nalezeno kritérium hledání více než jednou, funkce vrátí index první odpovídající hodnoty. Pouze tehdy, pokud je Typ = 0, můžete použít i regulární výrazy nebo zástupné znaky (podle toho, jsou-li povoleny v možnostech výpočtu).

Pokud se Typ=1 nebo třetí parametr chybí, je vrácen index poslední hodnoty, která je menší nebo rovna hledanému kritériu. Toto je použito pouze pokud prohledávané pole není seřazeno. Pro Typ=-1 je vrácena první hodnota, která větší nebo rovna.

Vyhledávání podporuje regulární výrazy. Například můžete zadat "all.*", abyste našli první výskyt "all" následovaný jakýmikoliv znaky. Chcete-li hledat text, který je rovněž regulárním výrazem, musíte před každý znak napsat znak \. Vypnout a zapnout automatické vyhodnocování regulárních výrazů můžete v LibreOffice - Předvolby Nástroje - Možnosti
- LibreOffice Calc - Výpočty.

### Příklad

=MATCH(200;D1:D100) hledá v oblasti D1:D100, která je seřazana podle sloupce D, hodnotu 200. Jakmile je tato hodnota dosažena, je vráceno číslo řádku ve kterém byla nalezena. Pokud je během hledání ve sloupci nalezena vyšší hodnota, je vráceno číslo předchozího řádku.

## OFFSET

Vrátí hodnotu buňky posunuté od výchozího odkazu o určený počet řádků a sloupců.

### Syntaxe

OFFSET(Odkaz, Řádky, Sloupce, Výška, Šířka)

Odkaz je odkaz od kterého funkce bude hledat nový odkaz.

Řádky je počet řádků, o který má být odkaz posunut nahoru (záporná hodnota) nebo dolů. Chcete-li zůstat na stejném řádku, použijte 0.

Řádky je počet řádků, o který má být odkaz posunut nahoru (záporná hodnota) nebo dolů. Chcete-li zůstat na stejném řádku, použijte 0.

Výška (nepovinné) je svislá výška oblasti, která má počátek na pozici nového odkazu.

Šířka (nepovinné) je vodorovná šířka oblasti, která má počátek na pozici nového odkazu.

Argumenty Řádky a Sloupce nesmí vést k nulovému nebo zápornému počátečnímu řádku nebo sloupci.

Argumenty Výška a Šířka nesmí vést k nulovému nebo zápornému počtu řádků a sloupců.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Příklad

=OFFSET(A1;2;2) vrátí hodnotu buňky C3 (A1 posunuto o dva řádky dolů a dva sloupce doprava). Pokud C3 obsahuje hodnotu 100, tato funkce vrátí hodnotu 100.

=OFFSET(B2:C3;1;1) vrátí odkaz na B2:C3 posunutý o jeden řádek dolů a jeden sloupec doprava (C3:D4).

=OFFSET(B2:C3;-1;-1) vrátí odkaz na B2:C3 posunutý o jeden řádek nahoru a jeden sloupec doleva (A1:B2).

=OFFSET(B2:C3;0;0;3;4) vrátí odkaz na B2:C3 s velikostí změněnou na 3 řádky a 4 sloupce (B2:E4).

=OFFSET(B2:C3;1;0;3;4) vrátí odkaz na B2:C3 posunutý o jeden řádek dolů a s velikostí změněnou na 3 řádky a 4 sloupce (B3:E5).

=SUM(OFFSET(A1;2;2;5;6)) spočítá součet oblasti s počátkem v buňce C3 a s výškou 5 řádek a šířkou 6 sloupců (oblast=C3:H7).

Pokud je uvedena šířka nebo výška, funkce OFFSET vrátí oblast, a proto musí být zadána jako maticový vzorec. Jsou-li šířka i výška vynechány, vrátí se odkaz na buňku.

## ROW

Vrátí číslo řádku odkazu na buňku. Jde-li o odkaz na buňku, je vráceno číslo řádku buňky. Jde-li o odkaz na oblast buněk, jsou vrácena čísla jednotlivých řádků v jednosloupcové matici, pokud bylo určeno, že jde o maticový vzorec. Je-li funkce ROW použita s odkazem na oblast, ale není určeno, že jde o maticový vzorec, potom je vráceno číslo prvního řádku oblasti.

### Syntaxe

ROW(Odkaz)

Odkaz je buňka, oblast nebo název oblasti.

Nezadáte-li parametr odkaz, potom je vráceno číslo řádku buňky obsahující tuto funkci. LibreOffice Calc automaticky nastaví odkaz na aktuální buňku.

### Příklad

=ROW(B3) vrátí 3, protože odkaz vede na třetí řádek tabulky.

{=ROW(D5:D8)} vrátí jednosloupcovou matici (5, 6, 7, 8), protože daný odkaz obsahuje řádky od 5 do 8.

=ROW(D5:D8) vrátí 5, protože funkce ROW nebyla použita jako maticový vzorec a vrací se pouze číslo prvního řádku odkazu.

{=ROW(A1:E1)} i =ROW(A1:E1) vrátí 1, protože odkaz obsahuje řádek 1 jako první řádek tabulky. (Protože jednořádkové oblasti obsahují pouze jediný řádek, nezáleží na tom, zda je použit maticový vzorec.

=ROW() vrátí 3, pokud byl vzorec zadán do řádku 3.

{=ROW(Rabbit)} vrátí jednosloupcovou matici (1, 2, 3), pokud je "Rabbit" pojmenovaná oblast (C1:D3).

## ROWS

Vrátí počet řádků odkazu nebo matice.

### Syntaxe

ROWS(Matice)

Matice je odkaz nebo pojmenovaná oblast, pro kterou se má určit celkový počet řádků.

### Příklad

=Rows(B5) vrátí 1, protože buňka obsahuje pouze jeden řádek.

=ROWS(A10:B12) vrátí 3.

=ROWS(Rabbit) vrátí 3, pokud je "Rabbit" pojmenovaná oblast (C1:D3).

## SHEET

Vrátí číslo listu pro zadaný odkaz nebo název listu jako řetězec. Nezadáte-li žádný z parametrů, funkce vrátí číslo toho listu sešitu, který obsahuje vzorec.

### Syntaxe

SHEET(Odkaz)

Odkaz je nepovinný parametr a může jít o odkaz na buňku, oblast nebo název listu.

### Příklad

=SHEET(List2.A1) vrátí 2 pokud je List2 druhým listem sešitu.

## SHEETS

Určí počet listů v odkazu. Nezadáte-li žádný z parametrů funkce, potom je vrácen počet listů aktuálního dokumentu.

### Syntaxe

SHEETS(Odkaz)

Reference je odkaz na list nebo oblast. Tento parametr je nepovinný.

### Příklad

=SHEETS(List1.A1:List3.G12) vrátí 3 pokud List1, List2 a List3 v dokumentu existují v uvedeném pořadí.

## STYLE

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats, "red" and "green" have to be defined beforehand.

### Syntaxe

STYLE("Styl"; Čas; "Styl2")

Styl je název stylu buňky přiřazený dané buňce. Název stylu musí být uzavřen do dvojitých uvozovek.

Time je nepovinný časový úsek, zadaný v sekundách. Pokud tento parametr není zadán, nedojde po uplynutí určitého času ke změně stylu.

Styl2 je nepovinný parametr udávající název stylu, který má být pro buňku použit po uplynutí zadaného časového úseku. Pokud není tento parametr uveden, předpokládá se "Výchozí" styl.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Příklad

=STYLE("Neviditelné";60;"výchozí") zformátuje buňky na průhledné na 60 sekund od doby, kdy byl dokument přepočítán nebo načten, poté se přiřadí formát Výchozí. Oba formáty buněk musí být definovány předem.

Since STYLE() has a numeric return value of zero, this return value gets appended to a string. This can be avoided using T() as in the following example:

="Text"&T(STYLE("můjStyl"))

Viz též CURRENT() pro další příklad.

## VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact SearchCriterion is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

Vyhledávání podporuje regulární výrazy. Například můžete zadat "all.*", abyste našli první výskyt "all" následovaný jakýmikoliv znaky. Chcete-li hledat text, který je rovněž regulárním výrazem, musíte před každý znak napsat znak \. Vypnout a zapnout automatické vyhodnocování regulárních výrazů můžete v LibreOffice - Předvolby Nástroje - Možnosti
- LibreOffice Calc - Výpočty.

### Syntaxe

=VLOOKUP(SearchCriterion; Array; Index; Sorted)

KritériumHledání je hodnota hledaná v prvním sloupci matice.

Matice je odkaz na oblast obsahující minimálně dva sloupce.

Index je číslo sloupce matice, který obsahuje hodnotu, která má být vrácena. První sloupec má číslo 1.

Sorted is an optional parameter that indicates whether the first column in the array is sorted in ascending order. Enter the Boolean value FALSE or zero if the first column is not sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is between the lowest and highest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return this message: Error: Value Not Available.

Práce s prázdnými buňkami

### Příklad

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Do buňky B1 zadejte následující vzorec:

=VLOOKUP(A1;D1:E100;2)

Jakmile zadáte do buňky A1 číslo, zobrazí se v buňce B1 odpovídající text obsažený v druhém sloupci v oblasti buněk D1:E100. Pokud zadáte číslo, které se ve sloupci D nenalézá, bude zobrazen text odpovídající nejbližší následující číselné hodnotě. Pokud chcete, aby při zadání neexistujícího čísla byla zobrazena chybová zpráva, zadejte v posledním parametru vzorce logickou hodnotu NEPRAVDA.

Související témata

Functions by Category