Fungsi Informasi

Kategori ini mengandung fungsi Informasi.

Untuk mengakses fungsi ini...

Sisip - Fungsi - Kategori Informasi


The data in the following table serves as the basis for some of the examples in the function descriptions:

C

D

2

-3,48

-3,48

3

-3,48

-3,48

4

-3,48

-10000

5

-3,48

-10000

6

-10000

-3,48

7

-3,48

-3,48

8

-3,48

-3,48

9

-3,48

-3,48


CELL

Returns information on address, formatting or contents of a cell.

Sintaksis

CELL(Jenis_info; Referensi)

InfoType is the character string that specifies the type of information. The character string is always in English. Upper or lower case is optional.

Jenis_info

Arti

COL

Menghasilkan nomor dari kolom yang direferensikan.

=CELL("COL";D2) returns 4.

ROW

Menghasilkan nomor dari baris yang direferensikan.

=CELL("ROW";D2) returns 2.

SHEET

Menghasilkan nomor dari lembar kerja (set) yang direferensikan.

=CELL("Sheet";Sheet3.D2) returns 3.

ADDRESS

Menghasilkan alamat absolut dari sel yang direferensikan.

=CELL("ADDRESS";D2) returns $D$2.

=CELL("ADDRESS";Sheet3.D2) returns $Sheet3.$D$2.

=CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.$D$2.

FILENAME

Menghasilkan nama berkas dan nomor lembar kerja (set) dari sel yang direferensikan.

=CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1.

=CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.

COORD

Returns the complete cell address in Lotus™ notation.

=CELL("COORD"; D2) returns $A:$D$2.

=CELL("COORD"; Sheet3.D2) returns $C:$D$2.

CONTENTS

Menghasilkan isi dari sel yang direferensikan, tanpa pemformatan apa pun.

TYPE

Menghasilkan jenis dari isi sel.

b = blank. sel kosong

l = label. Teks, hasil formula sebagai teks

v = value. Nilai, hasil formula sebagai angka/bilangan

WIDTH

Returns the width of the referenced column. The unit is the number of zeros (0) that fit into the column in the default text and the default size.

PREFIX

Menghasilkan perataan dari sel yang direferensikan.

' = rata kiri

" = rata kanan

^ = rata tengah

\ = berulang (saat ini tak aktif)

PROTECT

Menghasilkan status dari proteksi sel.

1 = sel diproteksi

0 = sel tidak diproteksi

FORMAT

Menghasilkan string karakter yang mengindikasikan format angka.

, = bilangan dengan pemisah ribuan

F = bilangan tanpa pemisah ribuan

C = format mata uang

S = representasi eksponensial, sebagai contoh, 1.234+E56

P = persentase

In the above formats, the number of decimal places after the decimal separator is given as a number. Example: the number format #,##0.0 returns ,1 and the number format 00.000% returns P3

D1 = MMM-D-YY, MM-D-YY dan format lainnya yang serupa

D2 = DD-MM

D3 = MM-YY

D4 = DD-MM-YYYY HH:MM:SS

D5 = MM-DD

D6 = HH:MM:SS AM/PM

D7 = HH:MM AM/PM

D8 = HH:MM:SS

D9 = HH:MM

G = Format lainnya

- (Minus) at the end = negative numbers are formatted in color

() (brackets) at the end = there is an opening bracket in the format code

COLOR

Returns 1, if negative values have been formatted in color, otherwise 0.

PARENTHESES

