Modulo
Contenuto
Indice 🔎︎

# Categoria Testo

In questa sezione sono descritte le funzioni della categoria Testo.

Per accedere a questo comando...

Inserisci - Funzione - Categoria Testo

## ANNULLA.SPAZI

Rimuove gli spazi da una stringa, lasciando un singolo spazio tra le parole.

### Sintassi

ANNULLA.SPAZI("Testo")

Testo indica il testo in cui gli spazi devono essere rimossi.

### Esempio

=ANNULLA.SPAZI(" ciao mondo ") restituisce ciao mondo senza spazi davanti e dietro e con un singolo spazio tra le parole.

## ARABO

Calcola il valore di un numero romano. L'intervallo di valori deve essere compreso tra 0 e 3999.

### Sintassi

ARABO("Testo")

Testo è il testo che rappresenta il numero romano.

### Esempio

=ARABO("MXIV") restituisce 1014

=ARABO("MMII") restituisce 2002

## ASC

La funzione ASC converte i caratteri ASCII e katakana da larghezza piena a larghezza dimezzata. Restituisce una stringa di testo.

Per la conversione di una tabella consultate https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions.

### Sintassi

ASC("Testo")

Testo è il testo che contiene i caratteri da convertire.

Vedere anche la funzione JIS.

## BASE

Converte un numero intero positivo in un testo da un sistema numerico alla base indicata. Vengono usate le cifre 0-9 e le lettere A-Z.

### Sintassi

BASE(Numero; Radice; [Lunghezza_minima])

Numero è l'intero positivo da convertire.

Radice indica la base del sistema numerico. Può essere un numero intero tra 2 e 36.

Lunghezza minima (opzionale) determina la lunghezza minima della sequenza di caratteri creata. Indicando questo parametro, se il testo è più breve verrà completato con degli zeri a sinistra della stringa.

### Esempio

=BASE(17;10;4) restituisce 0017 nel sistema decimale.

=BASE(17;2) restituisce 10001 nel sistema binario.

=BASE(255;16;4) restituisce 00FF nel sistema esadecimale.

## CARATT.UNI

Converte un numero di codice in un carattere o una lettera Unicode.

### Sintassi

CARATT.UNI(Numero)

### Esempio

=CARATT.UNI(169) restituisce il carattere di copyright ©.

Vedere anche la funzione UNICODE().

## CODICE

Restituisce il codice numerico del primo carattere di un testo o di una stringa.

### Sintassi

CODICE("Testo")

Testo è il testo per il quale si desidera trovare il codice del primo carattere.

Codici più grandi di 127 possono dipendere dalla mappatura dei caratteri del vostro sistema (ad esempio iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), e non essere dunque trasferibili.

### Esempio

La funzione =CODICE("Geronimo") restituisce 71, la funzione =CODICE("geroglifico") 103.

Il codice qui utilizzato non è un codice ASCII ma il codice della tabella corrente.

## CODICE.CARATT

Converte un numero in un carattere in base alla tabella codici attuale. Il numero può essere un numero intero di due o tre cifre.

Codici più grandi di 127 possono dipendere dalla mappatura dei caratteri del vostro sistema (ad esempio iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), e non essere dunque trasferibili.

### Sintassi

CODICE.CARATT(Numero)

Numero è un numero tra 1 e 255 che rappresenta il codice per il carattere.

### Esempio

=CODICE.CARATT(100) restituisce il carattere "d".

="abc" & CODICE.CARATT(10) & "def" inserisce un carattere di nuova riga all'interno della stringa.

## CONCATENA

Combina più stringhe di testo in un'unica stringa.

### Sintassi

CONCATENA("Testo 1"; ...; "Testo 30")

Testo 1; Testo 2; ... rappresenta fino a 30 passaggi di testo da combinare all'interno di una stringa.

### Esempio

=CONCATENA("Buon";"giorno ";"signora "; "Rossi") restituisce Buongiorno signora Rossi.

## DECIMALE

Converte un testo con caratteri da un determinato sistema numerico in un intero positivo, utilizzando come base la radice indicata. La radice deve essere compresa tra 2 e 36. Eventuali spazi e tabulazioni verranno ignorati. Il campo Testo non distingue tra maiuscole e minuscole.

Se la radice è 16, il sistema ignora un eventuale carattere x, X, 0x o 0X iniziale, e i caratteri h o H finali. Se la radice è 2, il sistema ignora un eventuale carattere b o B finale. Altri caratteri non appartenenti al sistema numerico generano un errore.

