/
Prev | Orchestra Opcodes and Operators | Next

## /

/ — Division operator.

## Description

Arithmetic operators perform operations of change-sign (negate), don't-change-sign, logical AND logical OR, add, subtract, multiply and divide. Note that a value or an expression may fall between two of these operators, either of which could take it as its left or right argument, as in

a + b * c.

In such cases three rules apply:

1. * and / bind to their neighbors more strongly than + and −. Thus the above expression is taken as

a + (b * c)

with * taking b and c and then + taking a and b * c.

2. + and − bind more strongly than &&, which in turn is stronger than ||:

a && b - c || d

is taken as

(a && (b - c)) || d

3. When both operators bind equally strongly, the operations are done left to right:

a - b - c

is taken as

(a - b) - c

Parentheses may be used as above to force particular groupings.

## Syntax

    a /  b  (no rate restriction)

where the arguments a and b may be further expressions.

## Arguments

The arguments of / can be scalar values or k-rate one dimensional arrays (vectors), or any combination. If one of the arguments is an array, so is the value.

## Examples

Here is an example of the / operator. It uses the file divides.csd.

Example 30. Example of the / operator.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o /.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    idiv  = 1/p3 * p4
    ktrm  oscil 1, idiv, 1						;use oscil as an envelope
    printf "retrigger rate per note duration = %f\n",1, idiv
    kndx  line 5, p3, 1						;vary index of FM
    asig  foscil ktrm, 200, 1, 1.4, kndx, 1
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1  0 4096 10   1    ;sine wave

    i 1 0 3	10
    i 1 4 3 15
    i 1 8 3 2

    e
    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like these:

    retrigger rate per note duration = 3.333333
    retrigger rate per note duration = 5.000000
    retrigger rate per note duration = 0.666667

## See Also

-, +, &&, ||, *, ^, %

## Credits

Arithmetic on vectors is new in version 6.00

Prev | Up | Next
- | Home | =