Modulo
Contenuto
Indice 🔎︎

# GIORNO.LAVORATIVO.INTL

Il risultato è un numero di data formattabile come data. L'utente può vedere la data di un giorno che è distante un certo numero di giorni lavorativi dalla data iniziale (prima o dopo). Esistono opzioni per definire i giorni di fine settimana o di vacanza. Il parametro fine settimana facoltativo (o una stringa) può essere usato per definire i giorni del fine settimana (o i giorni non lavorativi in ciascuna settimana). L'utente può inoltre definire facoltativamente un elenco delle vacanze. I giorni di fine settimana e le vacanze definite dall'utente non vengono conteggiate come giorni lavorativi.

### Sintassi

GIORNO.LAVORATIVO.INTL(Data iniziale; Giorni; Fine settimana; Vacanze)

Data iniziale è la data a partire dalla quale viene eseguito il calcolo. Se la data iniziale è un giorno lavorativo, questo verrà incluso nel calcolo. Questo elemento è obbligatorio.

Giorni è il totale dei giorni lavorativi. Un valore positivo indica un risultato posteriore alla data iniziale; un valore negativo indica un risultato anteriore alla data iniziale.

Fine settimana è un parametro facoltativo: un numero o una stringa usata per specificare i giorni della settimana che rappresentano il fine settimana e non sono considerati giorni lavorativi. Il fine settimana è un numero di fine settimana o una stringa che specifica quando si verificano i fine settimana. I valori numerici del fine settimana indicano i giorni di fine settimana seguenti:

Numero da 1 a 7 per fine settimana di due giorni e da 11 a 17 fine settimana di un giorno.

Numero | Fine settimana
1 od omesso | Sabato e domenica
2 | Domenica e lunedì
3 | Lunedì e martedì
4 | Martedì e mercoledì
5 | Mercoledì e giovedì
6 | Giovedì e venerdì
7 | Venerdì e sabato
11 | Solo domenica
12 | Solo lunedì
13 | Solo martedì
14 | Solo mercoledì
15 | Solo giovedì
16 | Solo venerdì
17 | Solo sabato

La stringa Fine settimana fornisce un altro modo per definire i giorni non lavorativi settimanali. Deve contenere sette (7) caratteri – zero (0) per i giorni lavorativi e uno (1) per quelli non lavorativi. Ciascun carattere rappresenta un giorno della settimana, iniziando con lunedì. Gli unici valori validi sono 1 e 0. “1111111” non è una stringa valida e non deve essere usata. Per esempio, la stringa di fine settimana “0000011” definisce sabato e domenica come giorni non lavorativi.

Vacanze è un elenco opzionale delle date devono essere conteggiate come giorni non lavorativi. L'elenco può essere fornito all'interno di un intervallo di celle.

### Esempio

Supponiamo che si desideri sapere la data del giorno che cade giorni 20 lavorativi dopo il 13 dicembre 2016. Si inserisce la data iniziale in C3 e il numero di giorni lavorativi in D3.

Il parametro fine settimana (numero) può essere lasciato vuoto o definito come 1 per il fine settimana standard (giorni non lavorativi) – sabato e domenica.

Le celle da F3 a J3 contengono cinque (5) vacanze per Natale e Capodanno, nel formato data: 24 dicembre 2016; 25 dicembre 2016; 26 dicembre 2016; 31 dicembre 2016; 1 gennaio 2017.

=GIORNO.LAVORATIVO.INTL(C3;D3;;F3:J3) restituisce 11 gennaio 2017 nella cella del risultato, diciamo D6 (usate il formato data in questa cella).

Usate il parametro il fine settimana 7 per definire venerdì e sabato come giorni di fine settimana.

=GIORNO.LAVORATIVO.INTL(C3;D3;7;F3:J3) restituisce 15 gennaio 2017 col 7 come parametro fine settimana.

Usate il parametro fine settimana 11 per definire solo domenica come giorno di fine settimana.

=GIORNO.LAVORATIVO.INTL(C3;D3;11;F3:J3) restituisce 9 gennaio 2017.

In alternativa, usate la stringa fine settimana "0000001" per i fine settimana con solo domenica.

=GIORNO.LAVORATIVO.INTL(C3;D3;"0000001";F3:J3) restituisce 9 gennaio 2017.

La funzione può essere utilizzata senza i due parametri opzionali – giorni di fine settimana e vacanze – ossia lasciandoli fuori:

=GIORNO.LAVORATIVO.INTL(C3;D3) restituisce 10 gennaio 2017.

Argomenti correlati

GIORNI.LAVORATIVI.TOT

GIORNI.LAVORATIVI.TOT.INTL

GIORNO.LAVORATIVO

Funzioni data