### Sintassi

DECIMALE("Testo"; Radice)

Testo è il testo da convertire. Per differenziarlo da un numero esadecimale, tipo A1 e il riferimento alla cella A1, dovete inserire il numero tra virgolette, per esempio, "A1" o "CADE".

Radice indica la base del sistema numerico. Può essere un numero intero tra 2 e 36.

### Esempio

=DECIMALE("17";10) restituisce 17.

=DECIMALE("CADE";16) restituisce 51934.

=DECIMALE("0101"; 2) restituisce 5.

## DESTRA

Restituisce l'ultimo o gli ultimi caratteri di una stringa di testo.

### Sintassi

DESTRA("Testo"; Numero)

Testo è il testo la cui parte destra deve essere determinata.

Numero (opzionale) è il numero di caratteri partendo dalla destra del testo.

### Esempio

=DESTRA("Sole";2) restituisce le.

## DESTRA.B

Restituisce l'ultimo o gli ultimi caratteri di un testo, con gruppi di caratteri a doppio byte (DBCS).

### Sintassi

DESTRA.B("Testo"; Numero_byte)

Testo è il testo la cui parte destra deve essere determinata.

Numero_byte (opzionale) specifica il numero di caratteri che DESTRA.B deve estrarre, basato sui byte.

### Esempi

DESTRA.B("中国";1) restituisce " " (un byte è solo metà carattere DBCS, e viene invece restituito un carattere di spazio).

DESTRA.B("中国";2) restituisce "国" (due byte costituiscono un carattere DBCS completo).

DESTRA.B("中国";3) restituisce " 国" (tre byte costituiscono mezzo carattere DBCS e un carattere DBCS intero; viene restituito uno spazio per il primo mezzo carattere).

DESTRA.B("中国";4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).

DESTRA.B("office";3) restituisce "ice" (tre caratteri non DBCS, ciascuno formato da un byte).

## FISSO

Restituisce un numero come testo con un numero di posizioni decimali fisso e con o senza separatore delle migliaia.

### Sintassi

FISSO(Numero; Decimali; Nessun separatore migliaia)

Numero è il numero che si desidera formattare.

Decimali è il numero di cifre a destra della virgola decimale.

Nessun separatore migliaia (opzionale) stabilisce se il separatore delle migliaia verrà visualizzato o meno. Se il parametro è un numero diverso da 0, il separatore delle migliaia viene nascosto. Se il parametro è uguale a 0 o non viene specificato, viene visualizzato il separatore delle migliaia delle impostazioni locali attuali.

### Esempio

=FISSO(1234567,89;3) restituisce 1.234.567,890 come stringa di testo.

=FISSO(1234567.89;3;1) restituisce 1234567,890 come stringa di testo.

## IDENTICO

Confronta due stringhe e restituisce VERO se sono identiche. Questa funzione distingue tra maiuscole e minuscole.

### Sintassi

IDENTICO("Testo 1"; "Testo 2")

Testo 1 è il primo testo da confrontare.

Testo 2 è il secondo testo da confrontare.

### Esempio

=IDENTICO("microsystems";"Microsystems") restituisce FALSE.

## JIS

La funzione JIS converte i caratteri ASCII e katakana da larghezza dimezzata a larghezza piena. Restituisce una stringa di testo.

Per la conversione di una tabella consultate https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions.

### Sintassi

JIS("testo")

Testo è il testo che contiene i caratteri da convertire.

Vedere anche la funzione ASC.

## LIBERA

Rimuove dal testo tutti i caratteri non stampabili.

### Sintassi

LIBERA("Testo")

Testo si riferisce al testo da cui rimuovere tutti i caratteri non stampabili.

## LUNGH.B

Per le lingue con gruppo di caratteri a doppio byte (DBCS), restituisce il numero di byte utilizzato per rappresentare i caratteri in una stringa di testo.

### Sintassi

LUNGH.B("Testo")

Testo è il testo la cui lunghezza deve essere determinata.

### Esempi

LUNGH.B("中") restituisce 2 (un carattere DBCS formato da due byte).

LUNGH.B("中国") restituisce 4 (due caratteri DBCS, ciascuno formato da due byte).

LUNGH.B("office") restituisce 6 (sei caratteri non DBCS, ciascuno formato da un byte).