Returns 1 if the format code contains an opening bracket (, otherwise 0.


Reference (list of options) is the position of the cell to be examined. If Reference is a range, the cell moves to the top left of the range. If Reference is missing, LibreOffice Calc uses the position of the cell in which this formula is located. Microsoft Excel uses the reference of the cell in which the cursor is positioned.

CURRENT

This function returns the result to date of evaluating the formula of which it is a part (in other words the result as far as that evaluation has got). Its main use is together with the STYLE() function to apply selected styles to a cell depending on the cell contents.

Sintaksis

CURRENT()

Contoh

=1+2+CURRENT()

The example returns 6. The formula is calculated from left to right as: 1 + 2 equals 3, giving the result to date when CURRENT() is encountered; CURRENT() therefore yields 3, which is added to the original 3 to give 6.

=A2+B2+STYLE(IF(CURRENT()>10;”Red”;”Default”))

The example returns A2 + B2 (STYLE returns 0 here). If this sum is greater than 10, the style Red is applied to the cell. See the STYLE function for more explanation.

="choo"&CURRENT()

hasil

FORMULA

Displays the formula of a formula cell as a text string.

Sintaksis

FORMULA(referensi)

Reference is a reference to a cell containing a formula.

An invalid reference or a reference to a cell with no formula results in the error value #N/A.

Contoh

If cell A8 contains the formula =SUM(1;2;3) then

=FORMULA(A8) returns the text =SUM(1;2;3).

INFO

Returns specific information about the current working environment. The function receives a single text argument and returns data depending on that parameter.

Sintaksis

INFO(jenis)

The following table lists the values for the text parameter Type and the return values of the INFO function.

Tipe nilai

Nilai hasil

"osversion"

Always "Windows (32-bit) NT 5.01", for compatibility reasons

"system"

The type of the operating system.
"WNT" for Microsoft Windows
"LINUX" for Linux
"SOLARIS" for Solaris

"release"

The product release identifier, for example "300m25(Build:9876)"

"numfile"

Always 1, for compatibility reasons

"recalc"

Current formula recalculation mode, either "Automatic" or "Manual" (localized into LibreOffice language)


Ikon Catatan

Other spreadsheet applications may accept localized values for the Type parameter, but LibreOffice Calc will only accept the English values.


Contoh

=INFO("release") returns the product release number of the LibreOffice in use.

=INFO(D5) with cell D5 containing a text string system returns the operation system type.

ISBLANK

Returns TRUE if the reference to a cell is blank. This function is used to determine if the content of a cell is empty. A cell with a formula inside is not empty.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

ISBLANK(nilai)

Nilai adalah nilai yang akan diperiksa.

Contoh

=ISBLANK(D2) returns FALSE as a result.

ISERR

Tests for error conditions, except the #N/A error value, and returns TRUE or FALSE.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

ISERR(nilai)

Value is any value or expression which is tested to see whether an error value other than #N/A is present.

Contoh

=ISERR(C8) where cell C8 contains =1/0 returns TRUE, because 1/0 is an error.

=ISERR(C9) where cell C9 contains =NA() returns FALSE, because ISERR() ignores the #N/A error.

ISERROR

Tests for error conditions, including the #N/A error value, and returns TRUE or FALSE.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

ISERROR(nilai)

Value is or refers to the value to be tested. ISERROR() returns TRUE if there is an error and FALSE if not.

Contoh

=ISERROR(C8) where cell C8 contains =1/0 returns TRUE, because 1/0 is an error.

=ISERROR(C9) where cell C9 contains =NA() returns TRUE.

ISERROR

Returns the value if the cell does not contains an error value, or the alternative value if it does.

Sintaksis

IFERROR(Value;Alternate_value)

Value is the value or expression to be returned if it is not equal or results in an error.

Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an error.

Contoh

=IFERROR(C8;C9) where cell C8 contains =1/0 returns the value of C9, because 1/0 is an error.

=IFERROR(C8;C9) where cell C8 contains 13 returns 13, the value of C8, which is not an error.

ISEVEN

Returns TRUE if the value is an even integer, or FALSE if the value is odd.

Sintaksis

ISEVEN(nilai)

Nilai adalah nilai yang akan diperiksa.

If Value is not an integer any digits after the decimal point are ignored. The sign of Value is also ignored.

Contoh

=ISEVEN(48) returns TRUE

=ISEVEN(33) returns FALSE

=ISEVEN(0) returns TRUE

=ISEVEN(-2.1) returns TRUE

=ISEVEN(3.999) returns FALSE

ISEVEN_ADD

Tests for even numbers. Returns 1 if the number divided by 2 returns a whole number.

Ikon Catatan

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


Sintaksis

ISEVEN_ADD(Angka)

Nilai adalah nilai yang akan diperiksa.

Contoh

=ISEVEN_ADD(5) returns 0.

=ISEVEN_ADD(A1) returns 1 if cell A1 contains the number 2.

ISFORMULA

Returns TRUE if a cell is a formula cell.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

ISFORMULA(referensi)

Reference indicates the reference to a cell in which a test will be performed to determine if it contains a formula.

Contoh

=ISFORMULA(C4) returns FALSE if the cell C4 contains the number 5.

ISLOGICAL

Tests for a logical value (TRUE or FALSE).

If an error occurs, the function returns FALSE.

Sintaksis

ISLOGICAL(nilai)

Returns TRUE if Value is a logical value (TRUE or FALSE), and returns FALSE otherwise.

Contoh

=ISLOGICAL(99) returns FALSE, because 99 is a number, not a logical value.

=ISLOGICAL(ISNA(D4)) returns TRUE whatever the contents of cell D4, because ISNA() returns a logical value.

ISNA

Returns TRUE if a cell contains the #N/A (value not available) error value.

If an error occurs, the function returns FALSE.

Sintaksis

ISNA(nilai)

Nilai adalah nilai yang akan diperiksa.

Contoh

=ISNA(D3) returns FALSE as a result.

ISNA

Returns the value if the cell does not contains the #N/A (value not available) error value, or the alternative value if it does.

Sintaksis

IFNA(Value;Alternate_value)

Value is the value or expression to be returned if it is not equal or results in an #N/A error.

Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an #N/A error.

Contoh

=IFNA(D3;D4) returns the value of D3 if D3 does not result in an #N/A error, or D4 if it does.

ISNONTEXT

Tests if the cell contents are text or numbers, and returns FALSE if the contents are text.

If an error occurs, the function returns TRUE.

Sintaksis

ISNONTEXT(nilai)

Value is any value or expression where a test is performed to determine whether it is a text or numbers or a Boolean value.

Contoh

=ISNONTEXT(D2) returns FALSE if cell D2 contains the text abcdef.

=ISNONTEXT(D9) returns TRUE if cell D9 contains the number 8.

ISNUMBER

Returns TRUE if the value refers to a number.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

ISNUMBER(nilai)

Value is any expression to be tested to determine whether it is a number or text.

Contoh

=ISNUMBER(C3) returns TRUE if the cell C3 contains the number 4.

=ISNUMBER(C2) returns FALSE if the cell C2 contains the text abcdef.

ISODD

Returns TRUE if the value is odd, or FALSE if the number is even.

Sintaksis

ISODD(nilai)

Nilai adalah nilai yang akan diperiksa.

If Value is not an integer any digits after the decimal point are ignored. The sign of Value is also ignored.

Contoh

=ISODD(33) returns TRUE

=ISODD(48) returns FALSE

=ISODD(3.999) returns TRUE

=ISODD(-3.1) returns TRUE

ISODD_ADD

Returns TRUE (1) if the number does not return a whole number when divided by 2.

Ikon Catatan

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


Sintaksis

ISODD_ADD(Angka)

Nilai adalah nilai yang akan diperiksa.

Contoh

=ISODD_ADD(5) returns 1.

ISREF

Tests if the argument is a reference. Returns TRUE if the argument is a reference, returns FALSE otherwise. When given a reference this function does not examine the value being referenced.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

ISREF(nilai)

Value is the value to be tested, to determine whether it is a reference.

Contoh

=ISREF(C5) returns the result TRUE because C5 is a valid reference.

=ISREF("abcdef") returns always FALSE because a text can never be a reference.

=ISREF(4) returns FALSE.

=ISREF(INDIRECT("A6")) returns TRUE, because INDIRECT is a function that returns a reference.

=ISREF(ADDRESS(1; 1; 2;"Sheet2")) returns FALSE, because ADDRESS is a function that returns a text, although it looks like a reference.

ISTEXT

Returns TRUE if the cell contents refer to text.

If an error occurs, the function returns FALSE.

Sintaksis

ISTEXT(nilai)

Value is a value, number, Boolean value, or an error value to be tested.

Contoh

=ISTEXT(D9) returns TRUE if cell D9 contains the text abcdef.

=ISTEXT(C3) returns FALSE if cell C3 contains the number 3.

N

Returns the numeric value of the given parameter. Returns 0 if parameter is text or FALSE.

If an error occurs the function returns the error value.

Sintaksis

N(nilai)

Value is the parameter to be converted into a number. N() returns the numeric value if it can. It returns the logical values TRUE and FALSE as 1 and 0 respectively. It returns text as 0.

Contoh

=N(123) returns 123

=N(TRUE()) returns 1

=N(FALSE()) returns 0

=N("abc") returns 0

=N(1/0) returns #DIV/0!

NA

Mengembalikan nilai galat #N/A.

Sintaksis

NA()

Contoh

=NA() converts the contents of the cell into #N/A.

TYPE

Returns the type of value, where 1 = number, 2 = text, 4 = Boolean value, 8 = formula, 16 = error value, 64 = array.

If an error occurs, the function returns a logical or numerical value.

Sintaksis

TYPE(nilai)

Value is a specific value for which the data type is determined.

Contoh (lihat tabel contoh di atas)

=TYPE(C2) returns 2 as a result.

=TYPE(D9) returns 1 as a result.