Module
Contents
Index 🔎︎

# གླེང་སྒྲོམ་རྩོམ་སྒྲིག་ཆས་ནང་གི་བྱ་རིམ་རྩོམ་འབྲིའི་དཔེ་གཞི་

གཤམ་གསལ་དཔེ་གཞི་ནི་མིང་ལ་ "Dialog1" ཡི་གླེང་སྒྲོམ་གསར་པ་ལ་དམིགས་པ་ཡིན། གླེང་སྒྲོམ་རྩོམ་སྒྲིག་ཆས་ནང་གི་ཡོ་བྱད་ཚང་ཚང་སྟེང་གི་ཡོ་བྱད་བདེ་སྤྱད་ན་གླེང་སྒྲོམ་གསར་འཛུགས་བྱ་ཐུབ་པ་མ་ཟད་གཤམ་གསལ་ཚོད་འཛིན་ཆས་གསབ་སྣོན་བྱ་བ་སྟེ་

ཚོད་འཛིན་ཆས་དེ་བྱ་ཡུལ་འགྱུར་ཆད་ལ་ཟུར་སྣོན་བྱ་སྐབས་ བྲི་བའི་ཡི་གེའི་ཆེ་ཆུང་གཅིག་མཐུན་རྒྱུན་འཁོངའཁོང་བྱེད་པ།

### ཁུར་སྣོན་གླེང་སྒྲོན་གྱི་ཁྱོན་ཡོངས་རྟེན་གྲངས་

    Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)

    Dim oLib as Object

    Dim oLibDialog as Object

    Dim oRuntimeDialog as Object

        If IsMissing(oLibContainer) Then

            oLibContainer = DialogLibraries

        End If

        oLibContainer.LoadLibrary(LibName)

        oLib = oLibContainer.GetByName(Libname)

        oLibDialog = oLib.GetByName(DialogName)

        oRuntimeDialog = CreateUnoDialog(oLibDialog)

        LoadDialog() = oRuntimeDialog

    End Function

### གླེང་སྒྲོམ་མངོན་པ་

    rem ཁྱོན་ཡོངས་འགྱུར་ཚད་ཀྱི་མཚན་འཇོག་

    Dim oDialog1 AS Object

    Sub StartDialog1

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        oDialog1.Execute()

    End Sub

### བྱ་རིམ་ནང་གི་ཚད་འཛིན་ཆས་ཀྱི་གཏོགས་གཤིས་ཀློག་འདོན་དང་རྩོམ་སྒྲིག་བྱ་བ་

    Sub Sample1

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM གླེང་སྒྲོམ་འདྲ་དབྱིབས་ཐོབ་པ་

        oDialog1Model = oDialog1.Model

        REM  Label1 གི་ཡི་གེ་མངོན་པ་

        oLabel1 = oDialog1.GetControl("Label1")

        MsgBox oLabel1.Text

        REM བཀོད་སྒྲིག་ཚོད་འཛིན་ཆས་ Label1 ཡི་གི་་གསར་པ་

        oLabel1.Text = "New Files"

        REM ཚོད་འཛིན་ཆས་ CheckBox1 ཡི་འདྲ་དབྱིབས་གཏོགས་གཤིས་མངོན་པ་

        oCheckBox1Model = oDialog1Model.CheckBox1

        MsgBox oCheckBox1Model.Dbg_Properties

        REM གིས་ CheckBox1 ཚོད་འཛིན་ཆས་ཀྱི་འདྲ་དབྱིབས་ཀྱིས་གནས་སྟངས་གསར་པ་བཀོད་སྒྲིག་བྱེད་

        oCheckBox1Model.State = 1

        REM ཚད་འཛིན་ཆས་ CommandButton1 ཡི་འདྲ་དབྱིབས་གཏོགས་གཤིས་མངོན་པ་

        oCMD1Model = oDialog1Model.CommandButton1

        MsgBox oCMD1Model.Dbg_Properties

        REM མངོན་པའི་ཚོད་འཛིན་ CommandButton1 ཡི་གཏོགས་གཤིས་

        oCMD1 = oDialog1.GetControl("CommandButton1")

        MsgBox oCMD1.Dbg_Properties

        REM ལག་བསྟར་གླེང་སྒྲོམ་

        oDialog1.Execute()

    End Sub

### རེའུ་འགོད་སྒྲོམ་ནང་གཤར་བྱང་གསབ་སྣོན་བྱ་

    Sub AddEntry

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM གི་ ListBox ནང་གཤར་བྱང་གསར་པ་གསབ་སྣོན་བྱེད་

        oDialog1Model = oDialog1.Model

        oListBox = oDialog1.GetControl("ListBox1")

        Dim iCount as integer

        iCount = oListbox.ItemCount

        oListbox.additem("New Item" & iCount,0)

    End Sub

### ListBox ནང་གི་གཤར་བྱང་སུབ་པ་

    Sub RemoveEntry

        BasicLibraries.LoadLibrary("Tools")

        oDialog1 = LoadDialog("Standard", "Dialog1")

        REM  ListBox ནང་གི་གཤར་བྱང་དང་པོ་སུབ་པ་

        oDialog1Model = oDialog1.Model

        oListBox = oDialog1.GetControl("ListBox1")

        oListbox.removeitems(0,1)

    End Sub

འབྲེལ་ཡོད་གཙོ་དོན་

གླེང་སྒྲོམ་རྩོམ་སྒྲིག་ཆས་ནང་ཚོད་འཛིན་ཆས་ཀྱི་གཏོགས་གཤིས་

གསར་འཛུགས་ Basic གླེང་སྒྲོམ་

གླེང་སྒྲོམ་རྩོམ་སྒྲིག་ཆས་ནང་ཚོད་འཛིན་ཆས་

བྱ་རིམ་ཚབ་ཨང་བརྒྱུད་ནས་གློང་སྒྲོམ་ཁ་ཕྱེ་བ་