=LUNGH.B("Buongiorno") restituisce 14.

=LUNGH.B(12345,67) restituisce 8.

## LUNGHEZZA

Restituisce la lunghezza di una stringa, inclusi gli spazi.

### Sintassi

LUNGHEZZA("Testo")

Testo è il testo la cui lunghezza deve essere determinata.

### Esempio

=LUNGHEZZA("Buongiorno") restituisce 10.

=LUNGHEZZA(12345,67) restituisce 8.

## MAIUSC

Converte la stringa specificata nel campo di testo in maiuscolo.

### Sintassi

MAIUSC("Testo")

Testo sono le lettere minuscole da convertire in maiuscole.

### Esempio

=MAIUSC("Buon giorno") restituisce BUON GIORNO.

## MAIUSC.INIZ

Converte in maiuscolo la prima lettera di tutte le parole di una stringa di testo.

### Sintassi

MAIUSC.INIZ("Testo")

Testo è il testo da convertire.

### Esempio

=MAIUSC.INIZ("open office") restituisce Open Office.

## MINUSC

Converte tutto il testo in minuscolo.

### Sintassi

MINUSC("Testo")

Testo è il testo da convertire.

### Esempio

=MINUSC("Sun") restituisce sun.

## RICERCA

Restituisce la posizione di un segmento di testo all'interno di una stringa di caratteri. L'impostazione dell'inizio della ricerca è opzionale. Il testo da ricercare può essere un numero oppure una sequenza di caratteri. La ricerca non distingue tra maiuscole e minuscole.

La ricerca supporta le espressioni regolari. Per esempio, potete digitare "tutto.*" per trovare la prima occorrenza di "tutto" seguita da un carattere qualunque. Per ricercare un testo che è anche un'espressione regolare, dovete far precedere ogni carattere da una \. La valutazione automatica delle espressioni regolari può essere attivata e disattivata in LibreOffice - Preferenze Strumenti - Opzioni
- LibreOffice Calc - Calcola.

### Sintassi

RICERCA("Testo ricercato"; "Testo"; Posizione)

TrovaTesto è il testo da cercare.

Testo è il testo da cui parte la ricerca.

Posizione (opzionale) è la posizione nel testo da cui iniziare la ricerca.

### Esempio

=RICERCA(54; 998877665544) restituisce 10.

## RIMPIAZZA

Sostituisce più volte testi parziali in un testo. Questa funzione permette di sostituire sia lettere che cifre (queste vengono convertite automaticamente in testo). Il risultato della funzione è sempre un testo. Se volete continuare a calcolare con un numero che è stato sostituito, è necessario prima convertirlo nel formato numerico ricorrendo alla funzione VALORE.

Ricordate di inserire qualsiasi testo contenente dei numeri tra virgolette, se non volete che sia interpretato come numero e convertito automaticamente in testo.

### Sintassi

RIMPIAZZA("Testo"; Posizione; Numero caratteri; "Nuovo testo")

Testo è il testo nel quale si desidera sostituire una parte.

Posizione è la posizione all'interno del testo da cui partirà la sostituzione.

Numero caratteri è il numero di caratteri da sostituire nel Testo.

Nuovo testo è il testo che sostituirà i caratteri in Testo.

### Esempio

=RIMPIAZZA("1234567";1;1;"444") restituisce "444234567". Un carattere alla posizione 1 viene sostituito dai caratteri specificati come Nuovo testo.

## RIPETI

Ripete una stringa di caratteri per il numero di volte specificato.

### Sintassi

RIPETI("Testo"; Numero)

Testo è il testo da ripetere.

Numero è il numero delle ripetizioni.

Il risultato può essere al massimo di 255 caratteri.

### Esempio

=RIPETI("Buon giorno";2) restituisce Buon giornoBuon giorno.

## ROMANO

Converte un numero arabo in un numero romano. Il numero da convertire deve essere compreso nell'intervallo di valori tra 0 e 3999, mentre il modo può essere un intero da 0 a 4.

### Sintassi

ROMANO(Numero; Modo)

Numero è la cifra da convertire in numero romano.

Modo (opzionale) restituisce il livello di semplificazione. Più il numero è elevato, più il numero romano verrà semplificato.

### Esempio

=ROMANO(999) restituisce CMXCIX

=ROMANO(999;0) restituisce CMXCIX

=ROMANO(999;1) restituisce LMVLIV

=ROMANO(999; 2) restituisce XMIX.

