Modulo
Contenuto
Indice 🔎︎

## Funzione CONTA.PIÙ.SE

Restituisce il conteggio delle celle che soddisfano i criteri in più intervalli.

### Sintassi

CONTA.PIÙ.SE(Intervallo1; Criterio1 [; Intervallo2; Criterio2 [; ...]])

Intervallo1 – argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per il conteggio e per trovare il criterio corrispondente.

Criterio1: argomento richiesto. Un'espressione che rappresenta una condizione logica o un riferimento di cella a tale espressione. L'espressione può contenere testo, numeri, espressioni regolari o caratteri jolly (se abilitati nelle opzioni di calcolo).

Intervallo2 – opzionale. Intervallo2 e tutto ciò che segue hanno lo stesso significato di Intervallo1.

Criterio2 – opzionale. Criterio2 e tutto ciò che segue hanno lo stesso significato di Criterio1.

Intervallo1, Intervallo2, ... e Criterio1, Criterio2, ... devono possedere la stessa dimensione, in caso contrario la funzione restituisce err:502 - Argomento non valido.

La relazione logica tra i criteri definibili come E logico (congiunzione). In altre parole, se, e solo se, tutti i criteri sono soddisfatti, viene inserito nel calcolo un valore derivante dalla cella corrispondente del Intervallo_Func specificato.

La funzione può possedere fino a 255 argomenti, nel senso che potete specificare 127 intervalli di criteri e i criteri ad essi relativi.

Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero).

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).

### Esempi

#### Considerate la tabella seguente

| A | B | C
1 | Nome prodotto | Vendite | Ricavo
2 | matita | 20 | 65
3 | penna | 35 | 85
4 | notebook | 20 | 190
5 | libro | 17 | 180
6 | astuccio | non | non

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.

#### Uso semplice

=CONTA.PIÙ.SE(B2:B6;">=20")

Conta la quantità di righe dell'intervallo B2:B6 con valori maggiori o uguali a 20. Restituisce 3, perché la quinta e la sesta riga non soddisfano il criterio.

=CONTA.PIÙ.SE(B2:B6;">=20";C2:C6;">70")

Conta la quantità di righe che contengono contemporaneamente valori maggiori di 70 nell'intervallo C2:C6 e valori maggiori o uguali a 20 nell'intervallo B2:B6. Restituisce 2, perché la seconda, la quinta e la sesta riga non soddisfano almeno un criterio.

#### Uso delle espressioni regolari e delle funzioni annidate

=CONTA.PIÙ.SE(B2:B6;"[:alpha:]*")

Conta la quantità di righe dell'intervallo B2:B6 che contengono solo simboli alfabetici. Restituisce 1, perché solo la sesta riga soddisfa il criterio.

=CONTA.PIÙ.SE(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Conta la quantità di righe dell'intervallo B2:B6 escludendo le righe con valori minimi e massimi dello stesso intervallo. Restituisce 2, perché la terza, la quinta e la sesta riga non soddisfano almeno un criterio.

=CONTA.PIÙ.SE(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Conta la quantità di righe che corrispondono a tutte le celle dell'intervallo A2:A6 che iniziano con "pen" e a tutte le celle dell'intervallo B2:B6, eccetto il suo massimo. Restituisce 1, perché solo la seconda riga soddisfa tutti i criteri.

#### Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione CONTA.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:

=CONTA.PIÙ.SE(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Se E2 = pen, la funzione restituisce 1, perché il collegamento alla cella è sostituito dal suo contenuto e agisce come la funzione sopra citata.

Argomenti correlati

CONTA.NUMERI, CONTA.SE, CONTA.VUOTE, CONTA.VALORI

CONTA.PIÙ.SE, MIN.PIÙ.SE, MAX.PIÙ.SE, MEDIA.PIÙ.SE, SOMMA.PIÙ.SE

Elenco delle espressioni regolari