=ROMANO(999;3) restituisce VMIV.

=ROMANO(999;4) restituisce IM.

## SINISTRA

Restituisce il primo o i primi caratteri di un testo.

### Sintassi

SINISTRA("Testo"; Numero caratteri)

Testo è il testo di cui determinare le parole comprese nella parte iniziale.

Numero (opzionale) specifica il numero di caratteri da estrarre da sinistra. Se questo parametro non è definito, viene restituito un solo carattere.

### Esempio

=SINISTRA("disattivare"; 3) restituisce “dis”.

## SINISTRA.B

Restituisce i primi caratteri di un testo DBCS.

### Sintassi

SINISTRA.B("Testo"; Numero_byte)

Testo è il testo di cui determinare le parole comprese nella parte iniziale.

Numero_byte (opzionale) specifica il numero di caratteri che SINISTRA.B deve estrarre, basato sui byte. Se questo parametro non è definito, viene restituito un solo carattere.

### Esempi

SINISTRA.B("中国";1) restituisce " " (un byte è solo metà carattere DBCS, e viene invece restituito un carattere di spazio).

SINISTRA.B("中国";2) restituisce "中" (due byte costituiscono un carattere DBCS completo).

SINISTRA.B("中国";3) restituisce "中 " (tre byte costituiscono un carattere DBCS e mezzo; l'ultimo carattere restituito è dunque un carattere di spazio).

SINISTRA.B("中国";4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).

SINISTRA.B("office";3) restituisce "off" (tre caratteri non DBCS, ciascuno formato da un byte).

## SOSTITUISCI

Sostituisce in una stringa un testo esistente con un nuovo testo.

### Sintassi

SOSTITUISCI("Testo"; "CercaTesto"; "Nuovo testo"; Occorrenza)

Testo è il testo in cui i segmenti devono essere scambiati.

CercaTesto è il segmento di testo da sostituire (un determinato numero di volte).

Nuovo testo è il testo che deve sostituire la parola parziale.

Occorrenza (opzionale) indica quale occorrenza della ricerca deve essere sostituita. Se manca questo parametro, il testo ricercato sarà sostituito completamente.

### Esempio

=SOSTITUISCI("123123123"; "3"; "abc") restituisce 12abc12abc12abc.

=SOSTITUISCI("123123123";"3";"abc";2) restituisce 12312abc123.

## STRINGA.ESTRAI

Restituisce una stringa di un testo. I parametri specificano la posizione iniziale e il numero di caratteri.

### Sintassi

STRINGA.ESTRAI("Testo", Inizio; Numero)

Testo è il testo contenente i caratteri da estrarre.

Inizio è la posizione del primo carattere da estrarre dal testo.

Numero specifica il numero dei caratteri nella porzione di testo.

### Esempio

=STRINGA.ESTRAI("office";2;2) restituisce ff.

## STRINGA.ESTRAI.B

Restituisce una stringa di un testo DBCS. I parametri specificano la posizione iniziale e il numero di caratteri.

### Sintassi

STRINGA.ESTRAI.B("Testo", Inizio; Numero_byte)

Testo è il testo contenente i caratteri da estrarre.

Inizio è la posizione del primo carattere da estrarre dal testo.

Numero_byte specifica il numero di caratteri, in byte, che STRINGA.ESTRAI.B restituirà dal testo.

### Esempi

STRINGA.ESTRAI.B("中国";1;0) restituisce "" (zero byte è sempre una stringa vuota).

STRINGA.ESTRAI.B("中国";1;1) restituisce " " (un byte è solo mezzo carattere DBCS, dunque il risultato è un carattere di spazio).

STRINGA.ESTRAI.B("中国";1;2) restituisce "中" (due byte costituiscono un carattere DBCS completo).

STRINGA.ESTRAI.B("中国";1;3) restituisce "中 " (tre byte costituiscono un carattere DBCS e mezzo; l'ultimo byte è formato da un carattere di spazio).

STRINGA.ESTRAI.B("中国";1;4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).

STRINGA.ESTRAI.B("中国";2;1) restituisce " " (la posizione di byte 2 non si trova all'inizio di un carattere in una stringa DBCS; viene restituito uno spazio di carattere).

STRINGA.ESTRAI.B("中国";2;2) restituisce " " (la posizione di byte 2 punta all'ultima metà del primo carattere nella stringa DBCS; i due byte richiesti costituiscono perciò nella stringa l'ultima metà del primo carattere e la prima metà del secondo; vengono restituiti dunque due spazi di carattere).

STRINGA.ESTRAI.B("中国";2;3) restituisce " 国" (la posizione di byte 2 non si trova all'inizio di un carattere in una stringa DBCS; viene restituito uno spazio di carattere per la posizione di byte 2).

STRINGA.ESTRAI.B("中国";3;1) restituisce " " (la posizione di byte 3 si trova all'inizio di un carattere in una stringa DBCS, ma un byte è solo mezzo carattere DBCS, e viene dunque restituito uno spazio di carattere).

STRINGA.ESTRAI.B("中国";3;2) restituisce "国" (la posizione di byte 3 si trova all'inizio di un carattere in una stringa DBCS, e due byte costituiscono un carattere DBCS).

STRINGA.ESTRAI.B("office";2;3) restituisce "ffi" (la posizione di byte 2 si trova all'inizio di un carattere in un stringa non DBCS, e tre byte di una stringa non DBCS costituiscono tre caratteri).

## T

Questa funzione restituisce il testo di destinazione o una stringa di testo vuota se la destinazione non è il testo.

### Sintassi

T(Valore)

Se Valore è una stringa di testo o si riferisce a essa, T restituisce quella stringa di testo; in caso contrario restituisce una stringa vuota.

### Esempio

=T(12345) restituisce una stringa vuota.

=T("12345") restituisce la stringa 12345.

## TESTO

Converte un numero in testo in base al formato indicato.

### Sintassi

TESTO(Numero; Formato)

Numero è il numero da convertire.

Formato è il testo che definisce il formato. Utilizzate i separatori di decimali e migliaia secondo la lingua impostata nel formato cella.

### Esempio

=TESTO(12,34567;"###,##") restituisce il testo 12,35

=TESTO(12,34567;"000,00") restituisce il testo 012,35

## TESTO.BAHT

Converte un numero in testo Thai, inclusi i nomi di valute Thai.

### Sintassi

TESTO.BAHT(Numero)

Numero è qualsiasi numero. "Baht" viene aggiunta alla parte integrale del numero e "Satang" viene aggiunta alla parte decimale del numero.

### Esempio

=TESTO.BAHT(12.65) restituisce una stringa in caratteri Thai con il significato di "12 Baht e 65 Satang".

## TROVA

Restituisce la posizione di una stringa di testo all'interno di un'altra stringa. Potete anche definire la posizione da cui iniziare la ricerca. Il termine da ricercare può essere un numero o qualsiasi stringa di caratteri. La ricerca distingue tra maiuscole e minuscole.

### Sintassi

TROVA("Testo ricercato"; "Testo"; Posizione)

Testo ricercato è il testo che si desidera trovare.

Testo è il testo da cui parte la ricerca.

Posizione (opzionale) è la posizione nel testo da cui iniziare la ricerca.

### Esempio

=TROVA(76; 998877665544) restituisce 6.

## UNICODE

Restituisce il codice numerico del primo carattere Unicode di una stringa di testo.

### Sintassi

UNICODE("Testo")

### Esempio

=UNICODE("©") restituisce il numero Unicode 169 per carattere di copyright.

Vedere anche la funzione CARATT.UNI().

## VALORE

Converte una stringa di testo in un numero.

### Sintassi

VALORE("Testo")

Testo è il testo da convertire in numero.

### Esempio

=VALORE("4321") restituisce 4321.

## VALUTA

Converte un valore numerico in un testo avente il formato valuta. Il valore viene inoltre arrotondato alle cifre decimali indicate. Nel campo di testo Valore va introdotto il numero razionale da convertire nel formato valuta. Volendo, si può anche digitare nel campo Decimali il numero delle cifre decimali da rappresentare nel formato valuta. In mancanza di tale valore vengono usate due cifre decimali.

Il formato della valuta viene definito nelle impostazioni del sistema.

### Sintassi

VALUTA(Valore; Decimali)

Valore può essere un numero, un riferimento a una cella che lo contiene o una formula che lo restituisce.

Decimali è il numero opzionale di posizioni decimali.

### Esempio

=VALUTA(255) restituisce 255,00 €.

=VALUTA(367,456;2) restituisce 367,46 €. Utilizza il separatore decimale corrispondente all'area regionale in cui è configurato attualmente il sistema.

Argomenti correlati

Funzioni per categoria